程序无错误，为什么所画的线总是会偏移

wangyao1052

我写了一程序，就是画圆的中心线，程序绝对无错误，而且也试过很多次都正常。

但不知为什么，在公司的AutoCAD里的就不行，总是会便宜固定的距离。好像是x坐标偏了80几，y坐标偏了几个，郁闷死了。百思不得其解！！望高手指点：

程序如下：

(defun c:cen(/ )
  (setq var1 (getvar "cmdecho"))
  (setq var2 (getvar "osmode"))
  (setq var3 (getvar "cecolor"))
  (setq var4 (getvar "celtype"))
  (setvar "cmdecho" 0)
  (setvar "osmode" 0)
  (command "color" "red")
  (command "linetype" "s" "center" "")
  (while (setq cir1 (car (entsel "\n请选择圆：")))
    (setq list1 (entget cir1))
    (if (= "CIRCLE" (cdr (assoc 0 list1)))
      (progn
       (setq cen (cdr (assoc 10 list1)))
       (setq rad (cdr (assoc 40 list1)))
       (setq p1 (polar cen 0 (* 1.5 rad))
     p2 (polar cen (* 0.5 pi) (* 1.5 rad))
     p3 (polar cen pi (* 1.5 rad))
     p4 (polar cen (* 1.5 pi) (* 1.5 rad))
       )
    
       (command "line" p1 p3 "")
       (command "line" p2 p4 "")
      )
      (princ "请选择圆对象\n")
    )
  )
  (setvar "cmdecho" var1)
  (setvar "osmode" var2)
  (setvar "cecolor" var3)
  (setvar "celtype" var4)
  (princ)
)

zhang8755

可能是目标捕捉的问题，试一试在程序开始前关闭目标捕捉

wangyao1052

不是很懂

在程序中我已经关闭了对象捕捉了 （setvar "osmode" 0）

你所说的目标捕捉是这个吗

Andyhon

或许是UCS的设定所致

dwg001

在画线命令前，做坐标转换，试试~~

(setq p1 (trans p1 0 1 )
      p2 (trans p2 0 1 )
      p3 (trans p3 0 1 )
      p4 (trans p4 0 1 ))

谢谢大家的指点！！！

终于找到原因了，其实是坐标系的问题。

只要使用如下命令就行：（command "UCS" "w"）将当前用户坐标系UCS设置为世界坐标系即可。

出现以上问题的原因是用户坐标系与世界坐标系偏离，我们通过图元表获取的圆心等一切点的坐标都是基于世界坐标系的，但当我们调用AUTOcad命令（通过command）时，虽然传递的是点的世界坐标系坐标值，但它已被转化为用户坐标系上的对应坐标值的点。所以发生了偏移。