[原创]快速把3DSOLID对象转出2d三视图

龙龙仔

有很多人说AutoCAD的3DSOLID不好用,但那只是你对它很少用及不了解,
像以下巨集能快速把3DSOLID对象转出2d三视图

(请参阅autocad 指令solview ,soldraw ,solprof)

FOR R14 / AUTOCAD2000
^C^CUNDO;M;SELECT;\TI;0;MV;F;(SETQ A (CDR (ASSOC 5 (ENTGET (ENTLAST)))));(SETQ A1(strcat"V-"A));MS;UCS;V;SOLPROF;;;;N;-LA;S;!A1;F;*;;X;L;-LA;T;0;S;0;;-CH;;LA;0;;CUTCLIP;;UNDO;B;TI;1

FOR 2002
^C^CUNDO;M;SELECT;\TI;0;MV;F;(SETQ A (CDR (ASSOC 5 (ENTGET (ENTLAST)))));(SETQ A1(strcat"V-"A));MS;UCS;V;SOLPROF;;;;N;-LA;S;!A1;F;*;;X;L;-LA;T;0;S;0;;-CH;;LA;0;;TI;1;UCS;V;CUTCLIP;;UNDO;END;UNDO;B

1.将上述巨集设定为按钮(所看即所得,设定你要之视景view<如等角>)

2.选好3DSOLID对象后..程序执行(画面闪动)....哈哈....2D平面图已在剪贴簿里

3.转至纸空间OR设定UCS enter, V enter按贴上按钮即可(等角图请放大1.224744871392倍)


不能执行原因:

1.可能是你的缩写命令与巨集不合

2.纸空间已有视埠(请把纸空间视埠删除)

3.巨集中多了一些无用的空格(所以copy上述巨集时要小心)

4.未加载"solids.arx"  FOR R14 / 2000
        "acsolids.arx"  FOR 2002

这巨集只抓出外型,虚线吗!!希望各网友能自己研究出来(有可能的话把它改为LISP程序吧!)

PS:真是不能执行，可能是以上巨集有我自己的缩写命令,网友们把它抓出吧!!

这个3d转2d巨集我在其它网站<台湾>早已提供,但会用的人可能不多(说AUTOCAD的3DSOLID不好用)

不懂巨集如何用吗?(看以下吧!)

(截录自AUTOCAD 2000手册)

菜单巨集

下表所提供的是可在菜单巨集中使用的特殊字符一览表。关于这些字符的用途，在本章稍后的各节中会有详细的描述。

菜单巨集中所使用的特殊字符

字符        描述
;         发出 ENTER
^M         发出 ENTER
^I          发出 TAB
空格键        输入一个空格；在菜单项目中，指令顺序之间的空格，其作用与按下空格键一样。
\         暂停以等待使用者输入（Accelerators 节中无法使用）
_         转换本字符之后的文字为 AutoCAD 的指令与关键词
+         让菜单巨集连续到下一行（如果是最后一个字符）
=*         显示目前的顶层影像、下拉或快捷菜单
*^C^C         重复项目的前缀
$         一个特殊字符码，用来加载菜单节、或引入条件式 DIESEL 巨集表示式（$M=）
^B         切换锁点，使其打开或关闭（CTRL+B）
^C         取消指令（ESC）
^D         切换坐标显示功能，使其打开或关闭（CTRL+D）
^E         设定为下一个等角平面（CTRL+E）
^G         切换格点，使其打开或关闭（CTRL+G）
^H         发出退格键
^O         切换正交，使其打开或关闭（CTRL+O）
^P         切换 MENUECHO，使其打开或关闭
^Q         将每个提示、状态列示以及输入的字符，响应到打印机（CTRL+Q）
^T         切换数字板，使其打开或关闭（CTRL+T）
^V         变更目前视埠（CTRL+V）
^Z          空字符，用来抑制菜单项目结束时自动加入空格键

当菜单项目被选取时，AutoCAD 在处理指令顺序之前，会先在巨集结束的地方放置一个空格。所以，在处理下列菜单巨集时，
AutoCAD 会当做您已输入 line + SPACEBAR。

[线]line

然而，有些指令像是 TEXT，必须由 ENTER 来终止而非用空格。另外，有时候则需要多于一个的空格（或 ENTER）才能完成一个指令，但是，某些文字编辑器并不能让您建立一个以许多空格结尾的行。有两种惯用法可以防止这些问题发生：

