绘制两个圆的公切线

langjs

手动画两个圆的公切线步骤繁多，因此编了个小程序，只需选择两个圆或者圆弧即可，可画内公切线和外公切线

;绘制两个圆的公切线
(defun c:aa (/ ent1 ent2 name1 pt1 pt2 pt3 pt4 pt5 pt6 pt7 pt8 r1 r2 ss x)
  (defun asin (x)                       ; 反正弦
    (if (<= (abs x) 1)(atan x (sqrt (- 1 (* x x))))))
  (setvar "cmdecho" 0)                       ; 关闭命令响应
  (setvar "osmode" 15359)
  (if (and (setq name1 (entsel "\n选择圆:"))
        (setq pt1 (cadr name1))
        (setq pt1 (osnap pt1 "_NEA"))
        (setq name1 (car name1))
        (setq ent1 (entget name1))
        (member (cdr (assoc 0 ent1)) '("CIRCLE" "ARC")))
    (if (and  (setq pt2 (getpoint pt1 "\n选择第二个圆:"))
          (setq ss (ssget "C" pt2 pt2 '((0 . "CIRCLE,ARC"))))
          (setq ent2 (entget (ssname ss 0))))
      (progn
        (setq pt3 (cdr (assoc 10 ent1)) pt4 (cdr (assoc 10 ent2)) r1 (cdr (assoc 40 ent1))  r2 (cdr (assoc 40 ent2)))
        (if (inters pt1 pt2 pt3 pt4 )
          (setq pt7 (polar pt4 (- (angle pt4 pt3) (- (* 0.5 pi) (asin (/ (+ r1 r2) (distance pt3 pt4))))) r2)
                pt8 (polar pt4 (+ (angle pt4 pt3) (- (* 0.5 pi) (asin (/ (+ r1 r2) (distance pt3 pt4))))) r2)
                pt5 (polar pt3 (- (angle pt4 pt3) (- (* 0.5 pi) (asin (/ (+ r1 r2) (distance pt3 pt4)))) pi) r1)
                pt6 (polar pt3 (+ (angle pt4 pt3) (- (* 0.5 pi) (asin (/ (+ r1 r2) (distance pt3 pt4)))) pi) r1))
          (setq pt7 (polar pt4 (- (angle pt4 pt3) (- (* 0.5 pi) (asin (/ (- r2 r1) (distance pt3 pt4))))) r2)
                pt8 (polar pt4 (+ (angle pt4 pt3) (- (* 0.5 pi) (asin (/ (- r2 r1) (distance pt3 pt4))))) r2)
                pt5 (polar pt3 (- (angle pt4 pt3) (- (* 0.5 pi) (asin (/ (- r2 r1) (distance pt3 pt4))))) r1)
                pt6 (polar pt3 (+ (angle pt4 pt3) (- (* 0.5 pi) (asin (/ (- r2 r1) (distance pt3 pt4))))) r1))
        )
        (if (< (distance pt1 pt5) (distance pt1 pt6))
          (entmake (list '(0 . "LINE") (cons 10 pt5) (cons 11 pt7))) (entmake (list '(0 . "LINE") (cons 10 pt6) (cons 11 pt8)))
        )
      )))
  (princ)
)

不一样地设计

感谢分享。  

yyz123121

感谢分享，化繁为简！