批量修改图层名称遇到的问题

鼠标牌水泥 · 发表于 2016-3-1 18:34:30

(defun c:GTC ()
(command "rename" "layer" "梁虚线" "BEAM")
(command "rename" "layer" "梁" "BEAM_CON")
(command "rename" "layer" "砼墙" "WALL")
(command "rename" "layer" "柱" "COLU")
(command "rename" "layer" "洞口边线" "HOLE")
(command "rename" "layer" "悬挑板" "LINE")
）

各位大侠，上面的批量修改图层名称运行，如果找不到某一个图层（如图中无“柱”图层），则后面的（如“洞口边线”“悬挑板”）就不执行了。如何解决啊？

kozmosovia · 发表于 2016-3-2 12:17:18

没有图纸可以测试，简单写了一个

(Defun _RenameBlockLayer (ValueList / BN DONE NEW OLD)
(vlax-for blk (vla-get-Blocks
(vla-get-ActiveDocument (vlax-get-acad-object))
)
(setq bn (vla-get-Effectivename blk))
(if (null (member bn done))
(progn
(setq done (cons bn done))
(vlax-for obj blk
(setq old (vla-get-layer obj))
(if (setq new (cdr (assoc old ValueList)))
(vla-put-layer obj new)
)
)
)
)
)
)
(Defun _SuperLayerRename (data / BBB NEW OLD SS)
(foreach abc data
(setq old (car abc)
new (cadr abc)
)
(cond ((and (tblsearch "Layer" old)
(null (tblsearch "Layer" new))
)
(command "_.Rename" "Layer" old new)
)
((and (tblsearch "Layer" old)
(tblsearch "Layer" new)
)
(setq bbb (cons (cons old new) bbb))
(if (setq ss (ssget "_x" (list (cons 8 old))))
(command "_.change" ss "" "_p" "la" new "")
)
)
)
)
(if bbb
(progn
(_RenameBlockLayer bbb)
(command "_.Purge" "Layer" "*" "n")
)
)
)
用法：
(_SuperLayerRename
'(("梁虚线" "BEAM")
("梁" "BEAM_CON")
("砼墙" "WALL")
("柱" "COLU")
("洞口边线" "HOLE")
("悬挑板" "LINE")
)
)

(Defun _RenameBlockLayer (ValueList / BN DONE NEW OLD) 
  (vlax-for blk        (vla-get-Blocks 
                  (vla-get-ActiveDocument (vlax-get-acad-object)) 
                ) 
    (setq bn (vla-get-Effectivename blk)) 
    (if        (null (member bn done)) 
      (progn 
        (setq done (cons bn done)) 
        (vlax-for obj blk 
          (setq old (vla-get-layer obj)) 
          (if (setq new (cdr (assoc old ValueList))) 
            (vla-put-layer obj new) 
          ) 
        ) 
      ) 
    ) 
  ) 
) 
(Defun _SuperLayerRename (data / BBB NEW OLD SS) 
  (foreach abc data 
    (setq old (car abc) 
          new (cadr abc) 
    ) 
    (cond ((and        (tblsearch "Layer" old) 
                (null (tblsearch "Layer" new)) 
           ) 
           (command "_.Rename" "Layer" old new) 
          ) 
          ((and        (tblsearch "Layer" old) 
                (tblsearch "Layer" new) 
           ) 
           (setq bbb (cons (cons old new) bbb)) 
           (if (setq ss (ssget "_x" (list (cons 8 old)))) 
             (command "_.change" ss "" "_p" "la" new "") 
           ) 
          ) 
    ) 
  ) 
  (if bbb 
    (progn 
      (_RenameBlockLayer bbb) 
      (command "_.Purge" "Layer" "*" "n") 
    ) 
  ) 
) 
 
用法： 
  (_SuperLayerRename 
    '(("梁虚线" "BEAM") 
      ("梁" "BEAM_CON") 
      ("砼墙" "WALL") 
      ("柱" "COLU") 
      ("洞口边线" "HOLE") 
      ("悬挑板" "LINE") 
     ) 
  )

kozmosovia · 发表于 2016-3-1 19:25:16

加个判断(if (tblsearch "layer" "XXX")(command "rename" "layer" "XXX" "YYY"))

鼠标牌水泥 · 发表于 2016-3-2 08:59:06

本帖最后由鼠标牌水泥于 2016-3-2 09:17 编辑

kozmosovia 发表于 2016-3-1 19:25
加个判断(if (tblsearch "layer" "XXX")(command "rename" "layer" "XXX" "YYY"))

如果原图中已经有YYY图层，则提示“图层YYY已存在，无效”，怎么解决啊？

kozmosovia · 发表于 2016-3-2 09:45:17

(if (and (tblsearch "layer" "XXX")
(null (tblsearch "layer" "YYY"))
(command "rename" "layer" "XXX" "YYY")
)

鼠标牌水泥 · 发表于 2016-3-2 10:38:31

kozmosovia 发表于 2016-3-2 09:45

还是不行哦，我的意思是：1.原图如果已经有"YYY"图层，我现在拷贝一个新图进去后，把新图XXX改为YYY图层；2.如果原图没有“YYY”图层，则把新图XXX改为YYY图层，同时满足上面1和2.

kozmosovia · 发表于 2016-3-2 11:10:36

你这个要完全实现，必须遍历所有图块定义，块内实体使用了需要修改的图层时，修改实体图层定义。
图形比较大时，这种遍历需要的时间会很长。

鼠标牌水泥 · 发表于 2016-3-2 11:53:33

kozmosovia 发表于 2016-3-2 11:10
你这个要完全实现，必须遍历所有图块定义，块内实体使用了需要修改的图层时，修改实体图层定义。
图形比较 ...

paulpipi · 发表于 2020-10-31 19:44:51

账号		自动登录	找回密码
密码			注册

[已解答] 批量修改图层名称遇到的问题

浏览过的版块