如果分号（;）出现在菜单巨集中，AutoCAD 会用 ENTER 替换它。
        如果行的结尾是一个控制字符、反斜线（\）、加号（+）或分号（;），AutoCAD 就不会在行的结尾加入空格。（有关如何使用控制字符做为菜单项目终止符号的范例，请参阅「条件式巨集表示式」）。

请仔细看一看以下范例中的删除 1 菜单项目：

[删除 1]erase \;

如果这个项目单单以反斜线做为结束（表示使用者输入），它就无法完成 ERASE 这项作业了，因为 AutoCAD 并不会在反斜线之后加入一个空格。因此，这个菜单巨集就使用一个分号（;），在使用者输入之后强制加入一个 ENTER。以下还有几个范例：

[UCS     ]ucs
[UCS W   ]ucs ;

[地址    ]text \.4 0 DRAFT Inc;;;Main St.;;;City, State;

选取第一个项目会在指令行中输入 ucs 以及空格键，接着会出现下列提示：

输入选项 [新建（N）/移动（M）/ 正投影（G）/ 前次（P）/ 取回（R）/ 储存（S）/ 删除（D）/ 套用（A）/ 列示（?）/ 世界（W）]
＜世界＞：

选取第二个项目，会在指令行中输入 ucs、空格键以及 ;（解译为 ENTER），它会接受默认值「世界」。在屏幕上，第一个项目与第二个项目之间的差异并不明显；所以，您当然不需要在同一个菜单中同时放置这两个项目。
选取第三个项目，会显示起点提示，然后用三行来显示地址。三个分号（;;;） 中的第一个用来结束字符串；第二个分号导致 TEXT 指令重复执行；第三个分号会呼叫前一行下方的预设位置。

在菜单巨集内需要输入的地方放置一个反斜线（\），以接受来自键盘或指向设备的输入，有时候这是一种很有用处的作法。

[圆－1]circle \1

[关闭图层  ]layer off \；

「圆－1」 会暂停并要求使用者输入中心点，然候从菜单读取半径 1。注意：\ 的后面没有空格。关闭图层会暂停并要求使用者输入一个图层名称，然候关闭该图层并结束 LAYER 指令。在正常情况下，LAYER 指令会提示另一项作业，而且，只有当您按下空格键（空格）或 ENTER（;）时才会结束。
在正常情况下，输入一个项目之后，菜单巨集会继续执行。所以不可能建构出一个可以接受不定数目的输入（如对象选择），然后还能继续执行的菜单巨集。不过，指令 SELECT 是一个例外；反斜线可用来暂停菜单项目，直到已完成对象选择为止。请仔细看看下列菜单项目：

[改为红色]select \change previous ;properties color red ;

这个项目用 SELECT 指令建立一个含有一或多个对象的选集。然后，它会发出 CHANGE 指令、用「前次」选项参考该选集，并将所有选取对象的颜色全部变更为红色。

注意由于反斜线字符（\）会使菜单巨集暂停，以等待使用者输入；因此，在菜单巨集中，您不能再将反斜线用在任何其它目的。指定档案目录路径时，请用正斜线（/）做为路径区隔符号：例如：/direct/file。

下列情况会延迟菜单巨集的继续执行：

如果点输入为期望值，则对象锁点模式会比实际的点输入优先。
        如果使用了 X/Y/Z 点过滤器，菜单项目会保持暂停状态，直到完全聚积成一整个点所需的资料为止。
        如果使用了 SELECT 指令，菜单项目就只能等到对象选择已完成时，才会继续执行。
        如果使用者在响应时使用透通指令，则已暂停的菜单巨集会继续保持暂停状态，直到完成该透通指令，并接收到原来所要求的输入为止。
        如果使用者的响应方式，是选择另一个菜单项目（例如：提供选项或执行透通指令），原来的巨集就会暂停，等到新选取的项目被处理完成之后，已暂停的巨集才会继续执行。
您可以开发一些能够用在外语版本的 AutoCAD 菜单。只要在指令或关键词之前加一个底线字符（_），就可以自动翻译 AutoCAD 的各个标准指令与关键词。acad.mnu 文件广泛使用这项特征。
下列范例展示部份的「下拉」菜单。

