社区 › VBA/VB/ActiveX/API 编程技术 › 请问，如何将图上所有的数字（成千上万个数值）减去同一个常数？

yutou 发表于 2002-12-7 14:23:00

请问，如何将图上所有的数字（成千上万个数值）减去同一个常数？

tfyyf 发表于 2002-12-13 15:10:00

你指的是text吗？

yutou 发表于 2002-12-15 00:35:00

是的

efan2000 发表于 2002-12-15 18:28:00

看看这段代码对你有没有用处。

这段程序提示你选择文本，然后指定增量，正的就是加，负的就是减了。如果选中的文本是数字的，那么就对它进行加或减处理。
Sub Test()
    Dim SSetObj As AcadSelectionSet
    Dim bFound As Boolean
    Dim IncreaseValue As Double
    Dim i As Integer
   
    On Error GoTo ErrTrap
    For Each SSetObj In ThisDrawing.SelectionSets
      If SSetObj.Name = "ChangeText" Then
            bFound = True
            Exit For
      End If
    Next
    If bFound = False Then
      Set SSetObj = ThisDrawing.SelectionSets.Add("ChangeText")
    Else
      Set SSetObj = ThisDrawing.SelectionSets("ChangeText")
      SSetObj.Clear
    End If
    SSetObj.SelectOnScreen
    If SSetObj.Count = 0 Then Exit Sub
    IncreaseValue = ThisDrawing.Utility.GetReal("指定数值增量: ")
    For i = 0 To SSetObj.Count - 1
      If TypeOf SSetObj(i) Is AcadText Or TypeOf SSetObj(i) Is AcadMText Then
            If IsNumeric(SSetObj(i).TextString) Then
                SSetObj(i).TextString = SSetObj(i).TextString + IncreaseValue
            End If
      End If
    Next
    SSetObj.Delete
    Set SSetObj = Nothing
    Exit Sub
   
ErrTrap:
    If Not (SSetObj Is Nothing) Then Set SSetObj = Nothing
    On Error GoTo 0
End Sub

yutou 发表于 2002-12-19 14:54:00

谢谢efan2000。

查看完整版本: 请问，如何将图上所有的数字（成千上万个数值）减去同一个常数？