[新手求助问题已解决]改变选择集中所有园为统一半径或统一比例缩放

bill168

请教：改变选择集中所有不同半径的园为统一半径或统一比例缩放，各园心点不变，lisp如何写？

yucpp

这个程序应该不难写的。我提供下我的算法：

首先用ssget过滤选择，得到一个选择集ss5；

然后让用户选择是改成统一半径的，还是比例缩放（我认为比例缩放其实就是new r=old r*比例K）。

接着循环，处理选择集中的每一个圆，用(repeat (sslength ss5)

循环中的代码来更新圆的半径   

            )

ok！

楼主好好思考下，一定能自己编出来。

cauin

(defun c:111 (/ sel int rad dat)
  (if (and (setq sel (ssget '((0 . "CIRCLE"))))
           (setq int 0
                 rad (getdist "\n半径:"))
      )
    (repeat (sslength sel)
      (setq dat (entget (ssname sel int))
            int (1+ int)
      )
      (entmod (subst (cons 40 rad) (assoc 40 dat) dat))
    )
  )
  (princ)
)

(defun c:222 (/ sel int sc rad dat)
  (if (and (setq sel (ssget '((0 . "CIRCLE"))))
           (setq int 0
                 sc  (getdist "\n比例:"))
      )
    (repeat (sslength sel)
      (setq dat (entget (ssname sel int))
            int (1+ int)
            rad (assoc 40 dat)
      )
      (entmod (subst (cons 40 (* sc (cdr rad))) rad dat))
    )
  )
  (princ)
)

无痕

liminnet发表于2009-8-24 23:22:00加我QQ599017495帮你解决

最近你有好几个贴都是这个调调，是明总明令禁止的。要帮就在这里帮，要发无关信息请用论坛短信功能单独发到对方收件箱。

mccad

liminnet发表于2009-8-24 23:22:00加我QQ599017495帮你解决

这是很严重的问题。取之于明，用之于明。好象你前一句用得挺好，但后一句不是这样用的。

phoenixdjq

世界之大！

……

5061220

给LZ提供我学Vlisp，写的第一个程序。瞎学的，这个是只能改单一圆，LZ需要修改一下哦

程序：(defun c:cr ()   ;改圆半径 

          （vl-load-com）

          （setq ent （car (entsel “\n选取圆对象：”)））  ;选取圆对象并提取象素名称。            

           (setq en (vlax-ename->vla-object  ent)) ;对象转换为 VLA 对象

(vla-put-Radius en 12);将圆半径改为“12”.

（princ）

)

bill168

谢谢各位这么热心,特别感谢cauin和5061220两位提供的程序，帮我把问题解决

AMTONNY

liminnet发表于2009-8-24 23:22:00加我QQ599017495帮你解决

此种行为令明经无地自容啊!    取之于明,用之于明????????何解哦,这么简单的程序也要私下解决,汗哦