[->弧]
  [3 点]^C^C_arc
  [起点，中心点，终点]^C^C_arc;\_c
  [起点，中心点，角度]^C^C_arc;\_c;\_a
  [起点，中心点，弦度]^C^C_arc;\_c;\_l
  [起点，终点，角度]^C^C_arc;\_e;\_a
  [起点，终点，半径]^C^C_arc;\_e;\_r

另外，AutoLISP 的 getcname 函数，也可以用来取出 AutoCAD 指令的英文名称或本土化名称（请参阅 AutoLISP 参考 中的  "getcname"）。
为了确保您之前并无尚执行完毕的指令，请在菜单项目中使用字符串 ^C^C。^C^C 字符串的作用，与在键盘上按两次 ESC 的作用一样。虽然单一 ^C 就能取消大部份的指令，但是，要从 DIM 指令返回「指令」提示时，就必须使用 ^C^C。因此，在大部份的情况下，^C^C 都能确保 AutoCAD 得以返回「指令」提示。
在正常情况下，从菜单项目读取到的字符，它会像从键盘输入一样地出现在屏幕的指令区；而且，即使菜单项目提供了响应，屏幕上还是会显示提示。您可以利用系统变量 MENUECHO 抑制这些提示的显示。如果菜单输入响应被停用了，菜单项目中的 ^P 可用来打开响应。
输入一个补入字符（^），其后接着另一个字符，您就可以将 ASCII 控制字符放置在菜单项目的指令字符串部份。例如：^C 转换成单一字符 CTRL+C （从菜单巨集呼叫该字符时，它发出的指令是 Cancel，不是 Copyclip）。以下是非字母控制字符：

^@     （ASCII 码 0）
^[     （ASCII 码27）
^\     （ASCII 码28）
^]     （ASCII 码29）
^^     （ASCII 码30）
^_     （ASCII 码31）

在菜单巨集中使用补入字符（^）时，它对应到键盘上的 CTRL 键。将补入字符结合另一个字符，您就能建构可以执行特定动作的菜单巨集，如切换格点使其打开或关闭（^G）、或取消某个指令（^C）。

[格点开关]^G

[*取消*]^C

您可以利用菜单巨集输入一或多个字符，但不做为最终输入递出。例如：您可以建立一系列菜单项目，仿真数字键台。

[1]1x^H
[2]2x^H
[3]3x^H

当您选择这些项目的其中一个时，就会有适当的数字被输入。数字之后接着另一个字符（在本范例中，指字母 x），而该字符则会被 ^H
移除（CTRL+H 就是退格键的 ASCII 码）。这些菜单项目全部都以控制字符做为结尾，而且 AutoCAD 也不会在这一类的项目中加入空格或 ENTER。因此，选择 [2]、[2]、[3]、[1] ，您就建构了输入 2231 四个字符。按下 ENTER，就可以输入已完成的数值。
下列菜单项目，可用来执行刚刚所描述的函数。这一次是使用反斜线。

[1]1\
[2]2\
[3]3\

在这两种方式中，建议您使用第一种。虽然第二种方式比较容易施行，而且，在大部份的情况下，产生的节果也相同，但是，在菜单暂停时所发出的指令，它的功能可能与期望值不同。
如果您要将菜单巨集，指定到主键以及从键盘激活的键序列，请参阅「加速键」。
如果无法以一行完成菜单档案中的某个项目，您可以将它连续到下一行。作法是在需要续行的该行行末，提供一个加号（+）。

[Setup ]layer set ground-floor;;grid on;fill off;+
limits 0,0 12,9;status

这个项目一直连续到第二行（它可能是用来设定新图面的初始条件）。菜单项目可以视需要而连续使用任意行数。

注意建立 MNS 档时，AutoCAD 不会保留行的连续。

如果您要发出的菜单巨集相当长，请使用 AutoLISP 所定义的指令、或使用定义于 MNL 文件的函数。这样的作法可以让您的菜单比较容易阅读，并使您的程序代码更加模块化。
一旦选取某个指令，您就可能用了数次之后，才会改用其它指令。这是使用工具的一般习惯：选择一种工具，用它做一些事，然后选择另一种工具，用它做其它的事，诸如此类。使用 AutoCAD 指令重复功能（由空响应触发），您就不必在每次要使用工具之前，都得先选择工具。请不要使用这项功能指定指令选项。
使用菜单巨集重复功能，您就可以重复使用您经常用到的指令，直到您选择另一个指令为止。如果某个菜单巨集的开头是 *^C^C ，其后紧接着项目卷标，该巨集会储存在内存中。该巨集会回答后续的指令提示，直到您用 ESC 终止它或您选取另一个菜单项目为止。

