社区 › 源码共享 › 分享一个反转轻量多段线的函数

hubeiwdlue 发表于 2025-2-20 15:31:24

分享一个反转轻量多段线的函数

本帖最后由 hubeiwdlue 于 2025-3-22 19:20 编辑

;; 功能：反转轻量多段线
;; 参数：ent - LWPOLYLINE图元名
;; 返回：成功返回图元名，失败返回nil
(defun ReverseLWPolyline (ent / bulgelist coord elist lineweight1 lineweight2 newbulge newcoord newlineweight1 newlineweight2 newz91 z91)
    (if (eq (cdr (assoc 0 (entget ent))) "LWPOLYLINE")
      (progn
      (setq elist (entget ent))
      (setq coord (vl-remove-if-not '(lambda (x) (= (car x) 10)) elist))
      (setq lineweight1 (vl-remove-if-not '(lambda (x) (= (car x) 40)) elist))
      (setq lineweight2 (vl-remove-if-not '(lambda (x) (= (car x) 41)) elist))
      (setq bulgeList (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 42)) elist)))
      (setq z91 (vl-remove-if-not '(lambda (x) (= (car x) 91)) elist))
      (setq newCoord (reverse coord))
      (setq newlineweight1 (mapcar '(lambda (x) (cons 41 (cdr x)))(cdr(reverse lineweight1))))
      (setq newlineweight2 (mapcar '(lambda (x) (cons 40 (cdr x)))(cdr(reverse lineweight2))))
      (setq newBulge (mapcar '- (cdr (reverse bulgeList))))
      (setq newz91 (reverse z91))
      (entmod
          (vl-remove nil
            (append
            (vl-remove-if '(lambda (x) (or (= (car x) 10)(= (car x) 40)(= (car x) 41)(= (car x) 42)(= (car x) 91))) elist)
            (apply 'append
                (mapcar '(lambda (pt lw1 lw2 bulge)
                           (list pt lw2 lw1(cons 42 bulge)))
                  newCoord
                  (append newlineweight1 (list(cons 41 (cdr(car lineweight1)))))
                  (append newlineweight2 (list(cons 40 (cdr(car lineweight1)))))
                  (append newBulge '(0.0))
                )
            )
            )
          )
      )
      ent
      )
    )
)

wzg356 发表于 2025-2-23 21:17:03

hubeiwdlue 发表于 2025-2-23 21:02
谢谢，我只在acad2008和中望上测试过，acad高版本确实没有测试，不清楚新增了91组码。

;(reverseLwp (car(entsel "\n选择线...")))
(defun reverseLwp (en / a es lst lst1 lst2)
        (setq es (entget en) en(assoc 210 es))       
        (while(/= 10(car (setq a (car es))))(setq lst1(cons a lst1) es(cdr es)))       
        (while (setq es (member (assoc 10 es) es))
                (setq lst
          (cons(cons 40 (cdr (assoc 41 es)))
          (cons(cons 41 (cdr (assoc 40 es)))
          (cons(cons 42 (- (cdr (assoc 42 es))))
          (cons(assoc 91 es)
          (cons (assoc 10 es) lst)))))
          )
          (setq es (cdr es))
    )
    (setq lst(vl-remove NIL lst));低版本没有91码时   
        (while(/= 10(car(setq a (car lst))))(setq lst2(cons a lst2) lst(cdr lst)))
        (setq lst2(append lst (reverse(cons en lst2))))
        (entmod(foreach a lst1(setq lst2(cons a lst2))))               
)

尘缘一生 发表于 2025-2-20 17:12:13

用在什么时候？

liuhe 发表于 2025-2-20 17:24:51

(DEFUN C:TT (/ E E1 NUM I BU)
(SETQ E (CAR (ENTSEL)))
(IF E
    (PROGN
      (VLA-COPY (vlax-ename->vla-object E))
      (SETQ E1      (ENTLAST)
            NUM      (CDR (ASSOC 90 (ENTGET E)))
            I      0
      )
      (REPEAT NUM
      (vla-PUt-Coordinate
          (vlax-ename->vla-object E)
          (- NUM I 1)
          (vla-get-Coordinate (vlax-ename->vla-object E1) I)
      )
      (setq BU (vla-GetBulge (vlax-ename->vla-object E1) I))
      (vl-catch-all-apply
          'vla-SetBulge
          (LIST
            (vlax-ename->vla-object E)
            (- NUM I 2)
            (* -1 (vla-GetBulge (vlax-ename->vla-object E1) I))
          )
      )
      (setq i (1+ i))
      )
      (ENTDEL E1)
    )
)
)

hubeiwdlue 发表于 2025-2-20 20:27:26

尘缘一生 发表于 2025-2-20 17:12
用在什么时候？

陈总，我是用在剖地形线的代码里面的。根据点选位置距离起点和终点的长度，判断是否需要反转。然后从起点开始剖断面。

hubeiwdlue 发表于 2025-2-20 20:28:34

liuhe 发表于 2025-2-20 17:24


谢谢流河大神，用vlisp果然要方便一些。

wzg356 发表于 2025-2-23 20:56:13

高版本（至少12版之后）多线段组码增加了91码，即各点均有的(10 ...)( 40 ...)( 41 ...)( 42 ...) (91....)
代码中把各点跟随的91吗采集进去好一些，否则其他程序涉及组码操作的时候可能会出错

hubeiwdlue 发表于 2025-2-23 21:02:52

wzg356 发表于 2025-2-23 20:56
高版本（至少12版之后）多线段组码增加了91码，即各点均有的(10 ...)( 40 ...)( 41 ...)( 42 ...) (91....) ...

谢谢，我只在acad2008和中望上测试过，acad高版本确实没有测试，不清楚新增了91组码。

hubeiwdlue 发表于 2025-2-23 22:27:01

wzg356 发表于 2025-2-23 21:17
;(reverseLwp (car(entsel "\n选择线...")))
(defun reverseLwp (en / a es lst lst1 lst2)
        (setq es...

谢谢指导。

hubeiwdlue 发表于 2025-2-24 13:25:26

wzg356 发表于 2025-2-23 21:17
;(reverseLwp (car(entsel "\n选择线...")))
(defun reverseLwp (en / a es lst lst1 lst2)
        (setq es...

请教一下您，91号组码的作用是什么？

查看完整版本: 分享一个反转轻量多段线的函数