如和判定某一个点是否在由多段线组成的闭合框内？

firstinti · 发表于 2014-10-23 06:25:29

凹包判断相对困难，凸包判断的算法已经很成熟了，射线法是比较常用的算法，论坛以前也有讨论过，楼主可以搜索一下，有现成的代码。不过按照楼主的条件我感觉还不需要做这种底层的运算，因为不是判断一个点是否在封闭点集内。bpoly如何

katamoto · 发表于 2014-10-23 08:28:08

firstinti 发表于 2014-10-23 06:25
凹包判断相对困难，凸包判断的算法已经很成熟了，射线法是比较常用的算法，论坛以前也有讨论过，楼主可以搜 ...

bpoly这个命令我知道，也用过，问这个问题是抱着向大侠学习的心态来专门问这种方法的。。

highflybir · 发表于 2014-10-23 20:16:43

katamoto 发表于 2014-10-23 08:28
bpoly这个命令我知道，也用过，问这个问题是抱着向大侠学习的心态来专门问这种方法的。。

http://bbs.mjtd.com/thread-111851-1-1.html
你读一下这个帖子里面的源码，有关于点在多边形或者曲线的判断的源码。

katamoto · 发表于 2014-10-28 08:19:03

ZZXXQQ 发表于 2014-10-22 21:28

版主，这个程序我试验了一下，把点放在封闭框内点后，还是返回 nil 的，您能看看是否有问题啊？

katamoto · 发表于 2014-10-28 08:25:48

ZZXXQQ 发表于 2014-10-22 21:28

版主您好，你这个程序我试验了一下，没成功，我选取的点在框内，但是返回值还是nil，您能看看是我哪里出的问题，

llsheng_73 · 发表于 2014-10-28 11:21:40

katamoto 发表于 2014-10-22 21:13
这个倒是一个有意思的思路啊，我还真没想到，搜索了一下也没看到有人用过这个方法。。。

ssget框选用2个 ...

没搜索到么?
判断点是否在多边形内的一个另类实现
http://bbs.mjtd.com/forum.php?mo ... &fromuid=202795
虽然不是用的点,但道理是一样的

llsheng_73 · 发表于 2014-10-28 11:23:03

lyqiezi 发表于 2014-10-23 00:03
(ssget "wp" ptlist)可以选择
还有一个思路，找出距离目标点最近的一个端点，将目标点插在最近端点的前后各 ...

这是一种新思路.

highflybir · 发表于 2014-10-28 16:45:28

给出楼主一段完整的代码吧：

;;;-----------------------------------------------------------;;
;;; 判断点是否在多边形内 ;;
;;;-----------------------------------------------------------;;
(defun c:tt( / poly dxf lst pt)
(if (and (setq poly (car (entsel "\n请选择多段线:")))
(setq dxf (entget poly))
(= "LWPOLYLINE" (cdr (assoc 0 dxf)))
)
(progn
(setq lst (mapcar 'cdr (vl-remove-if '(lambda (x) (/= 10 (car x))) Dxf)))
(if (zerop (getvar "WORLDUCS"))
(setq lst (mapcar (function (lambda (p) (trans p poly 1))) lst))
)
(while (setq pt (getpoint "\n判断点:"))
(if (ALG:Inside-p pt lst)
(princ "\n在内!")
(princ "\n在外!")
)
)
)
(princ "\n请选择多段线!")
)
(princ)
)
;;;-----------------------------------------------------------;;
;;; 夹角（以P1为顶点，从p2到p3的有向角度） ;;
;;; 正代表逆时针，负则反之 ;;
;;;-----------------------------------------------------------;;
(defun GEO:Angle (p1 p2 p3 / a )
(setq a (- (angle p1 p3) (angle p1 p2)))
(if (< a 0)
(if (< a (- pi))
(+ a 6.283185307179586476925286766559)
a
)
(if (> a pi)
(- a 6.283185307179586476925286766559)
a
)
)
)
;;;-----------------------------------------------------------;;
;;; 判断点是否在多边形（用顶点表示）内 ;;
;;; 方法: Pt与各个顶点的有向夹角和的绝对值如果等于2*pi则为真. ;;
;;; 参数: Pt 要判断的点 ;;
;;; lst 顶点列表 ;;
;;; 返回: T 在多边形内，nil则在外 ;;
;;;-----------------------------------------------------------;;
(defun ALG:Inside-p (Pt lst /)
(if (> (length lst) 2) ;至少要3点
(equal
(abs ;绝对值
(apply
'+ ;总和
(mapcar
(function (lambda (p q) (GEO:Angle pt p q))) ;有向夹角
(cons (last lst) lst)
lst
)
)
)
6.283185307179586476925286766559 ;2*pi
1e-4 ;设低一点，防止累计误差
)
)
)

;;;-----------------------------------------------------------;; 
;;; 判断点是否在多边形内                                      ;; 
;;;-----------------------------------------------------------;; 
(defun c:tt( / poly dxf lst pt) 
  (if (and (setq poly (car (entsel "\n请选择多段线:"))) 
           (setq dxf (entget poly)) 
           (= "LWPOLYLINE" (cdr (assoc 0 dxf))) 
      ) 
    (progn 
      (setq lst (mapcar 'cdr (vl-remove-if '(lambda (x) (/= 10 (car x))) Dxf))) 
      (if (zerop (getvar "WORLDUCS")) 
        (setq lst (mapcar (function (lambda (p) (trans p poly 1))) lst)) 
      ) 
      (while (setq pt (getpoint "\n判断点:")) 
        (if (ALG:Inside-p pt lst) 
          (princ "\n在内!") 
          (princ "\n在外!") 
        ) 
      ) 
    ) 
    (princ "\n请选择多段线!") 
  ) 
  (princ) 
) 
 
;;;-----------------------------------------------------------;; 
;;; 夹角（以P1为顶点，从p2到p3的有向角度）                    ;; 
;;; 正代表逆时针，负则反之                                    ;; 
;;;-----------------------------------------------------------;; 
(defun GEO:Angle (p1 p2 p3 / a ) 
  (setq a (- (angle p1 p3) (angle p1 p2))) 
  (if (< a 0) 
    (if (< a (- pi)) 
      (+ a 6.283185307179586476925286766559) 
      a 
    ) 
    (if (> a pi) 
      (- a 6.283185307179586476925286766559) 
      a 
    ) 
  ) 
) 
 
;;;-----------------------------------------------------------;; 
;;; 判断点是否在多边形（用顶点表示）内                        ;; 
;;; 方法: Pt与各个顶点的有向夹角和的绝对值如果等于2*pi则为真. ;; 
;;; 参数: Pt  要判断的点                                      ;; 
;;;       lst 顶点列表                                        ;; 
;;; 返回: T 在多边形内，nil则在外                             ;; 
;;;-----------------------------------------------------------;; 
(defun ALG:Inside-p (Pt lst /) 
  (if (> (length lst) 2)                                        ;至少要3点 
    (equal 
      (abs                                                        ;绝对值 
        (apply 
          '+                                                        ;总和 
          (mapcar 
            (function (lambda (p q) (GEO:Angle pt p q)))        ;有向夹角 
            (cons (last lst) lst) 
            lst 
          ) 
        ) 
      ) 
      6.283185307179586476925286766559                                ;2*pi 
      1e-4                                                        ;设低一点，防止累计误差 
    ) 
  ) 
)

账号		自动登录	找回密码
密码			注册

[已解答] 如和判定某一个点是否在由多段线组成的闭合框内？

浏览过的版块