注意请不要在以字符串 *^C^C 开头的菜单巨集内使用 ^C（取消）；因为，这样的动作会取消菜单巨集的重复功能。

以下的范例，是关于指令处理的重复方式，或操作模式。

[移动   ]*^C^CMOVE Single
[复制   ]*^C^CCOPY Single
[删除   ]*^C^CERASE Single
[拉伸   ]*^C^CSTRETCH Single Crossing
[旋转   ]*^C^CROTATE Single
[比例   ]*^C^CSCALE Single

「影像框」菜单中的项目，不能使用菜单巨集重复功能。
您可以使用单一对象选择将对象选择置于单选模式、停用由对象选择所引导的正常对话框，并使选集传回由后续选项所选取的第一批对象。这在菜单中是很方便使用的，如下列菜单项目所示：

[删除]*^C^CERASE single

这个项目终止目前的指令，并以「单选」选项激活 ERASE 指令。选取这个项目之后，您可以指向要被删除的单一对象，您也可以指向空白区域并指定一个窗口。以这种方法所选取的对象会被删除，而该菜单项目则会一直重复（由于前导星号），这样您才能继续删除其它对象。单选模式还可以和 AutoCAD 产生更多的动态互动关系。

范例如下:

画螺纹孔(网友可练习把中心线加上)
[M8]^C^Csetvar;osmode;32;CIRCLE;\3.4 chprop;l;;la;0;;setvar;osmode;0;^C^CARC;C;@;@-4,0;A;-270;chprop;l;;la;0;c 2;;setvar;osmode;39

基本锁点END,CEN,INT,MID
ID__0          [基本锁点END,CEN,INT,MID(&Z)]'OSMODE;39;

画等角圆
ID__68         [_Button("ISO 圆", "ISO CIRCLE.bmp", "ICON_24_BLANK")]*^C^CSETVAR SNAPSTYL 1 ELLIPSE;I;\;

设定倒角为R2
ID_Fillet_R2   [_Button("R2", "FILLET2.BMP", "ICON_24_FILLET")]^C^C_fillet r 2;;

插入图块图块:TRI22.DWG)
[Tri2]^c^cinsert tri22;\\ \

插入图框并同时设定各种比例图框:A4.DWG)
ID__0          [_Button("A4", "A4.bmp", "ICON_24_BLANK")]^C^C(SETQ A(GETREAL"A4图框比例: "));\(SETVAR "LTSCALE"(* 5 A));(SETVAR "limmax" (LIST (* a 198) (* a 285)));(SETVAR "GRIDUNIT" (LIST (* a 5.0) (* a 5.0)));(SETVAR "DIMSCALE"(* 1 A));INSERT;A4;0,0;!A;;;X;L;ZOOM;E;

xxc2001

其实autocad的3D转2D并不复杂，而且还可自动转换为虚线和剖面线。

龙龙仔

xxc2001发表于2002-2-12 22:39:00其实autocad的3D转2D并不复杂，而且还可自动转换为虚线和剖面线。

你是说可以简化下列程序,把它写出来吧!
FOR R14 / AUTOCAD2000
^C^CUNDO;M;SELECT;\TI;0;MV;F;(SETQ A (CDR (ASSOC 5 (ENTGET (ENTLAST)))));(SETQ A1(strcat"V-"A));MS;UCS;V;SOLPROF;;;;N;-LA;S;!A1;F;*;;X;L;-LA;T;0;S;0;;-CH;;LA;0;;CUTCLIP;;UNDO;B;TI;1

FOR 2002
^C^CUNDO;M;SELECT;\TI;0;MV;F;(SETQ A (CDR (ASSOC 5 (ENTGET (ENTLAST)))));(SETQ A1(strcat"V-"A));MS;UCS;V;SOLPROF;;;;N;-LA;S;!A1;F;*;;X;L;-LA;T;0;S;0;;-CH;;LA;0;;TI;1;UCS;V;CUTCLIP;;UNDO;END;UNDO;B

hxh2901

我需要这样的程序，可以提高我的工作效率。在哪里可以找到呢

gaoerjun

三维绘图需要用专用的三维绘图软件

那样的话就可以避免这些复杂的手续了.

hxh2901

龙版主的程序有没有人 教一下呀，谢谢了