外包矩形老是出错，问题有可能在哪里？
本帖最后由 suiran 于 2023-3-13 20:38 编辑用坐标点做得外包框，有时正确，有时错误，是不是系统参数不对？该怎么设置一下？求指点？
调试发现生成的最大、最小坐标点都没有问题。
(defun c:recl( / ent dxf ptb i minymaxy minx maxx lengthx ss ptb0 ptb1)
(setvar "dimzin" 0)
(prompt "\n<<框选图元：>>")
(if (setq ss (ssget '((0 . "LWPOLYLINE"))))
(progn
(repeat (setq i (sslength ss))
(setq i (1- i))
(setq ent (ssname ss i))
(setq dxf (entget ent))
(setq ptb (mapcar 'cdr (vl-remove-if '(lambda(a)(/= (car a) 10)) dxf))) ;生成坐标值表
(setq ptb (vl-sort ptb '(lambda(a b)
(< (cadr a) (cadr b))))) ;坐标点按y轴从小到大排序
(setq miny (cadr (car ptb))) ;生成y轴最小值
(setq ptb (vl-sort ptb '(lambda(a b)
(> (cadr a) (cadr b))))) ;坐标点按y轴从大到小排序
(setq maxy (cadr (car ptb))) ;生成y轴最大值
(setq ptb (vl-sort ptb '(lambda(a b)
(< (car a) (car b))))) ;坐标点按x轴从小到大排序
(setq minx (car (car ptb))) ;生成x轴最小值
(setq ptb (vl-sort ptb '(lambda(a b)
(> (car a) (car b))))) ;坐标点按x轴从大到小排序
(setq maxx (car (car ptb))) ;生成x轴最大值
(setq lengthx (abs(- maxx minx)));取绝对值生成矩形长度
(setq widthy (abs(- maxy miny)));取绝对值生成矩形宽度
(print miny)
(print maxy)
(print maxx)
(print minx)
(print lengthx)
(print widthy)
(setq ptb0 (list minx miny)) ;生成x轴最小、y轴最小的坐标点
(setq ptb1 (list (+ minx lengthx) (+ miny widthy))) ;生成x轴最大、y轴最大的坐标点
(command "RECTANG" ptb0 ptb1)
;;;;;(entdel ent) ;;;;;;;;;;删除原图元
(princ)
)
)
)
(princ)
)
(command "RECTANG""non" ptb0 "non" ptb1) 飞雪神光 发表于 2023-3-13 20:59
(command "RECTANG""non" ptb0 "non" ptb1)
这是啥意思呢？能说说吧？ "non"相当于 临时关闭捕捉 飞雪神光 发表于 2023-3-13 21:03
"non"相当于 临时关闭捕捉
试了一下，果真有效，谢谢！ 5角星的包围框倒是第一次见
(defun c:tt ()
(prompt "\n框选图元: ")
(setq i -1)
(if (setq ss (ssget))
(while (setq s1 (ssname ss (setq i (1+ i))))
(vla-getboundingbox (vlax-ename->vla-object s1) 'aa 'bb)
(setq p1 (vlax-safearray->list aa)p9 (vlax-safearray->list bb))
(command "RECTANG" "non" p1 "non" p9)
)
)
(princ)
)
xyp1964 发表于 2023-3-14 20:15
，学艺不精，理解能力还没有达到这一步，不过确实简洁。
页:
[1]