zsw23 发表于 2011-4-7 00:21:51

在轴线交点处批量生成柱子

本帖最后由 zsw23 于 2011-4-7 00:23 编辑

如题，最好有输入柱子大小的提示。。

Gu_xl 发表于 2011-4-7 00:21:52

回复 zsw23 的帖子


;;;计算曲线交点
(defun Curveinters (en1 en2 / pl pts)
(setq pl(vlax-invoke (vlax-ename->vla-object en2) 'IntersectWith (vlax-ename->vla-object en1) acExtendNone))
(while pl
    (setq pts (append pts (list (list (car pl) (cadr pl) (caddr pl))))
   pl (cdr (cdr (cdr pl)))
   )
    )
pts
)
;;;曲线选择集交点
(defun ssinters (ss / pts en1 en2)
(while (> (sslength ss) 1)
    (setq en1 (ssname ss 0))
    (ssdel en1 ss)
    (setq n (sslength ss))
    (repeat n
      (setq en2 (ssname ss (setq n (1- n))))
      (setq pts (append pts (Curveinters en1 en2)))
      )
    )
pts
)
;;;画框
(defun drawbox (pt d / r en ang)
(setq en (ssget pt '((0 . "*line"))))
(setq en (ssname en 0))
(setq ang (angle pt (mapcar '+ pt (vlax-curve-getFirstDeriv en (vlax-curve-getParamAtPoint en (setq pt (vlax-curve-getclosestpointto en pt)))))))

(setq r (* d (sqrt 2)))
;;此处也可改插入框的图块
(command "rectang" (polar pt (* pi 1.25) r) (polar pt (* pi 0.25) r ) )
(command "rotate" (entlast) "" pt (/ (* 180 ang) pi))
)
;;;使用实例
(defun c:tt(/ p1 p2 d minX minY maxX maxY pt pts p1 p2 ss os cmdecho)
(setq os (getvar "osmode"))
(setq cmdecho (getvar "cmdecho"))
(setvar "osmode" 0)
(setvar "cmdecho" 0)
(setq d (getreal "\n插入框大小<1.0>"))
(if (null d) (setq d 1.))
(while (and
         (setq p1 (getpoint "\n选择图框左下角："))
         (setq p2 (GETCORNER p1 "\n选择图框左下角："))
         )
    (setq minX (apply 'min (mapcar 'car (list p1 p2)))
          minY (apply 'min (mapcar 'cadr (list p1 p2)))
          maxX (apply 'max (mapcar 'car (list p1 p2)))
          maxY (apply 'max (mapcar 'cadr (list p1 p2)))
          )
    (grvecs (list 1 (list minx miny) (list maxx miny)
                  1 (list maxx miny) (list maxx maxy)
                  1 (list maxx maxy) (list minx maxy)
                  1 (list minx maxy) (list minx miny)
                  )
            )
    (setq ss (ssget "c" p1 p2 '((0 . "*line"))))
    (if ss
      (progn
      (setq pts (ssinters ss))
      (if pts
          (foreach pt pts
            (if (and (>= maxX (car pt) minX)
                     (>= maxY (cadr pt) minY)
                     )
            (drawbox pt d)
            )
            )
          )
      )
      )
    (princ "\n ***回车键结束***")
    )
(setvar "osmode" os)
(setvar "cmdecho" cmdecho)
(princ)
)

Andyhon 发表于 2011-4-7 08:30:15

交点与柱子的位置关系为何
可有示例

zsw23 发表于 2011-4-7 08:59:45

回复 Andyhon 的帖子

交与柱中心即可，不用很智能。我在意的是批量生成，位置可以手动调整，请高手赐教..

Andyhon 发表于 2011-4-7 09:07:11

依交点批量生成 ....
那么交点取得的滤取条件是什么
sorry 是外行,全不懂,
或许等同行来回应会好些

luntan666 发表于 2011-4-7 09:38:16

了解了解.....

198526 发表于 2011-5-3 10:20:17

看样子写这程序应该不难，难在不好理解你的意思。最好贴个图上来，把你开始的样子和要的样子贴上来

zsw23 发表于 2011-5-3 11:39:00

本帖最后由 zsw23 于 2011-5-3 11:40 编辑

回复 198526 的帖子

http://bbs.mjtd.com/thread-86381-1-1.html
轴线倾斜的话，效果不好

Andyhon 发表于 2011-5-3 11:50:41

轴线倾斜的话，效果不好?
可有 轴线倾斜 的示例?
您想要达成的正确效果又是如何?
或是耐心等待有专业知识背景的同行来回应?

lrd1861 发表于 2011-5-3 12:37:53

e派工具箱里面好像有个平面布柱功能    pmbz命令可以达到你的要求
页: [1] 2
查看完整版本: 在轴线交点处批量生成柱子