[求助]改非0层定义的块为0层定义的块

my_autocad

改非0层定义的块或多次定义的块为为0层定义的块

块的定义不规范，会影响后期工作的麻烦，想实现一个lsp程序，改非0层定义的块，修改成0层上定义的块

alin

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun C:BLKPRO (/ ss idx bname bnames blkdefobj)
  (princ
    "\nMove all objects in selected block(s) to layer '0'\nColour, linetype & lineweight to 'Bylayer'"
  )
  (if (setq ss (ssget '((0 . "INSERT"))))
    (progn
      (command "undo" "BE")
      (setq idx 0
     bnames '()
      )
      (while (<= idx (1- (sslength ss)))
 (setq bname (cdr (assoc 2 (entget (ssname ss idx)))))
 (if (not (member bname bnames))
   (progn
     (setq bnames (cons bname bnames))
     (setq blkdefobj (vla-item (vla-get-blocks
     (vla-get-activedocument
       (vlax-get-acad-object)
     )
          )
          bname
       )
     )
     (if (= (vla-get-isxref blkdefobj) :vlax-false)
       (vlax-for obj blkdefobj
  (vla-put-layer obj "0")
  (vla-put-color obj acBylayer)
  (vla-put-linetype obj "BYLAYER")
  (vla-put-lineweight obj acLnWtByLayer)
       )
     ) ; end if
   ) ; progn
 )
 (setq idx (1+ idx)
 )
      )
      (command "regenall")
      (command "undo" "End")
    )
  )
)

无痕

未考虑块中块

alin

You are right. This routine was written a few months ago for a friend of mine.

my_autocad

恩，感谢alin，程序非常好用