请教各位高手，如何利用lisp编程将CAD中的数据写入到WORD模板的表格中？？

tq0196_cn

请教各位高手，如何利用lisp编程将CAD中的数据写入到WORD模板的表格中？？

8350

g关注问题！！！

xcajcj

只知道lisp编程可以将CAD中的数据写入Excel中，写入到WORD模板还真不知道。

caddog

在CAD自带的帮助中有一些资料，讲了这方面的问题。再加上楼主的VBA知识，应该差不多啦:)

以下文字全部来自于CAD2000的帮助文档！！

建立与应用程序的连接

如果您的 PC 机上正运行着 Microsoft Word 的一个实例，可使用 vlax-get-object 来建立与该应用程序的连接。例如，下述函数调用将建立与 Microsoft Word 97 应用程序的连接，并将指向该应用程序的指针存到名为 msw 的变量中：

(setq msw (vlax-get-object "Word.Application.8"))

vlax-create-object 函数可创建应用程序对象的新实例。例如，如果 vlax-get-object 的返回值为 nil（表明所要求的应用程序不存在），您可以用 vlax-create-object 启动该应用程序。下述函数调用将启动 Microsoft Word 97，并将指向该应用程序的指针存到变量 msw 中：

(setq msw (vlax-create-object "Word.Application.8"))

另外，您也可以调用 vlax-get-or-create-object 函数来访问某应用程序。该函数先试图和应用程序的现有实例建立连接，如果它找不到其实例，该函数会启动应用程序的新实例。
在将应用程序对象设为可见之前它不会出现，您可以将对象的 Visible 特性设为 TRUE 来使对象可见。例如，下述函数调用使 Microsoft Word 应用程序可见：

(vla-put-visible msw :vlax-true)

应用程序编码样例

在访问应用程序对象之后，随后的 AutoLISP 代码将随所关心的应用程序以及所要完成的任务而异。例如，下述函数调用将访问 Microsoft Word 的 Document 集合对象：

(setq docs (vla-get-documents msw))

下述命令将创建一个新的 Word 文档：

(setq doc (mswm-add docs))

下列程序将创建一个与 Microsoft Word 97 和包含 mtext 的 AutoCAD 图形一起工作的 ActiveX 应用程序。

将 AutoCAD 中的 mtext 复制到 Microsoft Word 文档中的步骤

1 发出如下命令，确保已加载 AutoLISP ActiveX 支持：

(vl-load-com)

2 获取 AutoCAD 应用程序对象和当前模型空间对象，并保存它们的指针：

(setq *AcadApp* (vlax-get-acad-object))    ; 获取 AutoCAD 应用程序
(setq *ModelSpace* (vla-get-ModelSpace
  (vla-get-ActiveDocument *AcadApp*)))     ; 获取模型空间

3 输入 Microsoft Word 类型库，注意相应修改下述代码中的 :tlb-filename 参数，使它指向系统中的 msword8.olb
文件，然后运行该代码：

(if (equal nil mswc-wd100Words) ; 检查 Word 常量
  (vlax-import-type-library
    :tlb-filename "c:/Microsoft Office/Office/msword8.olb"
    :methods-prefix "mswm-"
    :properties-prefix "mswp-"
    :constants-prefix "mswc-"
  )

)

该代码先检查一个已知的 Microsoft Word 常量是否已被定义为某值，如果该常量有值，那么可认为已输入 Word 的类型库，不必再作其他操作。如果该常量为 nil，则调用 vlax-import-type-library。

4 运行下述代码，建立与 Microsoft Word 应用程序的连接：

 (setq msw (vlax-get-object "Word.Application.8"))
  (if (equal nil msw)
    (progn
      ; 未运行 Word，启动该应用程序。
      (setq msw (vlax-create-object "Word.Application.8"))
      (vla-put-visible msw :vlax-true)
    )

  )

该代码通过调用 vlax-get-object，与正在运行的 Microsoft Word 应用程建立连接（在该例中指定了版本 8，即 Word 97，如果省略了版本 8，则可接受 Word 的任何实例）。如果没有运行 Word，将调用 vlax-create-object，以启动 Word 的一个实例。

5 其余代码如下所示，代码的注释对处理过程进行了解释。

(if (/= nil msw)
  (progn
    ;; 获取文档集合对象。
    (setq docs (vla-get-documents msw))
    ;; 添加新文档
    (setq doc (mswm-add docs))
    ;; 获取文档的 paragraphs（进行格式设置）
    (setq paragraphs (mswp-get-paragraphs doc))
    ;; 现在遍历模型空间，并将所有 Mtext 图元输出到 Word。
    (vlax-for ent *ModelSpace*
      (if (equal (vla-get-ObjectName ent) "AcDbMText")
        (progn
           ;; 从 Mtext 图元中获取如下信息：

           ;;     o 文本字符串
           ;;     o 文本边界角点的位置
          
           (setq text (vla-get-TextString ent)      
                 textpos (vla-get-InsertionPoint ent)
                 arrayTextpos (vlax-variant-value textpos)
                 textinfo
                  (strcat
                 (rtos (vlax-safearray-get-element arrayTextpos 0) 2 2)
                ", "
                 (rtos (vlax-safearray-get-element arrayTextpos 1) 2 2)

                ", "
                (rtos (vlax-safearray-get-element arrayTextpos 2) 2 2)
                  )
           ) ;_ 结束 setq
         ;  打印某些信息（带格式）
         ;  获取文档的最后一段
         (setq pg (mswp-get-last paragraphs))
         ;  获取段落范围
         (setq range (mswp-get-range pg))
         ;  设置格式
         (mswp-put-bold range 1)                           ;粗体
         (mswp-put-underline range mswc-wdUnderlineSingle) ;下划线

         ; 4) 在段落末尾插入与文本有关的信息
         (mswm-InsertAfter range
            (strcat "AcDbMText at position " textinfo "\n"))
         ; 显示（来自 AutoCAD text 图元的）文本字符串
         (setq pg (mswp-get-last paragraphs))
         (setq range (mswp-get-range pg))
         (mswp-put-bold range 0)
         (mswp-put-underline range mswc-wdUnderlineNone)
         (mswm-InsertAfter range (strcat text "\n\n"))
        ) ;_结束 progn 

      ) ;_结束 if AcDbMText
    ) ;_结束 vlax-for
  ) ;_结束 progn
  (princ "\nNo Microsoft Word application found.\n")

)

加载并运行该代码，然后到 Microsoft Word 中查看结果。

tq0196_cn

非常感谢！

kexiya123

非常感谢

yuqiu233

谢谢，我想用lisp在word中书写公式（像公式编辑器的效果一样），该如何调用函数？

pslstar

非常感谢非常感谢

mahuan1279

正需要，刚好学习用上了！