怎样提取字符串中的数字

ayan634

如HW100X100X100X100中的数字提取也来分别赋值给A，B，C ，D。

alin

(defun C:test()
(mapcar 'set '(A B C D) (mapcar 'read (String_To_Numbers "100X100X100X100")))
)
; 从字符串中提取数据，返回表
; The following two subrs are written by Bill Kramer
; Copied from the book "AutoCADet's Guide to Visual Lisp" - 2002
;------------------------------------------------------ Listing 4.4
;
(defun String_To_Numbers (inStr
;;Input string
/ Res
;;Result list
Buf
;;String buffer
Inx
;;Character location
CH
;;Character
)
(setq Inx 1 ;start at the beginning of the string
Buf "" ;init buffer to empty
)
;
; Loop until the end of the string.
; (I indicates where we are in the string)
;
(while (<= Inx (strlen inStr))
;
; Get the character at position Inx, increment position indicator
(setq CH (substr inStr Inx 1)
Inx (1+ Inx)
)
;
(cond
; Test to see if character is a digit.
((wcmatch CH "[0-9.]")
(if (= CH ".") ;is it decimal?
(if (not (wcmatch Buf "*`.*")) ;not already in there
(setq Buf (strcat Buf CH))
(Flush_Buf)
)
;
(setq Buf (strcat Buf CH))
)
)
((= Buf "") ;is the buffer empty?
;Is CH minus
(if (= CH "-")
(setq Buf CH) ;Yes, save in Buf
)
)
('T ;else buffer is not empty
(Flush_Buf)
(if (= CH "-")
(setq Buf CH)
)
)
) ; End of COND
) ; End of WHILE
;
(if (and (/= Buf "")
(not (wcmatch Buf "[+-.]"))
)
(Flush_Buf)
)
(reverse Res)
)
;
; ------------------------------------------------------ Listing 4.5
;
(defun Flush_Buf ()
(if (not (wcmatch Buf "[+-.]")) ;is it not just +-.?
(progn
;Clean it up first
(if (= (substr Buf 1 1) ".")
(setq Buf (strcat "0" Buf))
)
;;add zero to front if .#
(if (= (substr Buf (strlen Buf)) ".")
(setq Buf (substr Buf 1 (1- (strlen Buf))))
)
;;remove decimal if #.
;Add to RES list
(setq RES (cons Buf RES))
)
)
(setq Buf "")
;;reset Buf
)

ayan634

非常感谢alin,你真是我的好老师，我又学了不少。

无痕

这个针对性强些，通用性差点：），自己看着办

2. (defun C:test()
3.    (mapcar 'set '(A B C D) (read (strcat "(" (vl-string-translate     "XXXX" "       " "100X200X300X400") ")")))
4.    (list A B C D)
5. )
6. ->(100 200 300 400)

(defun C:test()    (mapcar 'set '(A B C D) (read (strcat "(" (vl-string-translate     "XXXX" "       " "100X200X300X400") ")")))    (list A B C D) ) ->(100 200 300 400)

ayan634

就象你说的一样,针对性强些，通用性差点,不过你的方法还好.我还有个问题想问一下.我怎样在CAD中将计算得到结果直接赋值给屏幕上某个字串,而不需要我手工改.

f5612140

ayan634发表于2004-7-7 23:49:00就象你说的一样,针对性强些，通用性差点,不过你的方法还好.我还有个问题想问一下.我怎样在CAD中将计算得到结果直接赋值给屏幕上某个字串,而不需要我手工改.

有点像老师在问学生

无痕

ayan634发表于2004-7-7 23:49:00就象你说的一样,针对性强些，通用性差点,不过你的方法还好.我还有个问题想问一下.我怎样在CAD中将计算得到结果直接赋值给屏幕上某个字串,而不需要我手工改.

lsp方法：更新dxf1。 vla： vla-put-textstring

f5612140

1. 以下是引用无痕在2004-7-8 10:50:04的发言：

复制代码

1. lsp方法：更新dxf1。 vla：   vla-put-textstring

复制代码

楼主要的应该是所得的数值与屏幕上某个字串为list的结果

ayan634

谢谢各位,我知道了