香田里浪人 发表于 2013-1-23 15:38:05

关于“框选封闭区域面积到excel ”字体问题

有高手编写的“框选封闭区域面积到excel ”原程序如下
(defun c:qq (/ d ent f i lst m2 obj pt ss txt x y)
(setq TextHeight (getdist "\n输入标注文字高度:")
Textbh (getstring "\n输入编号前缀:"))
(defun maketext (txt pt)             ; 生成文字子函数
    (entmake (list '(0 . "TEXT") (cons 62 1) (cons 10 pt) (cons 40 TextHeight) (cons 1 txt) '(41 . 0.8)))
)
(setvar "cmdecho" 0)
(vl-load-com)
(setq ss (ssget) ent (entlast))
(command ".region" ss "")
(setq ss (ssadd)lst nil)
(while (setq ent (entnext ent))
    (if (= (cdr (assoc 0 (entget ent))) "REGION")
      (setq obj (vlax-ename->vla-object ent) pt (vlax-safearray->list (vlax-variant-value (vla-get-centroid obj)))
            m2 (rtos (vla-get-area obj) 2 2) d (rtos (vla-get-perimeter obj) 2 2) lst (cons (list pt m2 d) lst)
      )
    )
)
(command ".undo" "")
(setq lst (vl-sort lst (function (lambda (x y)(< (car (car x)) (car (car y)))))))
(setq lst (vl-sort lst (function (lambda (x y)(> (cadr (car x)) (cadr (car y)))))))
(setq f (getfiled "指定输出文件路径" "" "xls" 1) f (open f "a"))
(write-line "编号\t周长(mm)\t面积(mm2)" f)
(setq i 1)
(foreach x lst
    (setq pt (car x) m2 (cadr x) d (caddr x))
    (maketext (strcat Textbh (itoa i)) (list (car pt) (+ (cadr pt) (* 1.2 TextHeight))))
    (maketext (strcat "L=" d "mm") pt)
    (maketext (strcat "S=" m2 "mm2") (list (car pt) (- (cadr pt) (* 1.2 TextHeight))))
    (write-line (strcat (strcat Textbh (itoa i)) "\t" d "\t" m2) f)
    (setq i (1+ i))
)
(close f)
(princ)
)
可是运行后在图上显示的字体（见附件左图）不如意，如何修改，才能直接显示其他字体（如“宋体”等）希望显示如附件右图字体

zyhandw 发表于 2013-1-23 15:58:34

这个应该很好办吧，如果图中已有定义了宋体的文字样式（如附件中的"BG_ST"），直接修改
(entmake (list '(0 . "TEXT") (cons 62 1) (cons 10 pt) (cons 40 TextHeight) (cons 1 txt) '(41 . 0.8)))   =>
(entmake (list '(0 . "TEXT") (cons 62 1) (cons 10 pt) (cons 40 TextHeight) (cons 1 txt) '(41 . 0.8) '(7 . "BG_ST")))

zyhandw 发表于 2013-1-23 15:59:22

这个应该很好办吧，如果图中已有定义了宋体的文字样式（如附件中的"BG_ST"），直接修改
(entmake (list '(0 . "TEXT") (cons 62 1) (cons 10 pt) (cons 40 TextHeight) (cons 1 txt) '(41 . 0.8)))   =>
(entmake (list '(0 . "TEXT") (cons 62 1) (cons 10 pt) (cons 40 TextHeight) (cons 1 txt) '(41 . 0.8) '(7 . "BG_ST")))

香田里浪人 发表于 2013-1-23 16:08:14

试过，改了程序就不能运行。

香田里浪人 发表于 2013-1-23 16:15:20

再试一下，可以了。谢谢！

zyhandw 发表于 2013-1-24 08:40:38

不会都要再次运行才可以吧

香田里浪人 发表于 2013-1-24 13:01:29

不是再次运行才可以，是第一次搞错了，误把'(7 . "BG_ST")写成(7 . "BG_ST")导致不能运行。

zwf100 发表于 2013-8-6 23:50:28

总的来说，还不错，顶下

树櫴希德 发表于 2014-9-13 09:44:29

论坛高手就是多啊

llsheng_73 发表于 2014-9-13 09:55:42

树櫴希德 发表于 2014-9-13 09:44 static/image/common/back.gif
论坛高手就是多啊

[函数] Lisp-excel函数
http://bbs.mjtd.com/forum.php?mod=viewthread&tid=110435

输入lisp excel搜到的
页: [1] 2
查看完整版本: 关于“框选封闭区域面积到excel ”字体问题