这是什么原因！

muhanleek

     (if(/= c_gd_xs gdgc)
     (progn
     (princ (/= c_gd_xs gdgc))
     (princ "\n")
     (princ c_gd_xs)(princ gdgc)
     (princ "\n")
     )）

上面是一段代码！

执行完却是这样：

T
1.961.96
T
-0.3-0.3
T
-1.89-1.89
T
1.631.63
T
-0.01-0.01

muhanleek

我那里错了，解释下吧！！

ZZXXQQ

浮点数不要用=、/=进行判断。应该用EQUAL函数进行判断。

上式可写成：

     (if (not (equal c_gd_xs gdgc 1e-6))
     (progn
     (princ (not (equal c_gd_xs gdgc 1e-6))
     (princ "\n")
     (princ c_gd_xs) (princ " ") (princ gdgc)
     (princ "\n")
     )）

muhanleek

(defun c:xxx()
  (setvar "cmdecho" 0)
  (setq js (ssget "x" (list(cons 2 "FG_*")(cons 8 "*PT"))) n 0 m 0)
  (if js
    (progn
    (repeat (sslength js)   
    (setq   enn           (ssname js n)
            enn1          (entget enn '("*"))
            enn_x         (car (cdr (assoc -3 (entget enn '("*")))))
            exp_num       (cdr (nth  6  enn_x))
            dmgc          (atof(cdr (nth 11  enn_x)))
            ms            (atof(cdr (nth 12  enn_x)))
            c_gd          (atof(cdr (nth 13  enn_x)))
            c_gd_xs       (atof(cdr (nth 14  enn_x)))
            gdgc          (- dmgc ms)
            tt            (strcase(substr exp_num 1 2))
    )

  
   (cond
     ((or(= tt "YS")(= tt "HS")(= tt "WS"))
     (if(/= c_gd_xs gdgc)
     (progn
     (setq enn_y (subst (cons 1000 (rtos gdgc 2 2)) (nth 14 enn_x) enn_x))
     (setq enn1 (subst (cons -3 (list enn_y))(assoc -3 enn1)enn1 ))
     (entmod enn1)
     (setq m (+ m 1))
     (princ (/= c_gd_xs gdgc))
     (princ "\n")
     (princ c_gd_xs)(princ gdgc)
     (princ "\n")
     )
     )
     )
     (T
     (if(/= c_gd gdgc)
     (progn
     (setq enn_y (subst (cons 1000 (rtos gdgc 2 2)) (nth 13 enn_x) enn_x))
     (setq enn1 (subst (cons -3 (list enn_y))(assoc -3 enn1)enn1 ))
     (entmod enn1)
     (setq m (+ m 1))
     (princ exp_num)
     (princ "\n")
    
     )
    
     )
     )
   );end cond 
   (setq n (+ n 1))
   );end repeat
   );end progn 
  (princ "xxxxxxxxxxxxxxxxxx")
  );end if
  (princ (strcat "共有点" (rtos (sslength js) 2 0) "个！共改正错误" (rtos m 2 0) "个！"))
  (command "zoom" "e" "regen")
  (setvar "cmdecho" 1)
  (princ)

)

这是整个代码！liminnet，不好意思了。。。。。

muhanleek

ZZXXQQ，谢谢了，又学一样，改成EQUAL果然行！！！！