关于屏幕菜单自动收缩的问题

lyy

;;ACAD200x屏幕菜单恢复
(defun c:yad_scrmenu(/ screenkg screenres lst)
  (defun screenkg(sty / AcadObject Preference Display ShowScreenMenu)
    (setq AcadObject (vlax-get-acad-object)
            Preference (vla-get-Preferences AcadObject)
            Display (vla-get-Display Preference)
          ShowScreenMenu (vla-get-DisplayScreenMenu Display)
    )
    (if (= sty 0)
      (vla-put-DisplayScreenMenu Display :VLAX-FALSE)
      (vla-put-DisplayScreenMenu Display :VLAX-TRUE)
    )
    (mapcar 'vlax-release-object (list Display Preference AcadObject))
  )
  (if (and (> (atof (getvar "acadver")) 15.0) (= (getvar "screenboxes") 0))
    (progn
      (vl-load-com)
      (setq screenres (read (vl-string-subst " " "," (strcat "(" (vl-registry-read "HKEY_CURRENT_CONFIG\\Display\\Settings" "Resolution") ")")))
            lst (strcat (rtos (- (car screenres) 86) 2 0) " 95 " (rtos (- (car screenres) 20) 2 0) " " (rtos (- (cadr screenres) 120) 2 0))
      )
      (screenkg 0)
      (vl-registry-write (strcat "HKEY_CURRENT_USER\\" (vlax-product-key) "\\PROFILES\\yad\\DRAWING WINDOW\\") "ScreenMenu.Position" lst)
      (screenkg 1)
    )
  )
  (princ)
)

citykunan

先谢谢了。

龙龙仔

;;原恢复屏幕菜单至合适宽度，根据分辨率自动调整 Writen by eachy
;;MODIFY BY 龙龙仔(LUCAS)
(defun C:SCRMUN_REDRAW (/ ORG_POSITION_LST SCREEN CU_PROFILES)
  (if ;;(and (> (atof (getvar "acadver")) 15.0)
      (= (getenv "ScreenMenu") "1")
    ;;)
    (progn
      (setq SCREEN '(1024 768))                ;请查看看自己屏幕分辨率
      (setq ORG_POSITION_LST
             (strcat (rtos (- (car SCREEN) 86) 2 0)  ;参数屏幕菜单宽度
                     " 95 "                          ;参数屏幕菜单长度
                     (rtos (- (car SCREEN) 24) 2 0)  ;参数屏幕菜单宽度
                     " "
                     (rtos (- (last SCREEN) 120) 2 0);参数屏幕菜单长度
             )
      )
      (setq CU_PROFILES
             (strcat "HKEY_CURRENT_USER\\"
                     (vlax-product-key)
                     "\\PROFILES\\"
                     (vla-get-activeprofile
                       (vla-get-profiles
                         (vla-get-preferences (vlax-get-acad-object))
                       )
                     )
                     "\\DRAWING WINDOW\\"
             )
      )
      (setenv "ScreenMenu" "0")
      (if (vl-registry-read CU_PROFILES "SCREENMENU.POSITION")
        (progn
          (vl-registry-write
            CU_PROFILES
            "ScreenMenu.Position"
            ORG_POSITION_LST
          )
          (vl-registry-write CU_PROFILES "ScreenMenu.Style" 4)
        )
      )
      (setenv "ScreenMenu" "1")
    )
  )
  (princ)
)

秋枫

据Autodesk自己说，屏幕菜单放左边就没事了。

bobby

我的也一样，在2004里重新打开后屏幕菜单就成一条线了，可在2002里是可以的

wzt

acad2008屏幕菜单关掉之后,虽然没有文字了,但还有白框关不掉,谁有办法?