带屏幕显示的一键关键字（附用法示例）

sandyvs · 发表于昨天 17:11

本帖最后由 sandyvs 于 2024-12-23 17:15 编辑

;;根据G版的一键关键字改编，sandyvs
;[功能] 一键关键字，(czx:onekey str0 keyfun okfzj okfyj okfyd）
;[说明]str0 = 提示信息//keyfun = 关键字和对应功能组成的二维表//okfzj = 左键功能（表，可为nil）//okfyj = 右键功能（表，可为nil）//okfyd = 移动功能（表，可为nil）返回值 = 按键值
(defun czx:onekey (str0 keyfun okfzj okfyj okfyd / *error* gr key loop ret txt)
(defun *error* ( msg )
(if (not (wcmatch (strcase msg t) "*break,*cancel*,*exit*"))
(progn
(princ (strcat "\n错误：" msg))
(if (and txt (entget txt)) (entdel txt))
)
)
(princ)
)
;(if str0 (princ (strcat "\n " (czx:StrRegExpR "\\n" str0 "" "i") ) )) ;命令栏打印
(setq keyfun (mapcar '(lambda (x) (list (strcase (car x)) (cadr x) (caddr x))) keyfun))
(setq key (mapcar 'car keyfun))
(setq loop t)
(while loop
(setq gr (grread t 4 0))
(cond
((and (= 2 (car gr))
(or (member (setq ret (strcase(chr (cadr gr)))) key))
)
(eval(cadr (assoc ret keyfun)))
(if (caddr (assoc ret keyfun))(setq loop nil))
(redraw)
)
((= 5 (car gr))
(if (and txt (entget txt)) (entdel txt))
(if str0 (setq txt (czx:emkmt (cadr gr) str0 (/(getvar "viewsize")50) 3 t)))
(if okfyd (eval okfyd))
)
((or (= 25 (car gr)) (= 11 (car gr)))
(setq ret "右键")
(if okfyj (eval (car okfyj)))
(if (cadr okfyj) (setq loop nil))
)
((= 3 (car gr))
(setq ret "左键")
(if okfzj (eval (car okfzj)))
(if (cadr okfzj) (setq loop nil))
)
)
)
(if (and txt (entget txt)) (entdel txt))
ret
)
(defun czx:emkmt (pt str textheight textcolor bg)
;(czx:emkstyle "YQ_TEXT")
(setq lst
(list
'(0 . "MTEXT")
'(100 . "AcDbEntity")
'(100 . "AcDbMText")
(cons 40 textheight)
;(cons 7 "YQ_TEXT")
;(cons 8 layername)
;(cons 50 ang)
'(71 . 7)
'(72 . 5)
'(73 . 1)
(cons 62 textcolor) ;字颜色
(cons 1 str)
(cons 10 pt)
)
)
(if bg
(entmakex (append lst '((90 . 3) (45 . 1.1) (63 . 256) (441 . 0))))
(entmakex (append lst '((90 . 0))))
)
)

qazxswk · 发表于昨天 20:07

最好附个动图演示一下。

账号		自动登录	找回密码
密码			注册

带屏幕显示的一键关键字（附用法示例）

本帖子中包含更多资源