社区 › 编程申请 › [求助]求一程序，自动打开文件夹下所有文件，并执行图形清理、缩放和保存命令(已解

ly8zx2109 发表于 2013-4-8 13:54:45

不知道什么原因，好像没有清理干净。

ly8zx2109 发表于 2013-4-8 15:08:14

(defun c:test(/ FILE_LIST FOLD SF SFF RunNow)
(vl-load-com)
(defun GetFileList (dirName / files lst)
(defun path-addBackSlash (path)
(if (not (member (substr path (strlen path)) '("\\" "/")))
(strcat path "\\")
path
)
)
(setq dirName (path-addBackSlash dirName)
files (mapcar '(lambda (x) (strcat dirName x))
(vl-directory-files dirName "*.dwg" 1)
)
)
(mapcar '(lambda (x)
(setq lst (append lst (GetFileList (strcat dirName x))))
)
(vl-remove-if
'(lambda (x) (member x '("." "..")))
(vl-directory-files dirName nil -1)
)
)
(append files lst)
)
;; 用法：(qf_getFolder msg)
;; 例子：(qf_getFolder "选择文件夹:")
;; 返回值：字符串，文件夹路径，如果点了cancel, 返回nil
(defun qf_getFolder (msg / WinShell shFolder path catchit)
(vl-load-com)
(setq winshell (vlax-create-object "Shell.Application"))
(setq shFolder (vlax-invoke-method WinShell 'BrowseForFolder 0 msg 1))
(setq
catchit (vl-catch-all-apply
'(lambda ()
(setq shFolder (vlax-get-property shFolder 'self))
(setq path (vlax-get-property shFolder 'path))
)
)
)
(if (vl-catch-all-error-p catchit)
nil
path
)
)
(setq fold (qf_getFolder "选择文件所在目录:"))
(if fold
(progn
(setq file_list (GetFileList fold))
(if file_list
(progn
(setq sf (strcat (getvar "TEMPPREFIX") "批处理文件20100806.scr"))
(setq sff (open sf "w"))
(mapcar '(lambda (x)
(princ (strcat "open \"" x "\"\n""-purge all * n zoom e qsave close\n") sff);;;;;加了清理
)
file_list
)
(close sff)
(princ (strcat "\n目录下" fold "\n\t共有DWG文件数: " (itoa (length file_list))))
(initget "Y N")
(setq RunNow (getkword "\n是否立刻执行[是(Y)/否(N)]:<否>"))
(if (= RunNow "Y")
(progn
   (command "._script" sf)
   (princ "\n处理完成")
)
(princ "\n放弃立刻执行")
)
)
(princ "\n目录下没有DWG文件")
)
)
(princ "\n请选择目录")
)
(princ)
)

ly8zx2109 发表于 2013-4-8 15:09:00

在原来的基础上，加了清理，

bjzxdvip 发表于 2014-9-25 22:01:39

为什么真么刁难我？！为何？

不一样地设计 发表于 2014-10-6 00:59:10

不错的程序，能够节约大量时间！

o只是过客o 发表于 2015-5-4 22:21:10

mark楼主我想求源代码！多谢啦

panliang9 发表于 2015-10-10 11:37:04

这个应该会用到，先标记一个！

vladimir 发表于 2015-12-12 18:33:26

强大的程序。强大的楼主

qwerasdf123456 发表于 2018-7-1 20:42:03

好好好好好好好好，就是看不到

suqing 发表于 2018-7-3 23:58:32

学习下！文件夹读取文件的操作！

查看完整版本: [求助]求一程序，自动打开文件夹下所有文件，并执行图形清理、缩放和保存命令(已解