如何用lisp构造一个200个顶点的spline?

lgw

南子

;;;ptslist为点列表，如:
;;;'((317.284 76.8801 0.0)
;;;  (349.74 106.014 0.0)
;;;  (308.359 119.771 0.0)
;;;  (255.619 105.204 0.0)
;;;  (196.387 120.58 0.0)
;;;  (164.743 89.8283 0.0)
;;;)
;;;closed 为样条曲线是否封闭选项
;;;提取点列表示例
(defun c:getptslist(/ pt ptslist)
  (setq pt t)
  (while
    (setq pt (getpoint "\n下一点："))
     (setq ptslist (cons pt ptslist))
  )
)


(defun spline200 (PtsList Closed / num pt)
  (setq num 0)

  (if ptslist
    (progn
      (setq pt (car ptslist))
      (command "_.spline" pt)
      (while (setq pt (nth (setq num (1+ num)) PtsList))
        (command pt)
      )
;;;      是否封闭选项
      (if closed
        (command "c" "")
        (command "" "" "")
      )
      (command)
    )
  )
  (princ)
)

;;;example: (spline200 PtsList nil) or (spline200 (c:getptslist) t)

龙龙仔

南子兄:
像你这样一直用SPLINE画200多个顶点就可以了,不用使用LISP。

不如试试这个
思路:先画一条SPLINE(顶点数不限),再用DIVIDE分成200多段,再利用DIVIDE的点用SPLINE重画一次就好了。

但可否说说200个顶点的SPLINE,到底有甚么用???


(defun C:SP_TO_MSP (/             HOLDECHO             HOLDBLIP             ORIG_OSNAP
                     AA             A             A1             BB             LL             AS74
                     ENDPT   SPT     LP             A11
                    )
  (command "_.undo" "_group")
  (setq HOLDECHO (getvar "cmdecho"))
  (setq HOLDBLIP (getvar "blipmode"))
  (setq ORIG_OSNAP (getvar "osmode"))
  (setvar "cmdecho" 0)
  (setvar "blipmode" 0)
  (setvar "osmode" 0)
  (while (/= AA "SPLINE")
    (setq A (entsel "\n 选择SPLINE"))
    (setq A1 (car A))
    (setq AA (cdr (assoc 0 (entget A1))))
  )
  (setq BB (entget A1))
  (setq LL (length BB))
  (setq AS74 (cdr (assoc 74 BB)))
  (setq ENDPT (cdr (nth (- LL 1) BB)))
  (setq SPT (cdr (nth (- LL AS74) BB)))
  (setq LP (getint "\n 请设定段数/<60>: "))
  (cond ((null LP) (setq LP 60)))
  (command "_.divide" A1 (+ LP 1))
  (setq A (ssget "p"))
  (command "_.SPLINE" ENDPT)
  (repeat LP
    (setq A11 (cdr (assoc 10 (entget (ssname A (- LP 1))))))
    (command A11)
    (setq LP (- LP 1))
  )
  (command SPT "" "" "")
  (command "_.erase" A A1 "")
  (setvar "blipmode" HOLDBLIP)
  (setvar "osmode" ORIG_OSNAP)
  (setvar "cmdecho" HOLDECHO)
  (command "_.undo" "_end")
)

南子

c:getptslist只是为了测试该程序时提取点表方便一点。
有的同志在程序中得到了点表，又想在程序中画完spline.

lish

学习了！！！！！！！！！