取得当前日期
本帖最后由 尘缘一生 于 2024-6-25 03:38 编辑画图，经常需要以下两处改、写，很多时候，我们并不需要精确到小时，分钟，当然，程序你自己简单修改即可了。
能方便一点就方便一点，为此，做一下代码。
;三领设计 V3.0
;modify by 尘缘一生QQ：15290049
;;简体、繁体、英文提示---(一级)-----
;;msg1 简体字 nilmsg2 繁体字 nil msg3 英文 nil--
(defun slmsg (msg1 msg2 msg3 / msg)
(cond
((= $Lgver 1)
(setq msg msg1)
)
((= $Lgver 2) ;繁体版
(setq msg msg2)
)
((= $Lgver 3)
(setq msg msg3)
)
)
msg ;;输出信息
)
;;字符串转表,中英文拆分为单独文字表-----(一级)------
;(sl-str->singleonly "12我 的\n三领设计#$%文字@789") ("1" "2" "我" " " "的" "\n" "三" "领" "设" "计" "#" "$" "%" "文" "字" "@" "7" "8" "9")
(defun sl-str->singleonly (str / a)
(setq str (vl-string->list str))
(while
(if (< (car str) 129)
(setq a (cons (chr (car str)) a) str (cdr str))
(setq a (cons (strcat (chr (car str)) (chr (cadr str))) a) str (cddr str))
)
)
(reverse a)
)
;;字符串以旧换新----(一级)----
;;(t-string-subst "毛" "a" "abc")->"毛bc"
(defun t-string-subst (new old str / n)
(setq n (- (strlen new)))
(while (setq n (vl-string-search old str (min (+ n (strlen new)) (strlen str))))
(setq str (vl-string-subst new old str n))
)
str
)
;;字符串转表 str 字符串 sign 分割符号----(一级)---------
;;(str->lst "1 2 3 4" " ")->("1" "2" "3" "4")
;;(str->lst "毛泽东;88;xy;z" ";")->("毛泽东" "88" "xy" "z")
;;(str->lst "毛泽东;88;xy;z" "泽东")->("毛" ";88;xy;z")
(defun str->lst (str sign / lst n1 n2 str_1 m2)
(setq lst '())
(setq n1 (strlen str))
(setq n2 (strlen sign))
(while (setq m2 (vl-string-search sign str))
(setq str_1 (substr str 1 m2))
(setq str (substr str (+ 1 m2 n2)))
(if (/= str_1 "")
(setq lst (cons str_1 lst))
)
)
(if (/= str "")
(setq lst (cons str lst))
)
(reverse lst)
)
;CAD版本判定---阉割部分(三领)
(defun cadsys ()
(setq k1 (getvar "SYSCODEPAGE")) ;显示所在地区的代码
(cond
((= k1 (strcase "ansi_936")) ;;CAD是简体版
(setq $Lgver 1)
)
((= k1 (strcase "ansi_950")) ;繁体版
(setq $Lgver 2)
)
((and (/= k1 (strcase "ansi_936")) (/= k1 (strcase "ansi_950"))) ;;英文或其他版
(setq $Lgver 3)
)
)
)
;;数字字符串转汉字字符串----(一级)---
(defun numstr->chinastr (str / s lis0 lis)
(cadsys)
(setq lis0 (sl-str->singleonly str))
(while lis0
(setq s (car lis0))
(cond
((= s "0")
(setq lis (cons (slmsg "零" "箂" "Zero") lis))
)
((= s "1")
(setq lis (cons (slmsg "一" "" "One") lis))
)
((= s "2")
(setq lis (cons (slmsg "二" "" "Two") lis))
)
((= s "3")
(setq lis (cons (slmsg "三" "" "Three") lis))
)
((= s "4")
(setq lis (cons (slmsg "四" "" "four") lis))
)
((= s "5")
(setq lis (cons (slmsg "五" "き" "Five") lis))
)
((= s "6")
(setq lis (cons (slmsg "六" "せ" "Six") lis))
)
((= s "7")
(setq lis (cons (slmsg "七" "" "Seven") lis))
)
((= s "8")
(setq lis (cons (slmsg "八" "" "Eight") lis))
)
((= s "9")
(setq lis (cons (slmsg "九" "" "Nine") lis))
)
(t
(setq lis (cons s lis))
)
)
(setq lis0 (cdr lis0))
)
(apply 'strcat (reverse lis))
)
;;数字字符串转汉字字符串----(一级)---(备用)
(defun chinastr->numstr (str / s lis0 lis)
(cadsys)
(setq lis0 (sl-str->singleonly str))
(while lis0
(setq s (car lis0))
(cond
((= s (slmsg "零" "箂" "Zero"))
(setq lis (cons "0" lis))
)
((= s (slmsg "一" "" "One"))
(setq lis (cons "1" lis))
)
((= s (slmsg "二" "" "Two"))
(setq lis (cons "2" lis))
)
((= s (slmsg "三" "" "Three"))
(setq lis (cons "3" lis))
)
((= s (slmsg "四" "" "four"))
(setq lis (cons "4" lis))
)
((= s (slmsg "五" "き" "Five"))
(setq lis (cons "5" lis))
)
((= s (slmsg "六" "せ" "Six"))
(setq lis (cons "6" lis))
)
((= s (slmsg "七" "" "Seven"))
(setq lis (cons "7" lis))
)
((= s (slmsg "八" "" "Eight"))
(setq lis (cons "8" lis))
)
((= s (slmsg "九" "" "Nine"))
(setq lis (cons "9" lis))
)
(t
(setq lis (cons s lis))
)
)
(setq lis0 (cdr lis0))
)
(apply 'strcat (reverse lis))
)
;;取当前年月字符串--(一级)----
;;返回("2024年,6月" "二零二四年")
(defun curdata (/ slis str1 str2)
(cadsys)
(setq slis (str->lst (menucmd "m=$(edtime,$(getvar,DATE),YYYY-MO)") "-"))
(setq str1 (strcat (car slis) (slmsg "年" "" "Year"))) ;"2024年"
(setq str2 (t-string-subst "" "0" (strcat (cadr slis) (slmsg "月" "る" "Month")))) ;"6月"
(list (strcat str1 "," str2) (strcat (numstr->chinastr str1) (numstr->chinastr str2))) ;("2024年,6月" "二零二四年六月")
)
;;--------------------
;测试
(defun c:tt ()
(curdata)
)三领设计 V3.0 永久下载地址：
链接：https://pan.baidu.com/s/1W1NbdKNaLzNx6W9TDek-7Q
提取码：nuzq
下面展示《三领设计 V3.0》对这一问题的综合应用，由于涉及众多的集成函数，就不一一列出，
同时也一并展示了：DCL写法的综合性，仅作参考吧。
由于不画英文图纸，希望英文部分，谁发现字词不对，提出来。
;三领设计 V3.0
;modify by 尘缘一生QQ：15290049
;;改、写汉字函数【开始】------(一级)--------
;;s2 初始字符 "" ; nam0 初始目标文字 nil 若存在，则修改内容为 s2 ; K t 单独取s2 nil 修改nam0 为s2
;;返回s2 并返回 $txthi字符串ang字符串h0 ang0 sty ly tcol 全局变量
(defun sl-xhz (s2 nam0 k / s wid ent tp reg e ee nam dcl_id files p0 tmptxt linx kk lst str)
(defun getdt ()
(setq h0 (atof (get_tile "tileh")))
(setq ang0 (sl-d2r (atof (get_tile "tilea"))))
(setq sty (get_tile "tile7"))
(setq s2 (get_tile "tile0"))
)
;---------
(defun drawcl ()
(set_tile "color"
(cond
((= (strlen (itoa tcol)) 1) (strcat str " " (itoa tcol)))
((= (strlen (itoa tcol)) 2) (strcat str " " (itoa tcol)))
((= (strlen (itoa tcol)) 3) (strcat str " " (itoa tcol)))
)
)
)
;---------
(defun do1 ()
(setq s2 (car (curdata)))
(set_tile "tile0" s2)
)
;---------
(defun do2 ()
(setq s2 (cadr (curdata)))
(set_tile "tile0" s2)
)
;---------
(if (or (= $txthi nil) (not (equal (type $txthi) 'str))) (setq $txthi (rtos (* slbl 5.0) 2 0)))
(if (or (= ang nil) (not (equal (type ang) 'str))) (setq ang "0"))
(if (or (= sty nil) (not (equal (type sty) 'str))) (setq sty $hz))
(if (or (= ly nil) (not (equal (type ly) 'str))) (setq ly "PUB_TEXT"))
(if (or (= tcol nil) (not (equal (type tcol) 'int))) (setq tcol 7))
(if (/= nam0 nil) (setq ent (entget nam0) tp (dxf1 ent 0)))
(setq kk (strcat "1:" (rtos (cadr (getslbl)) 2 0)) s "")
(setq reg 3 str (slmsg "当前:" "讽玡:" "Current:"))
(while (> reg 2)
(setq wid (strlen s2))
(if (< wid 20) (setq wid 20))
(setq wid (rtos wid 2 0))
(setq dcl_id (load_dialog (xhz-dcl wid)))
(new_dialog "xhz1" dcl_id)
(set_tile "blstr" kk)
(set_tile "tile0" s2)
(set_tile "tilea" ang)
(set_tile "tileh" $txthi)
(set_tile "tile7" sty)
(drawdcl "color" tcol)
(drawcl)
(action_tile "tile0" "(getdt)")
(action_tile "qk" "(setq s \"\" s2 \"\") (set_tile \"tile0\" \"\")")
(action_tile "tile1" "(setq $txthi (rtos (* slbl 3.0) 2 0)) (set_tile \"tileh\" (rtos (* slbl 3.0) 2 0))")
(action_tile "tile12" "(setq $txthi (rtos (* slbl 5.0) 2 0)) (set_tile \"tileh\" (rtos (* slbl 5.0) 2 0))")
(action_tile "tile2" "(setq $txthi (rtos (* slbl 8.0) 2 0)) (set_tile \"tileh\" (rtos (* slbl 8.0) 2 0))")
(action_tile "tile3" "(setq $txthi (rtos (* slbl 4.0) 2 0)) (set_tile \"tileh\" (rtos (* slbl 4.0) 2 0))")
(action_tile "shiqu" "(done_dialog 13)")
(action_tile "queshe" "(done_dialog 14)")
(action_tile "qc" "(done_dialog 15)")
(action_tile "tile4" "(done_dialog 4)")
(action_tile "color" "(setq tcol (sl-c-num tcol))(drawdcl $key tcol)(drawcl)")
(action_tile "tile13" "(setq ang \"0\") (set_tile \"tilea\" \"0\")")
(action_tile "tile5" "(setq ang \"90\") (set_tile \"tilea\" \"90\")")
(action_tile "tile6" "(setq ang \"-90\") (set_tile \"tilea\" \"-90\")")
(action_tile "tile8" "(setq sty \"hz\") (set_tile \"tile7\" \"hz\")")
(action_tile "tile9" "(setq sty \"xz\") (set_tile \"tile7\" \"xz\")")
(action_tile "tile10" "(setq sty \"fan\") (set_tile \"tile7\" \"fan\")")
(action_tile "tile11" "(setq sty \"songti\") (set_tile \"tile7\" \"songti\")")
(action_tile "tile26" "(setq s2 (strcat \"%%p\" \"0.000\")) (set_tile \"tile0\" (strcat \"%%p\" \"0.000\"))")
(action_tile "tile53" "(setq s2 (slmsg \"现场\" \"瞷初\" \"On site\")) (set_tile \"tile0\" (slmsg \"现场\" \"瞷初\" \"On site\"))")
(action_tile "tile54" "(setq s2 (slmsg \"中心\" \"いみ\" \"Core\")) (set_tile \"tile0\" (slmsg \"中心\" \"いみ\" \"Core\"))")
(action_tile "tile57" "(do1)")
(action_tile "tile58" "(do2)")
(action_tile "tilec""(done_dialog 5)")
(action_tile "tilepm" "(done_dialog 6)")
(action_tile "tilelp" "(done_dialog 7)")
(action_tile "tilezb" "(done_dialog 8)")
(action_tile "tile50" "(getdt) (done_dialog 9)") ;读入txt
(action_tile "tile51" "(done_dialog 11)")
(action_tile "chbl" "(done_dialog 12)")
(action_tile "dq" "(done_dialog 16)") ;点取
(action_tile "accept" "(getdt) (done_dialog 1)")
(action_tile "cancel" "(done_dialog 0)")
(setq reg (start_dialog))
(slunloaddcl dcl_id)
(cond
((= reg 4)
(setq e (car (setq ee (nentsel (slmsg "\n 请选择实体【定角度】:" "\n 叫匡拒龟砰﹚à:" "\n Please select an entity :")))))
(setq ang (rtos (sl-r2d (e-ang e (cadr ee)))))
)
((= reg 5)
(dclxz s2) ;;返回 s
(setq s2 (strcat s2 s))
)
((= reg 6)
(dclpm) ;此处转嵌套DCL,余同
(setq s2 (strcat s2 s))
)
((= reg 7)
(dcllp)
(setq s2 (strcat s2 s))
)
((= reg 8)
(dclzb)
(setq s2 (strcat s2 s))
)
((= reg 9) ;读入TXT
(setq s2 "")
(vla-put-WindowState *Acad* 2);;CAD窗口最小化
(setq files (sl-choose-files "" "txt;*.doc" (getvar "DWGPREFIX")))
(vla-put-WindowState *Acad* 1);;CAD窗口最大化
(setq p0 (getpoint (slmsg "\n 文字块插入点:" "\n ゅ遏础翴:" "\n Text Block Insertion Point:")))
(while files
(if (/= (setq tmptxt (open (car files) "R")) nil)
(progn
(while (setq linx (read-line tmptxt))
(entmake (list '(0 . "TEXT") (cons 1 linx) (cons 10 p0) (cons 50 ang0) (cons 40 h0) (cons 62 tcol) (cons 7 sty) (cons 41 0.7) (cons 8 ly)))
(setq p0 (polar p0 (+ ang0 3pi2) (* 1.5 h0)))
)
(close tmptxt)
)
)
(setq files (cdr files))
)
)
((= reg 10)
(setq s2 "")
)
((= reg 11)
(setq s2 "")
(c:cad2txt)
)
((= reg 12)
(htbl)
(setq kk (strcat "1:" (rtos (cadr (getslbl)) 2 0)))
)
((= reg 13) ;拾取参数
(setq nam (car (entsel (slmsg "\n 拾取文字类实体:" "\n 珺ゅ摸龟砰:" "\n Pick text entities:"))))
(setq $txthi (rtos (e-higt nam) 2 2) ang (rtos (sl-r2d (e-ang nam nil))) sty (dxf1 nam 7) ly (dxf1 nam 8) tcol (dxf1 nam 62))
)
((= reg 14) ;缺省
(setq $txthi (rtos (* slbl 5.0) 2 0) ang "0" sty $hz ly "PUB_TEXT" tcol 7)
)
((= reg 15) ;词库
(setq s2 (strcat s2 (sl-qc)))
)
((= reg 16) ;点取
(setq nam (car (entsel (slmsg "\n 拾取文字类实体:" "\n 珺ゅ摸龟砰:" "\n Pick text entities:"))))
(setq s2 (getstr nam))
)
)
)
(if (and (/= s2 "") (= nam0 nil) (= k nil)) ;新写出
(progn
(setq p0 (cadr (grread 5)))
(entmake (list '(0 . "TEXT") (cons 1 s2) (cons 10 p0) (cons 50 ang0) (cons 40 h0) (cons 62 tcol) (cons 7 sty) (cons 41 0.7) (cons 8 ly)))
(setq nam (entlast))
(sldomov nam p0 t)
(setq lst (maxtxbox (txbox nam nil)))
(if (ssget "C" (car lst) (caddr lst) '((0 . "LINE,ARC,*P*LINE")))
(progn
(entdel nam)
(dgnxj-w (car lst) (caddr lst))
(entdel nam)
)
)
)
)
(if (and (/= s2 "") (/= nam0 nil) (= k nil)) ;修改
(ch-txtsys nam0 s2 h0 sty ang0 ly tcol)
)
s2
)
;;(xhz-dcl "20")---------
(defun xhz-dcl (wid / lst_str)
(setq lst_str
(append
(list
"xhz1:dialog {"
(slmsg
"label=\"三领设计 V3.0 文字系统 \";"
"label=\"烩砞璸 V3.0 ゅ╰参 \";"
"label=\"Sldesign V3.0 Writing System \";"
)
"initial_focus=tile0;"
$row
$boxed_row
(slmsg "label=\"键入文字:\";" "label=\"ゅ= :\";" "label=\"Text is= :\";")
(strcat ":button{label=\"" (slmsg "<-点取" "<-翴" "<-Pickup") "\"; key=\"dq\";}")
":edit_box {key=\"tile0\";allow_accept=true;"
(strcat "edit_width=" wid ";")
"}"
(strcat ":button{label=\"" (slmsg "清空->" "睲->" "Clear->") "\"; key=\"qk\";}")
"}"
$boxed_row
(slmsg "label=\"当前比例\";" "label=\"讽玡ゑㄒ\";" "label=\"Current scale\";")
(slmsg ":text{label=\"比例\";}" ":text{label=\"ゑㄒ\";}" ":text{label=\"Scale\";}")
":text{key=\"blstr\";is_bold=true;value=\"0.0000\";width=6;} "
(strcat ":button{label=\"" (slmsg "换比" "传ゑ" "Chang Scale") "\"; key=\"chbl\";}")
"}"
"}"
$boxed_row
)
(cond
((= $Lgver 1) ;简体版
(list
"label=\"智能组词\";"
":button {label=\"<-词库\";key=\"qc\";}"
":button {label=\"<-字符\";key=\"tilec\";}"
":button {label=\"<-平\";key=\"tilepm\";}"
":button {label=\"<-立剖\";key=\"tilelp\";}"
":button {label=\"<-更多\";key=\"tilezb\";}"
"}"
$boxed_row
"label=\"独取单词\";"
":button {label=\"±0.000\";key=\"tile26\";}"
":button {label=\"现场\";key=\"tile53\";}"
":button {label=\"中心\";key=\"tile54\";}"
(strcat ":button {label=\"" (car (curdata)) "\";key=\"tile57\";}")
(strcat ":button {label=\"" (cadr (curdata)) "\";key=\"tile58\";}")
"}"
$boxed_row
"label=\"文字参数\";"
$boxed_column
"label=\"字高\";"
(strcat ":edit_box {key=\"tileh\";value=\"" $txthi "\"" ";}")
(strcat ":radio_button {label=\"" (rtos (* slbl 3.0) 2 0) "\";key=\"tile1\";}") ;注意，此处整合三领系统的比例系统
(strcat ":radio_button {label=\"" (rtos (* slbl 4.0) 2 0) "\";key=\"tile3\";}")
(strcat ":radio_button {label=\"" (rtos (* slbl 5.0) 2 0) "\";key=\"tile12\";}")
(strcat ":radio_button {label=\"" (rtos (* slbl 8.0) 2 0) "\";key=\"tile2\";}")
"}"
$boxed_column
"label=\"字角度\";"
":edit_box {key=\"tilea\";value=\"0\";}"
":radio_button {label=\"0\";key=\"tile13\";}"
":radio_button {label=\"90\";key=\"tile5\";}"
":radio_button {label=\"-90\";key=\"tile6\";}"
":radio_button {label=\"<-取角\";key=\"tile4\";}"
"}"
$boxed_column
"label=\"文字字型\";"
":edit_box {key=\"tile7\";value=\"hz\";}"
":radio_button {label=\"细体字\";key=\"tile8\";is_default=true;}"
":radio_button {label=\"空心字\";key=\"tile9\";}"
":radio_button {label=\"宋体字\";key=\"tile11\";}"
":radio_button {label=\"繁体字\";key=\"tile10\";}"
"}"
$boxed_column
"label=\"参数设置\";"
":button{label=\"<-拾取\"; key=\"shiqu\";}"
":button{label=\"缺省\"; key=\"queshe\";}"
":text{label=\" 颜色\";}"
":image_button {height=1;key=\"color\";width=1.5;}"
)
)
((= $Lgver 2) ;繁体版
(list
"label=\"醇舱迭\";"
":button {label=\"<-迭畐\";key=\"qc\";}"
":button {label=\"<-才\";key=\"tilec\";}"
":button {label=\"<-キ\";key=\"tilepm\";}"
":button {label=\"<-ミ\";key=\"tilelp\";}"
":button {label=\"<-\";key=\"tilezb\";}"
"}"
$boxed_row
"label=\"縒虫迭\";"
":button {label=\"∮0.000\";key=\"tile26\";}"
":button {label=\"瞷初\";key=\"tile53\";}"
":button {label=\"いみ\";key=\"tile54\";}"
(strcat ":button {label=\"" (car (curdata)) "\";key=\"tile57\";}")
(strcat ":button {label=\"" (cadr (curdata)) "\";key=\"tile58\";}")
"}"
$boxed_row
"label=\"ゅ把计\";"
$boxed_column
"label=\"蔼\";"
(strcat ":edit_box {key=\"tileh\";value=\"" $txthi "\"" ";}")
(strcat ":radio_button {label=\"" (rtos (* slbl 3.0) 2 0) "\"" ";key=\"tile1\";}")
(strcat ":radio_button {label=\"" (rtos (* slbl 4.0) 2 0) "\"" ";key=\"tile3\";}")
(strcat ":radio_button {label=\"" (rtos (* slbl 5.0) 2 0) "\"" ";key=\"tile12\";}")
(strcat ":radio_button {label=\"" (rtos (* slbl 8.0) 2 0) "\"" ";key=\"tile2\";}")
"}"
$boxed_column
"label=\"à\";"
":edit_box {key=\"tilea\";value=\"0\";}"
":radio_button {label=\"0\";key=\"tile13\";}"
":radio_button {label=\"90\";key=\"tile5\";}"
":radio_button {label=\"-90\";key=\"tile6\";}"
":radio_button {label=\"<-à\";key=\"tile4\";}"
"}"
$boxed_column
"label=\"ゅ\";"
":edit_box {key=\"tile7\";value=\"hz\";}"
":radio_button {label=\"灿砰\";key=\"tile8\";is_default=true;}"
":radio_button {label=\"み\";key=\"tile9\";}"
":radio_button {label=\"Ш砰\";key=\"tile11\";}"
":radio_button {label=\"羉砰\";key=\"tile10\";}"
"}"
$boxed_column
"label=\"把计砞竚\";"
":button{label=\"<-珺\"; key=\"shiqu\";}"
":button{label=\"\"; key=\"queshe\";}"
":text{label=\" 肅︹\";}"
":image_button {height=1;key=\"color\";width=1.5;}"
)
)
((= $Lgver 3) ;英文版CAD
(list
"label=\"Intelligent group words\";"
":button {label=\"<-Thesaurus\";key=\"qc\";}"
":radio_button {label=\"<-Character\";key=\"tilec\";}"
":radio_button {label=\"<-Plane\";key=\"tilepm\";}"
":radio_button {label=\"<-Vertical\";key=\"tilelp\";}"
":radio_button {label=\"<-More\";key=\"tilezb\";}"
"}"
$boxed_row
"label=\"Independent Words\";"
":button {label=\"±0.000\";key=\"tile26\";}"
":button {label=\"Scene\";key=\"tile53\";}"
":button {label=\"Core\";key=\"tile54\";}"
(strcat ":button {label=\"" (car (curdata)) "\";key=\"tile57\";}")
(strcat ":button {label=\"" (cadr (curdata)) "\";key=\"tile58\";}")
"}"
$boxed_row
"label=\"Text parameters\";"
$boxed_column
"label=\"Text height\";"
(strcat ":edit_box {key=\"tileh\";value=\"" $txthi "\"" ";}")
(strcat ":radio_button {label=\"" (rtos (* slbl 3.0) 2 0) "\"" ";key=\"tile1\";}")
(strcat ":radio_button {label=\"" (rtos (* slbl 4.0) 2 0) "\"" ";key=\"tile3\";}")
(strcat ":radio_button {label=\"" (rtos (* slbl 5.0) 2 0) "\"" ";key=\"tile12\";}")
(strcat ":radio_button {label=\"" (rtos (* slbl 8.0) 2 0) "\"" ";key=\"tile2\";}")
"}"
$boxed_column
"label=\"Text Angle\";"
":edit_box {key=\"tilea\";value=\"0\";}"
":radio_button {label=\"0\";key=\"tile13\";}"
":radio_button {label=\"90\";key=\"tile5\";}"
":radio_button {label=\"-90\";key=\"tile6\";}"
":radio_button {label=\"<-Get angle\";key=\"tile4\";}"
"}"
$boxed_column
"label=\"Text Fonts\";"
":edit_box {key=\"tile7\";value=\"hz\";}"
":radio_button {label=\"Single-line-Text\";key=\"tile8\";is_default=true;}"
":radio_button {label=\"Hollow Text\";key=\"tile9\";}"
":radio_button {label=\"Song Text\";key=\"tile11\";}"
":radio_button {label=\"BIG5 Text\";key=\"tile10\";}"
"}"
$boxed_column
"label=\"Parameter setting\";"
":button{label=\"<-Pickup\"; key=\"shiqu\";}"
":button{label=\"Default\"; key=\"queshe\";}"
":text{label=\" Color\";}"
":image_button {height=1;key=\"color\";width=1.5;}"
)
)
)
(list "}}" $row
(strcat ":button{label=\"" (slmsg "读入<-txt文件" "弄<-txtゅン" "Read in<-txt file") "\"; key=\"tile50\";}")
$okbt $canbt
(strcat ":button{label=\"" (slmsg "写出->txt文件" "糶->txtゅン" "Output->txt file") "\"; key=\"tile51\";}")
"}}"
)
)
)
(dcl2lisp lst_str)
)
你要做这个的话,很快就想着多线程开图然后修改时间了.
然后多线程检查目录纸张数量和目录是否匹配.
真是心痒痒呢... 你有种再说一遍 发表于 2024-6-25 02:43
你要做这个的话,很快就想着多线程开图然后修改时间了.
然后多线程检查目录纸张数量和目录是否匹配.
真是 ...
对于一套建筑图，基本不多，因此没作这个，加之这个涉及属性吧？
多线程的问题也还没有涉及。 你有种再说一遍 发表于 2024-6-25 02:43
你要做这个的话,很快就想着多线程开图然后修改时间了.
然后多线程检查目录纸张数量和目录是否匹配.
真是 ...
哈哈，他这个不如直接点一个现有的日期文字替换成当前的日期，更快一步 本帖最后由 尘缘一生 于 2024-6-25 10:56 编辑
lxl217114 发表于 2024-6-25 08:56
哈哈，他这个不如直接点一个现有的日期文字替换成当前的日期，更快一步
对啊，就是如此，存在的即改，不存在的就写出。做不到如此，二开就没啥意思了。 三领的dcl界面做的审美在线，工整，优雅。 大赞，我是用属性+字段 字段，自动更新，这几百句了。 thanks for sharing
页:
[1]