社区 › AutoLISP/Visual LISP 编程技术 › 怎么可以框选将红色线与绿色连接起来？

277283904 发表于 2024-7-26 19:48:51

怎么可以框选将红色线与绿色连接起来？

J键好像要一条条点选才能连接吧？

tanshiyu2001 发表于 2024-7-27 13:07:53

;;;;;框选共线直线并批量连接:ZXX
;返回共线四点最远2点
(defun maxlong (p1 p2 p3 p4)
(setq ptlst '(p1 p2 p3 p4))
(setq n '())
(setq i -1)
(while (setq a (nth (setq i (1+ i)) ptlst)) ;返回表的第N个元素
    (setq b (cdr (member a ptlst)))      ;返回a后面的剩余元素,包括a,并去掉a的表
    (setq n (append (mapcar '(lambda (x) (list a x)) b) n))
)
(setq
    a1 (mapcar '(lambda      (x)
                  (list      (distance (vl-symbol-value (car x))
                                  (vl-symbol-value (cadr x))
                        )
                        x
                  )
                )
               (reverse n)
       )
)
(setq a2 (vl-sort a1 '(lambda (x y) (> (car x) (car y)))))
(setq a3 (car a2))
(setq a4 (cadr a3))
)
;检测3点是否共线
(defun pppl (pp1 pp2 pp3)
(setq dis1 (distance pp1 pp2))
(setq dis2 (distance pp2 pp3))
(setq dis3 (distance pp1 pp3))
(if (or (<= (abs (- dis1 (+ dis2 dis3))) 0.000001)
          (<= (abs(- dis2 (+ dis1 dis3))) 0.000001)
          (<= (abs(- dis3 (+ dis2 dis1))) 0.000001)

      )
    1
    nil
)

)

;框选共线直线并批量连接
(defun C:ZXX (/ ss flag n1 n2 ln1 pn1 p1 p2 la ln2 pn2 p3 p4 pp px1 px2 lk la)
(command "._UNDO" "_BEGIN")
(princ "\n框选共线直线并批量连接,请选择对象:")
(setq ss (ssget '((0 . "LINE"))))
                                        ;(setq sn (sslength ss))
(setq flag 0)                              ;选择集变动标志
(setq n1 0)
(while (< n1 (sslength ss))                ;读取选择集图元数量
    (setq n2 (+ n1 1))
    (while (< n2 (sslength ss))
      (setq ln1 (ssname ss n1))                ;把选择集第一个图元名赋给变量ln
      (setq pn1 (entget ln1))                ;获取图原名的定义数据
      (setq p1 (cdr (assoc 10 pn1)))      ;直线起点
      (setq p2 (cdr (assoc 11 pn1)))      ;直线终点
      (setq la (assoc 8 pn1))         ;直线所在图层
      (setq ln2 (ssname ss n2))
      (setq pn2 (entget ln2))
      (setq p3 (cdr (assoc 10 pn2)))      ;直线起点
      (setq p4 (cdr (assoc 11 pn2)))      ;直线终点
      (if (and (pppl p1 p2 p3) (pppl p1 p2 p4))
                                        ;判断4点共线
      (progn
          (setq pp (maxlong p1 p2 p3 p4)) ;返回共线4点中距离最远的2点
          (setq      px1 (vl-symbol-value (car pp)) ;第1点
                px2 (vl-symbol-value (cadr pp)) ;第2点
          )
          (setq
            lk (entmakex
               (list '(0 . "LINE") (cons 10 px1) la (cons 11 px2))
               )
          )                              ;生成1到2的直线
          (entdel ln1)                        ;删除共线直线lm
          (entdel ln2)                        ;删除共线直线ln
          (ssdel ln1 ss)                ;删除选择集中共线图元lm
          (ssdel ln2 ss)                ;删除选择集中共线图元ln
          (ssadd lk ss)                        ;增加新生成直线到选择集末尾
          (setq flag 1)
      )
      )
      (if (= flag 1)
      (progn
          (setq n2 (+ n1 1))
          (setq flag 0)
      )
      (setq n2 (+ n2 1))
      )
    )
    (setq n1 (+ n1 1))
)
(command "._UNDO" "_END")
(princ)
)

pzweng 发表于 2024-7-27 13:28:28

(defun c:myj (/ ss n)
(setq ss (setq ss (ssget)))
(setq n (sslength ss))
(setvar 'cmdecho 0)
(repeat n (command ".join" (ssname ss (setq n (1- n))) ss ""))
(princ)
)

277283904 发表于 2024-7-29 08:22:58

qazxswk 发表于 2024-7-28 22:02
如果按楼主画的，左右两边共6条线，共3组线，用tanshiyu2001网友的代码，可以一次性选中，并完成连接，如果 ...

不用一组一组，直接框选6条线就可以连接起来了

你有种再说一遍 发表于 2024-7-26 20:24:43

向量一致,延伸后删除线2.

277283904 发表于 2024-7-26 20:35:46

不会写代码{:1_1:}

迷失1786 发表于 2024-7-26 21:02:43

等高手出现{:1_1:}

`中微子 发表于 2024-7-26 21:18:17

本帖最后由 `中微子 于 2024-7-26 21:20 编辑

亲测,用CAD2024可以用J连接.可以框选.
噢,不能多组线一起.

自贡黄明儒 发表于 2024-7-26 22:01:16

Overkill也行的

tanshiyu2001 发表于 2024-7-27 13:09:16

我这也是找的

pzweng 发表于 2024-7-27 13:30:02

tanshiyu2001 发表于 2024-7-27 13:07
;;;;;框选共线直线并批量连接:ZXX
;返回共线四点最远2点
(defun maxlong (p1 p2 p3 p4)


你这个搞复杂了

查看完整版本: 怎么可以框选将红色线与绿色连接起来？