[求助]vlisp中，怎么给Group对象的AppendItems方法赋值

xransnow

源代码如下

(vl-load-com)
(setq *AcadDoc* (vla-get-ActiveDocument (vlax-get-Acad-Object)))
(setq *ModelSpace* (vla-get-ModelSpace *AcadDoc*))
(setq *PaperSpace* (vla-get-PaperSpace *AcadDoc*))
(setq *Groups* (vla-get-Groups *AcadDoc*))
(defun C:MakeGroup()
      (setq cirobj (vla-addCircle *ModelSpace* (vlax-3d-point '(3.0 3.0 0.0)) 2.0))
      (setq txtobj (vla-addText *MOdelSpace* (vlax-3d-point '(3.0 3.0 0.0)) "Test" 10))
      (setq objlist (list cirobj txtnoobj))
      (setq objgroup (vla-add *Groups* "Test01"))
      (setq objarray (vlax-make-safearray vlax-vbVariant '(0 . 1)))
      (vlax-safearray-fill objarray objlist)
      (vla-appenditems objgroup objarray)
)

执行后总是提示

; 错误: Automation 错误。 对象数组无效

请教高手，问题出在哪里？先谢了

sailorcwx

(vl-load-com)
(setq *AcadDoc* (vla-get-ActiveDocument (vlax-get-Acad-Object)))
(setq *ModelSpace* (vla-get-ModelSpace *AcadDoc*))
(setq *PaperSpace* (vla-get-PaperSpace *AcadDoc*))
(setq *Groups* (vla-get-Groups *AcadDoc*))
(defun C:MakeGroup()
      (setq cirobj (vla-addCircle *ModelSpace* (vlax-3d-point '(3.0 3.0 0.0)) 2.0))
      (setq txtobj (vla-addText *MOdelSpace*  "Test" (vlax-3d-point '(3.0 3.0 0.0)) 10))
      (setq objlist (list cirobj txtobj))
      (setq objgroup (vla-add *Groups* "Test01"))
      (setq objarray (vlax-make-safearray vlax-vbobject '(0 . 1)))
      (vlax-safearray-fill objarray objlist)
      (vla-appenditems objgroup objarray)
)

xransnow

谢谢高手，解决了，第三行是关键，前面两行是笔误，我从大段代码中提取出来的时候有的地方没修改好，总之解决了，太感谢了

xransnow

根据sailorcwx大大的提示，修改了以后，给出个列表转化为对象数组的函数，希望能有用

(defun Ut:list->Obj-Array (ptsList / arraySpace sArray)
     ; 给对象数组分配空间
  (setq arraySpace
  (vlax-make-safearray
    vlax-vbObject  ; 元素类型
    (cons 0
   (1- (length ptsList))
    )    ; 数组维数
  )
  )
  (setq sArray (vlax-safearray-fill arraySpace ptsList))
     ; 返回对象数组)
)