块插入的简单问题？[求助]

urumchi_xcs

在工作中需要以前的一些地图,量很大。我需要将它们拼接到一起,但在拼接的过程中发现,再插入块时插入点等都不指定，两个图会差得很远，不知道什么原因，看坐标他们应该是在一起的，我把其中的两个发上去，看大家谁能找到原因。

meflying

两个块的插入点虽然是一样的，但两个块的插入点定义的不同，就是在定义插入点时，插入点和块相差很远，这样如果两个图同插入点之间的距离不一样，而如果这两个插入点相同时，两个图就会相差很远了。试试在原图中，将其做成块，并定义适当位置为插入点

urumchi_xcs

也许是我做的不对还是不行，我新建一个dwg将这两个图插入后还是离的很远(我要求不拖动修改就可以)[br]

meflying

东哥

如果一个文件被插入，这个文件在保存之前没有用BASE命令定义过基点，则以原点为默认基点。而BASE命令就可以任由用户为文件指定插入基点。

龙龙仔

;;一个VLISP的批量处理范例
;;从这个范例可以了解VLISP如何批量处理图档
;;虽然速度慢了点,但非常实用
;;By LUCAS(龙龙仔)
;;批量修改插入点                                             
;;注意未充分测试,使用前先COPY原图檔!!!!
;;                                                           
;;虽配合Expresstools__(acetutil.arx)                        
;;为加速程序执行,程序将设定系统变量ACADLSPASDOC              
;;即<只载入 acad.lsp 至 AutoCAD 执行期所开启的第一个图面>   
;;当然程序结束后,会还原系统变量ACADLSPASDOC
;;
;;For AutoCad 2000+
;;Usage: CH_INSPT


(arxload "acetutil.arx" NIL)
(vl-load-com)
(defun C:CH_INSPT        (/ HOLDECHO APP        DWGNAME        PREFIX_DWG NN QQ SS HOLDLSP WW
                 ENT_LAY)

  (defun BOUND (SS / BLK_BOUND)
    (setq BLK_BOUND (ACET-GEOM-SS-EXTENTS SS t))
    (car BLK_BOUND)
  )

  (setq HOLDECHO (getvar "cmdecho"))
  (setvar "cmdecho" 0)
  (setq        PREFIX_DWG
         (strcat
           (vl-string-right-trim
             "\\"
             (strcase (acet-ui-pickdir
                        "选择目录"
                        (vl-string-right-trim "\\" (getvar "dwgprefix"))
                        "移除未使用之具名参考"
                      )
             )
           )
           "\\"
         )
  )
  (setq HOLDLSP (getvar "ACADLSPASDOC"))
  (setvar "acadlspasdoc" 0)
  (setq QQ (vl-directory-files PREFIX_DWG "*.DWG"))
  (setq NN 0)
  (if (/= QQ NIL)
    (progn
      (setq APP (vlax-get-acad-object))
      (repeat (length QQ)
        (setq DWGNAME (strcase (strcat PREFIX_DWG (nth NN QQ))))
        (setq WW (vla-open (vla-get-documents APP) DWGNAME))
        (setq SS (ssadd))
        (vlax-for ENT_LAY (vla-get-modelspace WW)
          (ssadd (vlax-vla-object->ename ENT_LAY) SS)
        )
        (vla-setvariable WW "INSBASE" (vlax-3d-point (BOUND SS)))
        (vla-save WW)
        (prompt (strcat "\n" DWGNAME " <修改插入点完成>!!!"))
        (vla-close WW :vlax-false)
        (setq NN (1+ NN))
      )
      (vlax-release-object WW)
      (vlax-release-object APP)
    )
    (prompt "\n所选目录中未有任何图档!!!")
  )
  (setvar "acadlspasdoc" HOLDLSP)
  (setvar "cmdecho" HOLDECHO)
  (princ)
)
(princ)

myfreemind

你先分别打开这两幅图，注记图廓的左下角坐标，看看和图廓的坐标是否相同，若相同，你再检查两图在制图前的左下角坐标设置是否相同，若也相同，就检查是图纸模式还是实地模式，要保证两幅图的这几个设置完全一致，就绝对可以拼接起来的！

xujinhua

; 错误: no function definition: ACET-UI-PICKDIR

我的是2004  。。。正需要这个程序啊

bingshan23

技术文档，占位以后学习