[求助]关于文件遍历的问题

starlet2003 · 发表于 2009-12-26 07:57:00

请问如何在多级目录中遍历查找符合条件的文件？

xianaihua · 发表于 2009-12-26 22:36:00

(defun C:SEARCHFOR (/ foundfiles folder fn)
(defun filesearch (fld filename / fld fn found flst lst)
(cond ((setq flst
(vl-remove ".." (vl-remove "." (vl-directory-files fld)))
)
(setq
lst (mapcar
(function (lambda (n)
(if (= (substr fld (strlen fld) 1) "\")
(strcat fld n)
(strcat fld "\" n)
)
)
)
flst
)
)
(foreach fd lst
(cond ((vl-file-directory-p fd)
(filesearch fd filename)
)
(T
(cond ((wcmatch fd filename)
(setq found fd
foundfiles
(cons found foundfiles)
)
(princ found)
(terpri)
)
)
)
)
)
)
)
)
(defun BrowseForFolder (PrmStr / ShlObj Folder FldObj OutVal)
(vl-load-com)
(setq
ShlObj (vla-getInterfaceObject
(vlax-get-acad-object)
"Shell.Application"
)
Folder (vlax-invoke-method ShlObj 'BrowseForFolder 0 PrmStr 0)
)
(vlax-release-object ShlObj)
(if Folder
(progn
(setq FldObj (vlax-get-property Folder 'Self)
OutVal (vlax-get-property FldObj 'Path)
)
(vlax-release-object Folder)
(vlax-release-object FldObj)
OutVal
)
)
)
(setq folder (BrowseForFolder "选择要查找的文件夹: ")
fn (getstring "\n要查找的文件<*.dwg>: ")
)
(if (= folder "")
(setq folder (getenv "systemDrive"))
)
(if (= fn "")
(setq fn "*.dwg");查询所有的图形文件
)
(cond ((and folder (/= fn ""))
(filesearch folder fn)
)
)
(princ
(strcat "\n共有" (itoa (length foundfiles)) "文件被查询到")
)
(princ)
)

(defun C:SEARCHFOR (/ foundfiles folder fn)
  (defun filesearch (fld filename / fld fn found flst lst)
    (cond ((setq flst
    (vl-remove ".." (vl-remove "." (vl-directory-files fld)))
    )
    (setq
      lst (mapcar
     (function (lambda (n)
          (if (= (substr fld (strlen fld) 1) "\")
     (strcat fld n)
     (strcat fld "\" n)
          )
        )
     )
     flst
   )
    )
    (foreach fd lst
      (cond ((vl-file-directory-p fd)
      (filesearch fd filename)
     )
     (T
      (cond ((wcmatch fd filename)
      (setq found fd
     foundfiles
      (cons found foundfiles)
      )
      (princ found)
      (terpri)
     )
      )
     )
      )
    )
   )
    )
  )
  (defun BrowseForFolder (PrmStr / ShlObj Folder FldObj OutVal)
    (vl-load-com)
    (setq
      ShlObj (vla-getInterfaceObject
        (vlax-get-acad-object)
        "Shell.Application"
      )
      Folder (vlax-invoke-method ShlObj 'BrowseForFolder 0 PrmStr 0)
    )
    (vlax-release-object ShlObj)
    (if Folder
      (progn
 (setq FldObj (vlax-get-property Folder 'Self)
       OutVal (vlax-get-property FldObj 'Path)
 )
 (vlax-release-object Folder)
 (vlax-release-object FldObj)
 OutVal
      )
    )
  )
  (setq folder (BrowseForFolder "选择要查找的文件夹: ")
 fn     (getstring "\n要查找的文件<*.dwg>: ")
  )
  (if (= folder "")
    (setq folder (getenv "systemDrive"))
  )
  (if (= fn "")
    (setq fn "*.dwg");查询所有的图形文件
  )
  (cond ((and folder (/= fn ""))
  (filesearch folder fn)
 )
  )
  (princ
    (strcat "\n共有" (itoa (length foundfiles)) "文件被查询到")
  )
  (princ)
)

starlet2003 · 发表于 2009-12-30 23:23:00

谢谢啦

程序有个小小的瑕疵，文件扩展名是不区分大小写的，加入一个strcase处理就比较好了，呵呵

再谢谢，递归用的不好，传几次就有些晕了

账号		自动登录	找回密码
密码			注册

[求助]关于文件遍历的问题

浏览过的版块