标注样式组码，entmake创建标注样式，应该是目前最全的
本帖最后由 小万LISP 于 2019-10-4 17:26 编辑之前群里发的entmake创建标注样式里的群码不大全，以及 “AutoCAD 群码表.pdf”中关于标注样式的群码几乎不能看，于是晚上折腾了一下，分享出来：
换算单位、公差页 因个人用不着，而且 没咖啡了，我撑不住，太困了，所以群码没测试。
折腾了大晚上，能不能加个分什么的。
1028695446 发表于 2019-11-2 20:48
(defun c:tt(/)
(entmake ;创建标注样式
(list
箭头没法控制楠 本帖最后由 1028695446 于 2020-1-1 19:55 编辑
(defun c:tt(/)
(entmake ;创建标注样式
(list
'(0 . "DIMSTYLE")
'(100 . "AcDbSymbolTableRecord")
'(100 . "AcDbDimStyleTableRecord")
(cons 2 "测试"); 标注样式名
'(176 . 256);线-尺寸线-颜色：256=ByLayer，0=ByBlock，1=红色……
(cons 345 (tblobjname "LTYPE" "Bylayer")) ;线-尺寸线-线型=Bylayer，ByBlock=此项消失…
'(371 . -1) ;线-尺寸线-线宽：ByLayer=-1，ByBlock=此项消失，25=0.25mm…
'(46 . 0) ;线-尺寸线-超出标记 的距离
'(43 . 300) ;线-尺寸线-基线间距
'(281 . 0) ;线-尺寸线-隐藏：尺寸线1，0=显示，1=隐藏
'(282 . 0) ;线-尺寸线-隐藏：尺寸线2，0=显示，1=隐藏
'(177 . 256);线-延申线-颜色：256=ByLayer，0=ByBlock，1=红色……
(cons 346 (tblobjname "LTYPE" "Bylayer")) ;线-延伸线-线型1=Bylayer，ByBlock=此项消失…
(cons 347 (tblobjname "LTYPE" "Bylayer")) ;线-延伸线-线型1=Bylayer，ByBlock=此项消失…
'(372 . -1) ;线-延申线-线宽：ByLayer=-1，ByBlock=此项消失，25=0.25mm…
'(44 . 100) ;线-延申线-超出尺寸线 的距离
'(42 . 150) ;线-延申线-起点偏移量，标注点到延伸线的距离
'(75 . 0) ;线-延申线-隐藏：延伸线1,0=显示，1=隐藏
'(76 . 0) ;线-延申线-隐藏：延伸线2,0=显示，1=隐藏
'(290 . 0) ;线-延申线-固定长度的延伸线，0=不勾选，1=勾选此项
'(49 . 0) ;线-延申线-固定长度的延伸线-长度
'(5 . "ArchTick") ;符号和箭头-箭头-第一个，建筑标记="ArchTick"，空心闭合="ClosedBlank"，实心圆点="Dot"
'(41 . 40) ;符号和箭头-箭头-箭头大小
'(141 . 0) ;符号和箭头-圆心标记，0=无，正数=标记，负数=直线
;'(90 . 0) ;符号和箭头-弧长符号：标注文字的上方=1，无=2，标注文字的前缀=此项消失
(cons 340 (tblobjname "style" "HZ")) ;文字-文字外观-文字样式
'(178 . 7) ;文字-文字外观-文字颜色，256=ByLayer，0=ByBlock，7=白色……
'(69 . 0) ;文字-文字外观-填充颜色类型，0=不填充，1=背景色，2=使用颜色编号
'(70 . 0) ;文字-文字外观-填充颜色，256=ByLayer，0=ByBlock，1红2黄……使用颜色编号时;;;;;;;;;;;;;;;;;;;此项必备
'(140 . 150);文字-文字外观-文字高度
'(77 . 1) ;文字-文字位置-垂直：1=上，0=居中，4=下……
'(280 . 0) ;文字-文字位置-水平：0=居中，1=第一条延伸线……
'(147 . 20) ;文字-文字位置-从尺寸线偏移，填入负数时，“绘制文字边框”项会被勾选
'(73 . 0) ;文字-文字对齐：水平=1，与尺寸线对齐=0，ISO标准=0
'(74 . 0) ;文字-文字对齐：水平=1，与尺寸线对齐=0，ISO标准=1
'(174 . 1);调整-调整选项：文字始终在延伸线之间=1，文字=0，箭头=0，文字和箭头=0，文字或箭头=0
'(289 . 2);调整-调整选项：文字始终在延伸线之间=2，文字=2，箭头=1，文字和箭头=0，文字或箭头=此项消失
'(175 . 0);调整-调整选项-若箭头不能放在延伸线内则将其消除，不勾选=0，勾选=1
'(279 . 2);调整-文字位置：尺寸线上方不带引线=2，尺寸线上方带引线=1，尺寸线旁边=0
'(40 . 1) ;调整-标注特征比例：将标注缩放到布局=0，使用全局比例>0，
'(288 . 0);调整-优化：手动放置文字，不勾选=0，勾选=1
'(172 . 1);调整-优化：在延伸线之间绘制尺寸线，不勾选=0，勾选=1
'(270 . 2);主单位-线性标注-单位格式：科学=1，小数=2，工程=3……
'(271 . 0);主单位-线性标注-精度：0=0，0.0=1，0.00=2…
'(271 . 0);主单位-线性标注-精度：0=0，0.0=1，0.00=2…(不是我重复，组码表就是列出了2个)
'(272 . 0);主单位-线性标注-精度：0=0，0.0=1，0.00=2…
'(144 . 1);主单位-线性标注-测量单位比例
'(78 . 8) ;主单位-线性标注-消零：后续，勾选=8
'(275 . 0);主单位-角度标注-单位格式：十进制=0
'(79 . 2) ;主单位-角度标注-消零：后续，勾选=2
)
)
)
;;;作者将70组码给注释掉了，所以不能正常新建标注样式
核查了一下在线帮助文档中的 DXF参考，2015-2020（除了2016）的都有中文版本。
2002-2014版本提供了pdf文件（英语），部分版本随软件安装文件提供了 中文版本的 pdf。
R13-2000提供了hlp或者htm格式的文件（英语）
这些都是官方提供的文档资料，不需要在其他书里找。
谢谢分享 方便多了 感谢分享！最近正需要这个！ 我的是这样的
;;说明:标注样式表
;;参数:name:文字样式名称
;;参数:global-scale:全局比例
;;参数:Local-scale:局部比例
;;返回:样式表
(defun T-get-dim-style (name global-scale Local-scale / dim-dxf-lst)
(setq dim-dxf-lst (list
;尺寸线
"DIMCLRD" 44 ;为尺寸线、箭头和标注引线指定颜色。
"DIMLTYPE" "BYBLOCK" ;设置尺寸线的线型。值为“BYLAYER”、“BYBLOCK”或线型名称
"DIMLWD" -2 ;为尺寸线指定线宽。 -3 默认值（LWDEFAULT 值） -2 BYBLOCK -1 BYLAYER
"DIMDLE" 0 ;当使用小斜线代替箭头进行标注时，设置尺寸线超出尺寸界线的距离。
"DIMDLI" 0 ;控制基线标注中尺寸线的间距。
"DIMSD1" 0 ;控制是否隐去第一条尺寸线和箭头。设定为打开，将不显示第一条尺寸界线与文字之间的尺寸线和箭头。0显示 1不显示
"DIMSD2" 0 ;控制是否隐去第二条尺寸线和箭头。0显示 1不显示
;尺寸界线
"DIMCLRE" 44 ;为尺寸界线、圆心标记和中心线指定颜色。颜色数显示在“选择颜色”对话框中。对于“BYBLOCK”，输入 0。对于“BYLAYER”，输入 256。
"DIMLTEX1" "BYBLOCK" ;设置第一条尺寸界线的线型。值为“BYLAYER”、“BYBLOCK”或线型名称
"DIMLTEX2" "BYBLOCK" ;设置第二条尺寸界线的线型。值为“BYLAYER”、“BYBLOCK”或线型名称。
"DIMLWE" -2 ;为尺寸界线指定线宽。 -3 默认值（LWDEFAULT 值） -2 BYBLOCK -1 BYLAYER
"DIMSE1" 0 ;控制是否隐去第一条尺寸界线。 0 显示1 不显示
"DIMSE2" 0 ;控制是否隐去第二条尺寸界线。 0 显示1 不显示
"DIMEXE" 1.5 ;指定尺寸界线超出尺寸线的距离。
"DIMEXO" 1.0 ;指定尺寸界线偏离原点的距离。对于固定长度的尺寸界线，此值将决定最小偏移量。
"DIMFXLON" 1 ;控制是否将尺寸界线设定为固定长度。 0 关闭1 打开
"DIMFXL" 5.0 ;设置起始于尺寸线，直至标注原点的尺寸界线总长度。
;剪头
"DIMBLK" "_ARCHTICK" ;设置尺寸线末端显示的箭头块。
; "" 实心闭合
; "_DOT" 点
; "_DOTSMALL" 小点
; "_DOTBLANK" 空心点
; "_ORIGIN" 原点标记
; "_ORIGIN2" 原点标记 2
; "_OPEN" 打开
; "_OPEN90" 直角
; "_OPEN30" 30 度角
; "_CLOSED" 闭合
; "_SMALL" 空心小点
; "_NONE" 无
; "_OBLIQUE" 倾斜
; "_BOXFILLED" 实心框
; "_BOXBLANK" 方框
; "_CLOSEDBLANK" 空心闭合
; "_DATUMFILLED" 实心基准三角形
; "_DATUMBLANK" 基准三角形
; "_INTEGRAL" 完整标记
; "_ARCHTICK" 建筑标记
"DIMSAH" 0 ;控制尺寸线箭头块的显示。 0 使用由 DIMBLK 系统变量设置的箭头块 1 使用由 DIMBLK1 和 DIMBLK2 系统变量设置的箭头块
"DIMBLK1" "_ARCHTICK" ;为尺寸线的第一个端点设置箭头（当 DIMSAH 处于打开状态时）。要恢复默认设置（实心闭合箭头显示），请输入单个句点 (.)。有关箭头列表，请参见 DIMBLK。
"DIMBLK2" "_ARCHTICK" ;为尺寸线的第二个端点设置箭头（当 DIMSAH 处于打开状态时）。要恢复默认设置（实心闭合箭头显示），请输入单个句点 (.)。有关箭头列表，请参见 DIMBLK。
"DIMLDRBLK" "_ARCHTICK" ;指定引线箭头的类型。要恢复默认设置（实心闭合箭头显示），请输入单个句点 (.)。有关箭头列表，请参见 DIMBLK。
"DIMASZ" 1.0 ;控制尺寸线和引线箭头的大小。并控制基线的大小。
; 箭头大小的倍数决定尺寸线和文字是否可以在尺寸界线之间布满。如果 DIMASZ 由 DIMBLK 系统变量设置，那么 DIMASZ 也将用于按比例缩放箭头块。如果 DIMTSZ 系统变量的值非零，那么 DIMASZ 将不起作用。
;圆心标记
"DIMCEN" 1.0 ;通过 DIMCENTER、DIMDIAMETER 和 DIMRADIUS 命令控制圆或圆弧圆心标记以及中心线的绘制。对于 DIMDIAMETER 和 DIMRADIUS，仅当将尺寸线放置到圆或圆弧外部时，才绘制圆心标记。
; 0 不绘制圆心标记和中心线
; <0 绘制中心线
; >0 绘制圆心标记
; 此系统变量的绝对值指定了圆心标记或中心线的大小。
; 中心线的尺寸是指从圆或圆弧的中心标记端点向外延伸的中心线线段的长度，也就是中心标记与中心线起点之间的间隙的大小。
; 中心标记的尺寸是从圆或圆弧的中心到中心标记端点之间的距离。
;折断标注
;"" "";
;弧长符号
"DIMARCSYM" 0 ;控制弧长标注中圆弧符号的显示。
; 0 将弧长符号放在标注文字的前面
; 1 将弧长符号放在标注文字的上方
; 2 不显示弧长符号
;半径折弯标注
"DIMJOGANG" 33 ;决定折弯半径标注中，尺寸线的横向线段的角度。折弯半径标注通常在圆心位于页面外部时创建。有效设置范围为 5 到 90。
;线性折弯标注
;"" "";
;文字外观
"DIMTXSTY" name ;指定标注的文字样式。
"DIMCLRT" 7 ;为标注文字指定颜色。
"DIMTFILL" 1 ;控制标注文字的背景。
; 0 无背景
; 1 图形的背景色
; 2 背景由 DIMTFILLCLR 指定
"DIMTFILLCLR" 0 ;为标注中的文字背景设置颜色。颜色数显示在“选择颜色”对话框中。对于“BYBLOCK”，输入 0。对于“BYLAYER”，输入 256。
"DIMTXT" 2.0 ;指定标注文字的高度（除非当前文字样式具有固定的高度）。
"DIMGAP" 1.0 ;设置当打断尺寸线以符合标注文字时，标注文字周围的距离。
;文字位置
"DIMTAD" 2 ;控制文字相对于尺寸线的垂直位置。
; 0 标注文字在尺寸界线之间居中放置。
; 1 将标注文字放置在尺寸线上方，除非尺寸线不是水平放置的或者尺寸界线内的文字被强制为水平放置 (DIMTIH = 1)。从尺寸线到文字最低基线的距离为当前 DIMGAP 的值。
; 2 将标注文字放在尺寸线远离定义点的一边。
; 3 将标注文字按照日本工业标准 (JIS) 放置。
; 4 将标注文字放在尺寸线下方。
"DIMJUST" 0 ;控制标注文字的水平位置。
; 0 将文字置于尺寸线之上，并在尺寸界线之间置中对正
; 1 紧邻第一条尺寸界线放置标注文字
; 2 紧邻第二条尺寸界线放置标注文字
; 3 将标注文字放在第一条尺寸界线以上，并与之对齐
; 4 将标注文字放在第二条尺寸界线以上，并与之对齐
"DIMTXTDIRECTION" 0 ;指定标注文字的阅读方向。
; 0 从左到右阅读的样式显示标注文字
; 1 从右到左阅读的样式显示标注文字
"" "";
;文字对齐
"DIMTOH" 0 ;控制标注文字在尺寸界线外的位置。
; 0 将文字与尺寸线对齐
; 1 水平绘制文字
"DIMTIH" 0 ;控制所有标注类型（坐标标注除外）的标注文字在尺寸界线内的位置。
; 0 将文字与尺寸线对齐
; 1 水平绘制文字
;调整选项
"DIMATFIT" 3 ;尺寸界线内的空间不足以同时放下标注文字和箭头时，此系统变量将确定这两者的排列方式。
; 0 将文字和箭头均放置于尺寸界线之外
; 1 先移动箭头，然后移动文字
; 2 先移动文字，然后移动箭头
; 3 移动文字和箭头中较合适的一个
; 如果 DIMTMOVE 系统变量设置为 1，将向移动的标注文字添加一条引线
"DIMTIX" 1 ;在尺寸界线之间绘制文字。
; 0 对于线性标注和角度标注，如果有足够的空间，标注文字将放置在尺寸界线的内部。
; 1 在尺寸界线之间绘制标注文字，即使这些文字通常要被放置在尺寸界线之外。对于半径标注和直径标注，启用 DIMTIX 可始终强制将标注文字放置在圆或圆弧外部。
"DIMSOXD" 0 ;如果尺寸界线内没有足够的空间，则隐去箭头。 0 关闭1 打开
; 如果尺寸界线内没有足够的空间并且 DIMTIX 设置为开，则将 DIMSOXD 设置为“开”可不显示箭头。如果 DIMTIX 设定为关，则 DIMSOXD 不起作用。
;文字位置
"DIMTMOVE" 2 ;设置标注文字的移动规则。
; 0 尺寸线和标注文字一起移动
; 1 在移动标注文字时添加一条引线
; 2 允许标注文字自由移动而不用添加引线
;标注特征比例
"DIMSCALE" (if global-scale
global-scale
1
) ;设置应用于标注变量（用于指定尺寸、距离或偏移量）的全局比例因子。
; 0.0 将根据当前模型空间视口和图纸空间两者之间的比例计算出一个合理的默认值。如果当前处于图纸空间或模型空间，但未使用图纸空间的特征，则该比例因子为 1.0。
; >0 将计算出比例因子，使文字大小、箭头大小以及其他按比例缩放的距离均按它们的字面值进行打印。
;优化
"DIMUPT" 0 ;控制用户定位文字的选项。
; 0 光标仅控制尺寸线的位置
; 1 光标控制文字和尺寸线的位置
"DIMTOFL" 1 ;控制是否在尺寸界线之间绘制尺寸线（即使标注文字被放置在尺寸界线之外）。对于半径标注和直径标注，当文字、箭头和引线放置在外部时，会在圆或圆弧的内部绘制尺寸线。
; 0 关闭 如果箭头放置在测量点之外，则不在测量点之间绘制尺寸线
; 1 开 即使箭头放置在测量点之外，也在测量点之间绘制尺寸线
;线性标注
"DIMLUNIT" 2 ;为所有标注类型（角度标注除外）设置单位。
; 1 科学
; 2 小数
; 3 工程
; 4 建筑（始终堆叠显示）
; 5 分数（始终堆叠显示）
; 6 Microsoft Windows 桌面（使用控制面板中的小数分隔符和数字分组符号设置的十进制格式）
"DIMDEC" 2 ;设置标注主单位中显示的小数位数。精度基于选定的单位或角度格式。当 DIMADEC 设定为 -1 时，指定的值将应用于角度标注。
"DIMFRAC" 0 ;设置分数格式（当 DIMLUNIT 设定为 4 [建筑] 或 5 [分数] 时）。
; 0 水平堆叠
; 1 对角堆叠
; 2 非堆叠（例如，1/2）
"DIMDSEP" "." ;指定创建单位格式为小数的标注时要使用的单字符小数分隔符。出现提示时，在命令提示下输入单字符。如果标注单位设定为“小数”，将使用 DIMDSEP 字符，而不是默认的小数点。如果 DIMDSEP 设定为 NULL（默认值，可以通过输入句点“.”来重置），将使用小数点作为标注分隔符。
"DIMRND" 0 ;将所有标注距离舍入为指定值。
; 例如，如果将 DIMRND 设定为 0.25，则所有距离都舍入到 0.25 单位。如果将 DIMRND 设定为 1.0，则所有距离都舍入到最接近的整数。请注意，小数点后的位数取决于由 DIMDEC 系统变量设置的精度。DIMRND 变量不能用于角度标注。
"DIMPOST" "" ;为标注测量值指定文字前缀或后缀（或两者）。
; 例如，要为测量单位“毫米”设置后缀，可将 DIMPOST 设定为“mm”。19.2 个单位的距离会显示为 19.2mm。
; 如果打开了公差，后缀也将应用到公差和主标注中。
; 使用 <> 指示文字相对于标注值的位置。例如，输入 <>mm 可将 5.0 毫米的半径标注显示为“5.0mm”。如果输入 mm <>，标注将显示为“mm 5.0”。角度标注中也可使用 <> 机制。
;测量单位比例
"DIMLFAC" (if Local-scale
Local-scale
1
) ;为线性标注测量值设置比例因子。
; 标注中的所有线性距离（包括半径、直径和坐标）在转换成标注文字前都要乘以 DIMLFAC 的值。DIMLFAC 的正值可应用于模型空间和图纸空间中的标注；负值仅应用于图纸空间的标注。
; DIMLFAC 主要应用于非关联标注（DIMASSOC 设定为 0 或 1）。对于图纸空间中的非关联标注，必须为每一个布局视口单独设置 DIMLFAC 以适应视口比例。
; DIMLFAC 对角度标注无影响，也不应用于系统变量 DIMRND、DIMTM 和 DIMTP 中设置的值。
;消零
"DIMZIN" 8 ;控制针对主单位值的消零处理。值为 0 到 3 时仅影响英尺-英寸标注。DIMZIN 还影响 AutoLISP rtos 和 angtos 函数执行的实数-字符串转换。
; 0 消除零英尺和零英寸
; 1 包含零英尺和零英寸
; 2 包含零英尺，消除零英寸
; 3 包含零英寸，消除零英尺
; 4 消除十进制标注中的前导零（例如，0.5000 变为 .5000）
; 8 消除十进制标注中的后续零（例如，12.5000 变为 12.5）
; 12 消除前导零和后续零（例如，0.5000 变为 .5）
;角度标注
"DIMAUNIT" 0 ;为角度标注设定单位格式。
; 0 十进制度数
; 1 度/分/秒
; 2 百分度
; 3 弧度
"DIMADEC" 2 ;角度标注中显示的精度小数位数。
; -1 角度标注显示由 DIMDEC 指定的小数位数。
; 0-8 指定角度标注中显示的小数位数（与 DIMDEC 无关）
"DIMAZIN" 2 ;针对角度标注进行消零处理。
; 0 显示所有前导零和后续零
; 1 消除十进制标注中的前导零（例如，0.5000 变为 .5000）
; 2 消除十进制标注中的后续零（例如，12.5000 变为 12.5）
; 3 消除前导零和后续零（例如，0.5000 变为 .5）
)
)
) 给你加分，多谢分享了 本帖最后由 小万LISP 于 2019-10-4 07:39 编辑
更新一下 AAAAAAAAAAAAAAAAAAAAAAAAAA 感谢分享 这个可以，正需要，找了很久 dear sir
great........................ 我测试了下，并没有新建 圣天诺杰 发表于 2019-10-4 17:40
我测试了下，并没有新建
可以咯
taoyi0727 发表于 2019-10-4 20:22
我的是这样的
很厉害的而样子, 看不大懂:L