请各位高手帮忙

baozhiliang

请问明经CAD实用函数中的如下函数我怎么运行不成功？是否代码有问题？请帮助调试修改一下，万分感谢！
添加文件夹到AutoCAD支持搜索路径中的指定位置
(defun addSupportPath (dir pos / tmp c)
  (setq        tmp ""
        c   -1
  )
  (if (not pos)
    (setq tmp (strcat (getenv "ACAD") ";" dir))
    (mapcar '(lambda (x)
               (setq tmp (if (= (setq c (1+ c)) pos)
                           (strcat tmp ";" dir ";" x)
                           (strcat tmp ";" x)
                         )
               )
             )
            (parse (getenv "ACAD") ";")
    )
  )
  (setenv "ACAD" tmp)
  (princ)
)


功能

添加文件夹到AutoCAD支持搜索路径中的指定位置

参数

文件夹路径及插入的位置(0时插入前端)

示例

(addSupportPath "c:\\myFolder" 2)

注意

位置参数为空时将文件夹添加到路径最后。位置参数为0时将文件夹添加到路径最前端。

作者

未知

baozhiliang

mccad

龙龙仔

;;;要配合其它函数使用
;;;==================================================================
;;; (StrParse Str Delimiter)
;;;                将具有分隔符的字符串解析为列表
;;;------------------------------------------------------------------
;;; 参数:
;;;                Str                        要解析的字符串
;;;                Delimiter        要搜索的分隔符
;;;------------------------------------------------------------------
;;;        返回:
;;;                一个字符串列表。
;;;                示例:
;;;                (setq a "Harp,Guiness,Black and Tan")
;;;                (StrParse a ",")
;;;                返回:
;;;                ("Harp" "Guiness" "Black and Tan")
;;;------------------------------------------------------------------
;;; 相关主题: (StringToList)
;;;------------------------------------------------------------------
(defun STRPARSE        (STR DELIMITER / SEARCHSTR STRINGLEN RETURN N CHAR)
  (setq SEARCHSTR STR)
  (setq STRINGLEN (strlen SEARCHSTR))
  (setq RETURN '())
  (while (> STRINGLEN 0)
    (setq N 1)
    (setq CHAR (substr SEARCHSTR 1 1))
    (while (and (/= CHAR DELIMITER) (/= CHAR ""))
      (setq N (1+ N))
      (setq CHAR (substr SEARCHSTR N 1))
    )
    (setq RETURN (cons (substr SEARCHSTR 1 (1- N)) RETURN))
    (setq SEARCHSTR (substr SEARCHSTR (1+ N) STRINGLEN))
    (setq STRINGLEN (strlen SEARCHSTR))
  )
  (reverse RETURN)
)

(defun ADDSUPPORTPATH (DIR POS / TMP C)
  (setq        TMP ""
        C   -1
  )
  (if (not POS)
    (setq TMP (strcat (getenv "ACAD") ";" DIR))
    (mapcar '(lambda (X)
               (setq TMP (if (= (setq C (1+ C)) POS)
                           (strcat TMP ";" DIR ";" X)
                           (strcat TMP ";" X)
                         )
               )
             )
            (STRPARSE (getenv "ACAD") ";")
    )
  )
  (setenv "ACAD" TMP)
  (princ)
)

baozhiliang

非常感谢高手的指点，我已经调试过程序，能正常运行。
现在我还有点问题要向您请教，还是和这个程序相关的，因为这个程序只是添加了一个CAD的支持路径，但并没有建立这个文件夹到指定位置，能否实现用程序来建立这个文件夹呢？
等待您的回复，我是个LISP的初学者，给您添麻烦了！

龙龙仔

mccad

(defun c:md()
  (command "sh" "md d:\\mccad")
  )

注意先用findfile函数查一下目录是否存在。