qianyi0710 发表于 2019-8-11 00:34:17

dist量取的数值距离能否直接ctrl+C粘到其他文档里吗？

本帖最后由 qianyi0710 于 2019-8-11 00:37 编辑

dist量取的数值距离能否直接ctrl+C里面，粘到其他文档里吗？如粘到Excel 里面

mokson 发表于 2019-8-11 07:55:13

不会呀，帮顶。

kozmosovia 发表于 2019-8-11 13:13:00

可以，直接先吧结果复制到剪切板

东升铮 发表于 2019-8-11 23:24:38

;获取剪贴板
(DEFUN GET-CLIP        ()                       
(VLAX-INVOKE
    (VLAX-GET-PROPERTY
      (VLAX-GET        (VLAX-GET-OR-CREATE-OBJECT "HTMLFILE")
                'PARENTWINDOW
      )
      'CLIPBOARDDATA
    )
    'GETDATA
    "TEXT"
)
)
;设置剪贴板
(DEFUN SET-CLIP        (STR)                       
(VLAX-INVOKE
    (VLAX-GET-PROPERTY
      (VLAX-GET (VLAX-CREATE-OBJECT "HTMLFILE") 'PARENTWINDOW)
      'CLIPBOARDDATA
    )
    'SETDATA
    "TEXT"
    STR
)
)
;清空剪贴板
(DEFUN CLS-CLIP        ()                       
(VLAX-INVOKE
    (VLAX-GET-PROPERTY
      (VLAX-GET (VLAX-CREATE-OBJECT "HTMLFILE") 'PARENTWINDOW)
      'CLIPBOARDDATA
    )
    'SETDATA
    "TEXT"
    "ABOUT:BLANK"
)
)
;V-1选择两点返回距离至系统粘贴板、
(DEFUN C:T1 (/ PT1 PT2)
(SETQ PT1 (GETPOINT "****请选择第一个点:"))
(SETQ PT2 (GETPOINT "****请选择第二个点:"))
(SET-CLIP (RTOS(DISTANCE PT1 PT2)))
)
;V-2选择对象返回距离至系统粘贴板、
(DEFUN C:T2 (/ SS ASPT NTPI)
               (setq SS(SSNAME (SSGET) 0));选择对象返回对象图元
               (setq ASPT (CDR (ASSOC 10 (ENTGET SS))));获取对象起点
           (setq NTPT (CDR (ASSOC 11 (ENTGET SS))));获取对象终点
        (SET-CLIP (RTOS(DISTANCE ASPT NTPT)));把数据交至系统粘贴板'
        (PRINT "系统粘贴板已有数据，CTRL+V即可粘贴")
        (PRINC)
)

东升铮 发表于 2019-8-11 23:30:14

;;粘贴板控制函数来源:
;;@JH1005。
如何使用系统粘贴板

qianyi0710 发表于 2019-8-27 22:46:48

东升铮 发表于 2019-8-11 23:24


谢谢{:1_1:}
页: [1]
查看完整版本: dist量取的数值距离能否直接ctrl+C粘到其他文档里吗？