BUBUBA918 发表于 2013-9-19 09:15:37

关于如何替换文字中的个别字符？

我一直用一下这个函数，最近发现不能替换文字中的个别字符，如12.380改为12@380，求助？
;;;--文字替换函数
(defun re_txt (oldtxt newtxt)
(if (= (cdr (assoc 1 shiti)) oldtxt)(setq shiti (subst (cons 1 newtxt) (assoc 1 shiti) shiti)))
) ;改文字值

004 发表于 2013-9-19 09:27:18

find可直接替，论坛搜索字符任意位置递增，或看zml84的搜狐博客，均有指定文本任意位置字符修改，替换，递增的功能。均有源码。

香田里浪人 发表于 2013-9-19 10:47:29

论坛里有此程序，查找与替换

自贡黄明儒 发表于 2013-9-19 16:41:16

本帖最后由 自贡黄明儒 于 2013-9-26 16:38 编辑

搜一下ACET-STR-REPLACE
(acet-str-replace "." "@" "12.380");返回"12@380"

http://bbs.mjtd.com/thread-107569-1-1.html
(acet-str-replace1 "." "@" "12.380");返回"12@380"

(vl-string-subst "@" "." "12.380");返回"12@380"

004 发表于 2013-9-19 21:21:07

在百度中直接搜索zml84
http://zml84.blog.sohu.com/
关于text对象中单个文字位置的计算
http://zml84.blog.sohu.com/81365320.html


【原创】文字任意位置原位递增，（源码奉献，一个不留）
http://bbs.mjtd.com/forum.php?mod=viewthread&tid=89387&fromuid=251174

香田里浪人 发表于 2013-9-19 22:22:53

试试这个
;;;查找与替换
;;; (reptext <要找的文字> <替换成的文字>)
;;;应用举例:
;;;(SETQ char-A "DRAWING1" char-B "BDYCADCAD")
;;;(reptext char-A char-B)
;;;_______________________________________________________
(defun reptext
             (char-A          char-B    /              pc        ss
                index          ent          typeA   typeA-len        char-Alen
                char-Blen n          char-aa   newsize
             )
(setq pc 0)
(setq ss (ssget '((0 . "TEXT,MTEXT")))) ;选择文字
(if ss
    (progn
      (setq index 0)
      (repeat (sslength ss)
        (setq ent (entget (ssname ss index)))
        (setq index (+ 1 index))
        (setq typeA (cdr (assoc 1 ent))) ;选择的文字内容
        (setq typeA-len (strlen typeA))        ;选择的文字内容的长度
        (setq char-Alen (strlen char-A)) ;取得要找的文字的长度
        (setq char-Blen (strlen char-B)) ;取得替换文字的长度
        (setq n 1)
        (if (= char-A "")
          (setq typeA-len 1)
        )
        (repeat        typeA-len
          (setq char-aa (substr typeA n char-Alen))
                                        ;查找选择的文字内容里是否有要被替换的文字
          (if (= char-aa char-A)
          (progn                        ;如果有
              (setq typeA (vl-string-subst char-B char-A typeA))
              (setq newsize (cons 1 typeA))
              (setq ent (subst newsize (assoc 1 ent) ent))
              (entmod ent)
              (setq pc (1+ pc))
          )
          ;;End progn
          )
          ;;End if
          (setq n (1+ n))
        )
        ;;End repeat
      )
      ;;End repeat
      (princ (strcat "\n替换了" (rtos pc) "个."))
    )
    ;;End progn
)
;;End if
)
;;;_______________________________________________________
(defun c:chtext        (/ cm char-A char-B)
(setq cm (getvar "cmdecho"))
(setvar "cmdecho" 0)
(command "_.UNDO" "Group")
(setq char-A (getstring "\n请输入要查找的文字:"))
(setq char-B (getstring "\n请输入新的文字:"))
(reptext char-A char-B)
(command "_.UNDO" "End")
(setvar "cmdecho" cm)
(princ)
)

BUBUBA918 发表于 2013-9-19 22:51:09

改造一下，输入2.16，提示; 错误: 参数类型错误: lselsetp 2.16
(defun c:rr( / )
(setq pc 0)(SETQ char-A "." char-B "%%132")
(setq ss(getstring t "\n标注文字:"))
; (setq ss (ssget '((0 . "TEXT,MTEXT")))) ;选择文字
(if (/= ss "")
    (progn
      (setq index 0)
      (repeat (sslength ss)
      (setq ent (entget (ssname ss index)))
      (setq index (+ 1 index))
      (setq typeA (cdr (assoc 1 ent))) ;选择的文字内容
      (setq typeA-len (strlen typeA))      ;选择的文字内容的长度
      (setq char-Alen (strlen char-A)) ;取得要找的文字的长度
      (setq char-Blen (strlen char-B)) ;取得替换文字的长度
      (setq n 1)
      (if (= char-A "")
          (setq typeA-len 1)
      )
      (repeat      typeA-len
          (setq char-aa (substr typeA n char-Alen))
                                        ;查找选择的文字内容里是否有要被替换的文字
          (if (= char-aa char-A)
            (progn                        ;如果有
            (setq typeA (vl-string-subst char-B char-A typeA))
            (setq newsize (cons 1 typeA))
            (setq ent (subst newsize (assoc 1 ent) ent))
            (entmod ent)
            (setq pc (1+ pc))
            )
            ;;End progn
          )
          ;;End if
          (setq n (1+ n))
      )
      ;;End repeat
      )
      ;;End repeat
      (princ (strcat "\n替换了" (rtos pc) "个."))
    )
    ;;End progn
)
;;End if
)
(c:rr)

jsh2939 发表于 2013-9-22 21:37:03

顶！！！！！！！！！！！！！！

BUBUBA918 发表于 2013-9-22 21:51:22

论坛上找到一个，改造一下
(defun c:rr ()
   (setq new "%%132"old ".")
   (setq lst(getstring t "\n文字:"))
   (setq ss (read(apply 'vl-string-subst (mapcar 'vl-princ-to-string (list new old lst)))));文字替换
   (setq ss (vl-prin1-to-string ss)) ;格式转换
   (princ ss)
   (princ)
)

灰石Jeremy 发表于 2023-4-17 09:20:32

不错，刚好可以借鉴一下
页: [1]
查看完整版本: 关于如何替换文字中的个别字符？