请教：如何重新指定一条封闭多段线的起点？（已解决，感谢andyhon）

mandala · 发表于 2011-3-15 15:27:27

嗯，看来我只好硬改组码了，结果如下：

;;子程序，修改不闭合的pline使其闭合，并按指定点作为起点重绘pline，
;;返回pline的组码。
(defun plchangestart (ee p1 / pt dat ptfrst ename aa data datb dat0 dat1 dat9)
(setq pt (list (car p1) (cadr p1)))
(setq dat (entget ee))
(setq ptfrst (cons 10 pt))
(setq ename (vlax-ename->vla-object ee))
(if (vlax-curve-isClosed ename)
(setq dat dat)
(progn
(setq dat (subst (cons 70 129) (assoc 70 dat) dat))
(setq data (List (Last dat)))
(setq datb (reverse(cdr(cdr(cdr(cdr(cdr(reverse dat))))))))
(setq dat(entmod (append datb data)))
)
)
;;以上一段：如果pl最终不是以“c”闭合而是以捕捉端点方式“闭合”，
;;则修改组码使其达到闭合效果。
(setq
dat0 (reverse (member '(39 . 0.0) (reverse dat)))
dat1 (cdr (member '(39 . 0.0) dat))
dat9 (List (Last dat1))
dat1 (reverse (cdr (reverse dat1)))
data (member ptfrst dat1)
datb (reverse (cdr (member ptfrst (reverse dat1))))
)
(entmod (append dat0 data datb dat9))
;;以上一段：修改组码，使pline从指定点开始。
)

;;子程序，修改不闭合的pline使其闭合，并按指定点作为起点重绘pline， 
;;返回pline的组码。 
(defun plchangestart (ee p1 / pt dat ptfrst ename aa data datb dat0 dat1 dat9) 
 
(setq pt (list (car p1) (cadr p1))) 
(setq dat (entget ee))      
(setq   ptfrst (cons 10 pt)) 
(setq ename (vlax-ename->vla-object ee)) 
(if (vlax-curve-isClosed ename) 
(setq dat dat) 
(progn 
(setq dat (subst (cons 70 129) (assoc 70 dat) dat)) 
(setq data (List (Last dat))) 
(setq datb (reverse(cdr(cdr(cdr(cdr(cdr(reverse dat)))))))) 
(setq dat(entmod (append datb data))) 
) 
) 
;;以上一段：如果pl最终不是以“c”闭合而是以捕捉端点方式“闭合”， 
;;则修改组码使其达到闭合效果。 
(setq 
     dat0 (reverse (member '(39 . 0.0) (reverse dat))) 
     dat1 (cdr (member '(39 . 0.0)  dat)) 
     dat9 (List (Last dat1)) 
     dat1 (reverse (cdr (reverse dat1))) 
     data (member ptfrst dat1) 
     datb (reverse (cdr (member ptfrst (reverse dat1)))) 
) 
(entmod (append dat0 data datb dat9)) 
 
;;以上一段：修改组码，使pline从指定点开始。 
 
)

mandala · 发表于 2011-3-15 15:45:06

本帖最后由 mandala 于 2011-3-15 15:47 编辑

最后贴上制作宗地图的源码。
修改lsp中几个指定层名的语句后，即可正常使用。

;;制作宗地图。
;;指定一条闭合的pline，指定起点，程序会自动顺向标注界址点号、界址尺寸，加粗界址线、圈上界址点并算出宗地面积。
;;程序中用到了本单位系统专用的几个层名，随机用户要使用的话，必须修改相应语句。
(defun c:make( / *error* os zin lay ltp pl startpoint mj j plst ll plename p plast pnext pt1 pt2 pt3 p4 n ss1 jzx jzxename jzxout jzxoutename d l dist m angle1 angle2 start end )
(defun *error* (msg)
(prompt "\n没搞定")
(print msg )
(SETVAR "DIMZIN" ZIN)
(SETVAR "OSMODE" OS)
(setvar "clayer" lay)
(setvar "celtype" ltp)
(COMMAND ".UNDO" "E")
) ;_ 结束defun
(SETVAR "CMDECHO" 0)
(COMMAND ".UNDO" "BE")
(SETQ OS (GETVAR "OSMODE")
ZIN (GETVAR "DIMZIN")
) ;_ 结束SETQ
(setq lay (getvar "clayer"))
(setq ltp (getvar "celtype"))
(SETVAR "DIMZIN" 0)
(setvar "celtype" "continuous")
(PRINC "\n请选择已封闭的界址线: ")
(setq pl (car (entsel)))
(while (= pl nil)
(PRINC "\n没点中……拜托请选择已封闭的界址线: ")
(setq pl (car (entsel)))
)
(command "area" "o" pl)
(setq mj (getvar "area"))
(if (= (fangxiang pl) 0) (reverseLwp pl))
(setq startpoint (getpoint "\n请指定界址线的起点："))
(while (= (equal startpoint (vlax-curve-getClosestPointTo (vlax-ename->vla-object pl) startpoint) 0.001) nil)
(setq startpoint (getpoint "\n你指定的点不在线上，请指定界址线的起点："))
)
(SETVAR "OSMODE" 0)
(SETQ ent (plchangestart pl startpoint))
(setq J 0
PLST (LIST)
) ;_ 结束setq
(REPEAT (LENGTH ENT)
(IF (= (CAR (NTH J ENT)) 10)
(SETQ PLST (APPEND PLST (LIST (CDR (NTH J ENT)))))
) ;_ 结束IF
(SETQ J (1+ J))
) ;_ 结束REPEAT
(SETQ J 0
LL (LENGTH PLST)
) ;_ 结束SETQ
(setq plename (vlax-ename->vla-object pl))
(REPEAT LL
(SETQ P (NTH J PLST))
(if (= j 0)
(setq plast (NTH (- ll 1) PLST))
(setq plast (NTH (- J 1) PLST))
) ;_ 结束if
(if (= j (- ll 1))
(setq pnext (NTH 0 PLST))
(setq pnext (NTH (1+ J) PLST))
) ;_ 结束if
(setq pt1 (polar p (angle p plast) 1))
(setq pt2 (polar p (angle p pnext) 1))
(setq
pt3 (polar pt1 (angle pt1 pt2) (* 0.5 (distance PT1 PT2)))
;;以这种方式来求得角平分线，得到点位用以标注点号
) ;_ 结束setq
(setq P4 (POLAR P (ANGLE Pt3 p) 3))
(setvar "clayer" "jzd")
(command "circle" p "0.4")
(setvar "clayer" "jzdh")
(setq n (rtos (1+ j) 2 0))
(command "text" "s" "等线体" "j" "c" p4 "2" "0" n)
(setq J (1+ J))
);_ 结束REPEAT
(command "_.explode" pl)
(setq ss1 (SSGET "P")
n 0
) ;_ 结束setq
(REPEAT ll
(setq jzx (ssname ss1 n))
(setq jzxename (vlax-ename->vla-object jzx))
(vla-offset jzxename 0.1)
(setq jzxout (entlast))
(command "chprop" jzxout "" "la" "jzxout" "")
(setq jzxout (entlast))
(setq jzxoutename (vlax-ename->vla-object jzxout))
(vla-offset jzxoutename -0.1)
(entdel jzxout)
(setq jzxout (entlast))
(if (= (cdr (assoc 0 (entget jzxout))) "ARC")
(setq d -2.5)
(setq d 2.5)
) ;_ 结束if，该段为下面标注距离时的注记位置做准备。绝大多数圆弧需要的d是负的。
(command "pedit" jzxout "y" "w" "0.3" "")
(setq jzxout (entlast))
;;以上偏移了每段jzx，变成jzxout后偏移回原位，变粗，得到对应的图元jzxout。
(setq jzxoutename (vlax-ename->vla-object jzxout))
(setq l (vlax-curve-getDistAtPoint
jzxoutename
(vlax-curve-getEndPoint jzxoutename)
) ;_ 结束vlax-curve-getDistAtPoint
) ;_ 结束setq
;;l为线长
(setq dist (rtos (/ l 2) 2 2))
(setq m (vlax-curve-getPointAtDist jzxoutename (/ l 2)))
;;m为中点
(setq angle1 (angle (vlax-curve-getstartPoint jzxoutename)
(vlax-curve-getendPoint jzxoutename)
) ;_ 结束angle
) ;_ 结束setq
;;angle1为距离注记的位置
(setq angle2 (/ (* angle1 180) pi))
;;angle2为注记旋转的角度,在某些情况下注记的旋转角度需要反转
(if (and (> angle2 90) (< angle2 270))
(setq angle2 (+ angle2 180))
) ;_ 结束if
;;以下的if分别考虑线长小于0.8和大于0.8两种情况下，jzxout的处理。
;;为了留出界址点位置，jzxout小于0.8，删除；大于0.8，截短。
(if (<= l 0.8)
(entdel jzxout)
(progn (setq start (vlax-curve-getStartPoint jzxoutename))
(setq end (vlax-curve-getendPoint jzxoutename))
(command "lengthen"
"de"
"-0.4"
(list jzxout start)
(list jzxout end)
""
) ;_ 结束command
) ;_ 结束progn
);_ 结束if
(setvar "clayer" "jzxl")
(command "text"
"s"
"等线体"
"j"
"m"
(polar m (+ angle1 (/ pi 2)) d)
"2"
angle2
dist
) ;_ 结束command
;;标注距离
(setq n (1+ n))
) ;_ 结束REPEAT
(SETVAR "OSMODE" OS)
(setvar "clayer" lay)
(setvar "celtype" ltp)
(SETVAR "DIMZIN" ZIN)
(COMMAND ".UNDO" "E")
(prompt "\n搞定！")
(prompt "\n该区域面积 = ")
(princ (rtos mj 2 4))
(prompt " ")
(prompt "如果当前比例尺为1:500，那么实际面积= ")
(princ (rtos (/ mj 2) 2 4))
(PRINC)
);_ 结束DEFUN
;;;;;;;;;;;;;;;;
;;子程序，判断pline方向，返回1为顺时针，0为逆时针
(defun fangxiang (xx / fd ang offsetObj plineObj x fx)
(setq plineObj (vlax-ename->vla-object xx))
(setq fd (vlax-curve-getFirstDeriv plineObj 0.5))
(setq ang (atan (/ (cadr fd) (car fd))))
(setq offsetplineObj
(car
(vlax-safearray->list
(vlax-variant-value (vla-offset plineObj 0.0001)) ;_ 结束vlax-variant-value
) ;_ 结束vlax-safearray->list
) ;_ 结束car
) ;_ 结束setq
(if (> (vla-get-length plineobj)
(vla-get-length offsetplineobj)
) ;_ 结束>
(setq x 1)
(setq x 0)
) ;_ 结束if
(vla-delete offsetplineObj)
(setq fx x)
) ;_ 结束defun
;;;子程序：pline顶点逆序
(defun reverseLwp (ent1 / a pl how li1 li2 li3)
(setq pl (entget ent1 '("*"))
how nil
) ;_ 结束setq
(foreach an pl
(if (setq a (member (car an) '(10 40 41 42)))
(setq how t)
) ;_ 结束if
(cond ((not how) (setq li1 (cons an li1)))
((and how a)
(cond ((= (car an) 40) (setq an (cons 41 (cdr an))))
((= (car an) 41) (setq an (cons 40 (cdr an))))
((= (car an) 42) (setq an (cons 42 (- 0 (cdr an)))))
(t an)
) ;_ 结束cond
(setq li2 (cons an li2))
)
((and how (not a)) (setq li3 (cons an li3)))
) ;_ 结束cond
) ;_ 结束foreach
(entmod
(append (reverse li1)
(append (cdddr li2) (list (car li2) (cadr li2) (caddr li2)))
(reverse li3)
) ;_ 结束append
) ;_ 结束entmod
) ;_ 结束defun
;;子程序，修改不闭合的pline使其闭合，并按指定点作为起点重绘pline，
;;返回pline的组码。
(defun plchangestart (ee p1 / pt dat ptfrst ename aa data datb dat0 dat1 dat9)
(setq pt (list (car p1) (cadr p1)))
(setq dat (entget ee))
(setq ptfrst (cons 10 pt))
(setq ename (vlax-ename->vla-object ee))
(if (vlax-curve-isClosed ename)
(setq dat dat)
(progn
(setq dat (subst (cons 70 129) (assoc 70 dat) dat))
(setq data (List (Last dat)))
(setq datb (reverse(cdr(cdr(cdr(cdr(cdr(reverse dat))))))))
(setq dat(entmod (append datb data)))
)
)
;;以上一段：如果pl最终不是以“c”闭合而是以捕捉端点方式“闭合”，
;;则修改组码使其达到闭合效果。
(setq
dat0 (reverse (member '(39 . 0.0) (reverse dat)))
dat1 (cdr (member '(39 . 0.0) dat))
dat9 (List (Last dat1))
dat1 (reverse (cdr (reverse dat1)))
data (member ptfrst dat1)
datb (reverse (cdr (member ptfrst (reverse dat1))))
)
(entmod (append dat0 data datb dat9))
;;以上一段：修改组码，使pline从指定点开始。
)

;;制作宗地图。 
;;指定一条闭合的pline，指定起点，程序会自动顺向标注界址点号、界址尺寸，加粗界址线、圈上界址点并算出宗地面积。 
;;程序中用到了本单位系统专用的几个层名，随机用户要使用的话，必须修改相应语句。 
 
(defun c:make( / *error* os zin lay ltp pl startpoint mj j plst ll plename p plast pnext pt1 pt2 pt3 p4 n ss1 jzx jzxename jzxout jzxoutename d l dist m angle1 angle2 start end ) 
(defun *error* (msg) 
    (prompt "\n没搞定") 
    (print msg ) 
    (SETVAR "DIMZIN" ZIN) 
    (SETVAR "OSMODE" OS) 
    (setvar "clayer" lay) 
    (setvar "celtype" ltp) 
    (COMMAND ".UNDO" "E") 
  ) ;_ 结束defun 
(SETVAR "CMDECHO" 0) 
  (COMMAND ".UNDO" "BE") 
  (SETQ OS  (GETVAR "OSMODE") 
ZIN (GETVAR "DIMZIN") 
  ) ;_ 结束SETQ 
  (setq lay (getvar "clayer")) 
  (setq ltp (getvar "celtype")) 
    (SETVAR "DIMZIN" 0) 
  (setvar "celtype" "continuous") 
  (PRINC "\n请选择已封闭的界址线: ") 
   (setq pl (car (entsel))) 
(while (= pl nil) 
(PRINC "\n没点中……拜托请选择已封闭的界址线: ") 
(setq pl (car (entsel))) 
) 
    (command "area" "o" pl) 
    (setq mj (getvar "area")) 
(if (= (fangxiang pl) 0) (reverseLwp pl)) 
(setq startpoint (getpoint "\n请指定界址线的起点：")) 
(while (= (equal startpoint (vlax-curve-getClosestPointTo (vlax-ename->vla-object pl) startpoint) 0.001) nil) 
(setq startpoint (getpoint "\n你指定的点不在线上，请指定界址线的起点：")) 
) 
(SETVAR "OSMODE" 0) 
(SETQ ent (plchangestart pl startpoint)) 
    (setq J    0 
   PLST (LIST) 
    ) ;_ 结束setq 
    (REPEAT (LENGTH ENT) 
      (IF (= (CAR (NTH J ENT)) 10) 
        (SETQ PLST (APPEND PLST (LIST (CDR (NTH J ENT))))) 
      ) ;_ 结束IF 
      (SETQ J (1+ J)) 
    ) ;_ 结束REPEAT 
    (SETQ J  0 
   LL (LENGTH PLST) 
    ) ;_ 结束SETQ 
    (setq plename (vlax-ename->vla-object pl)) 
    
    (REPEAT LL 
      (SETQ P (NTH J PLST)) 
      (if (= j 0) 
        (setq plast (NTH (- ll 1) PLST)) 
        (setq plast (NTH (- J 1) PLST)) 
      ) ;_ 结束if 
      (if (= j (- ll 1)) 
        (setq pnext (NTH 0 PLST)) 
        (setq pnext (NTH (1+ J) PLST)) 
      ) ;_ 结束if 
      (setq pt1 (polar p (angle p plast) 1)) 
      (setq pt2 (polar p (angle p pnext) 1)) 
      (setq 
        pt3 (polar pt1 (angle pt1 pt2) (* 0.5 (distance PT1 PT2))) 
   ;;以这种方式来求得角平分线，得到点位用以标注点号 
      ) ;_ 结束setq 
      (setq P4 (POLAR P (ANGLE Pt3 p) 3)) 
      (setvar "clayer" "jzd") 
      (command "circle" p "0.4") 
      (setvar "clayer" "jzdh") 
      (setq n (rtos (1+ j) 2 0)) 
      (command "text" "s" "等线体" "j" "c" p4 "2" "0" n) 
      (setq J (1+ J)) 
    );_ 结束REPEAT 
    (command "_.explode" pl) 
    (setq ss1 (SSGET "P") 
   n   0 
    ) ;_ 结束setq 
    (REPEAT ll 
      (setq jzx (ssname ss1 n)) 
      (setq jzxename (vlax-ename->vla-object jzx)) 
      (vla-offset jzxename 0.1) 
      (setq jzxout (entlast)) 
      (command "chprop" jzxout "" "la" "jzxout" "") 
      (setq jzxout (entlast)) 
      (setq jzxoutename (vlax-ename->vla-object jzxout)) 
      (vla-offset jzxoutename -0.1) 
      (entdel jzxout) 
      (setq jzxout (entlast)) 
      (if (= (cdr (assoc 0 (entget jzxout))) "ARC") 
        (setq d -2.5) 
        (setq d 2.5) 
      ) ;_ 结束if，该段为下面标注距离时的注记位置做准备。绝大多数圆弧需要的d是负的。 
      (command "pedit" jzxout "y" "w" "0.3" "") 
      (setq jzxout (entlast)) 
      ;;以上偏移了每段jzx，变成jzxout后偏移回原位，变粗，得到对应的图元jzxout。 
      (setq jzxoutename (vlax-ename->vla-object jzxout)) 
      (setq l (vlax-curve-getDistAtPoint 
         jzxoutename 
         (vlax-curve-getEndPoint jzxoutename) 
       ) ;_ 结束vlax-curve-getDistAtPoint 
      ) ;_ 结束setq 
      ;;l为线长 
      (setq dist (rtos (/ l 2) 2 2)) 
      (setq m (vlax-curve-getPointAtDist jzxoutename (/ l 2))) 
      ;;m为中点 
      (setq angle1 (angle (vlax-curve-getstartPoint jzxoutename) 
     (vlax-curve-getendPoint jzxoutename) 
     ) ;_ 结束angle 
      ) ;_ 结束setq 
      ;;angle1为距离注记的位置 
      (setq angle2 (/ (* angle1 180) pi)) 
      ;;angle2为注记旋转的角度,在某些情况下注记的旋转角度需要反转 
      (if (and (> angle2 90) (< angle2 270)) 
        (setq angle2 (+ angle2 180)) 
      ) ;_ 结束if 
      ;;以下的if分别考虑线长小于0.8和大于0.8两种情况下，jzxout的处理。 
      ;;为了留出界址点位置，jzxout小于0.8，删除；大于0.8，截短。 
      (if (<= l 0.8) 
        (entdel jzxout) 
        (progn (setq start (vlax-curve-getStartPoint jzxoutename)) 
        (setq end (vlax-curve-getendPoint jzxoutename)) 
        (command "lengthen" 
          "de" 
          "-0.4" 
          (list jzxout start) 
          (list jzxout end) 
          "" 
        ) ;_ 结束command 
        ) ;_ 结束progn 
      );_ 结束if 
      (setvar "clayer" "jzxl") 
      (command "text" 
        "s" 
        "等线体" 
        "j" 
        "m" 
        (polar m (+ angle1 (/ pi 2)) d) 
        "2" 
        angle2 
        dist 
      ) ;_ 结束command 
      ;;标注距离 
      (setq n (1+ n)) 
    ) ;_ 结束REPEAT 
  (SETVAR "OSMODE" OS) 
  (setvar "clayer" lay) 
  (setvar "celtype" ltp) 
  (SETVAR "DIMZIN" ZIN) 
  (COMMAND ".UNDO" "E") 
  (prompt "\n搞定！") 
  (prompt "\n该区域面积 = ") 
  (princ (rtos mj 2 4)) 
  (prompt "  ") 
  (prompt "如果当前比例尺为1:500，那么实际面积= ") 
  (princ (rtos (/ mj 2) 2 4)) 
  (PRINC) 
);_ 结束DEFUN 
 
;;;;;;;;;;;;;;;; 
;;子程序，判断pline方向，返回1为顺时针，0为逆时针 
(defun fangxiang (xx / fd ang offsetObj plineObj x fx) 
  (setq plineObj (vlax-ename->vla-object xx)) 
  (setq fd (vlax-curve-getFirstDeriv plineObj 0.5)) 
  (setq ang (atan (/ (cadr fd) (car fd)))) 
  (setq offsetplineObj 
  (car 
    (vlax-safearray->list 
      (vlax-variant-value (vla-offset plineObj 0.0001)) ;_ 结束vlax-variant-value 
    ) ;_ 结束vlax-safearray->list 
  ) ;_ 结束car 
  ) ;_ 结束setq 
  (if (> (vla-get-length plineobj) 
  (vla-get-length offsetplineobj) 
      ) ;_ 结束> 
    (setq x 1) 
    (setq x 0) 
  ) ;_ 结束if 
  (vla-delete offsetplineObj) 
  (setq fx x) 
) ;_ 结束defun 
;;;子程序：pline顶点逆序 
(defun reverseLwp (ent1 / a pl how li1 li2 li3) 
  (setq pl  (entget ent1 '("*")) 
how nil 
  ) ;_ 结束setq 
  (foreach an pl 
    (if (setq a (member (car an) '(10 40 41 42))) 
      (setq how t) 
    ) ;_ 结束if 
    (cond ((not how) (setq li1 (cons an li1))) 
   ((and how a) 
    (cond ((= (car an) 40) (setq an (cons 41 (cdr an)))) 
   ((= (car an) 41) (setq an (cons 40 (cdr an)))) 
   ((= (car an) 42) (setq an (cons 42 (- 0 (cdr an))))) 
   (t an) 
    ) ;_ 结束cond 
    (setq li2 (cons an li2)) 
   ) 
   ((and how (not a)) (setq li3 (cons an li3))) 
    ) ;_ 结束cond 
  ) ;_ 结束foreach 
  (entmod 
    (append (reverse li1) 
     (append (cdddr li2) (list (car li2) (cadr li2) (caddr li2))) 
     (reverse li3) 
    ) ;_ 结束append 
  ) ;_ 结束entmod 
) ;_ 结束defun 
;;子程序，修改不闭合的pline使其闭合，并按指定点作为起点重绘pline， 
;;返回pline的组码。 
(defun plchangestart (ee p1 / pt dat ptfrst ename aa data datb dat0 dat1 dat9) 
(setq pt (list (car p1) (cadr p1))) 
(setq dat (entget ee))      
(setq   ptfrst (cons 10 pt)) 
(setq ename (vlax-ename->vla-object ee)) 
(if (vlax-curve-isClosed ename) 
(setq dat dat) 
(progn 
(setq dat (subst (cons 70 129) (assoc 70 dat) dat)) 
(setq data (List (Last dat))) 
(setq datb (reverse(cdr(cdr(cdr(cdr(cdr(reverse dat)))))))) 
(setq dat(entmod (append datb data))) 
) 
) 
;;以上一段：如果pl最终不是以“c”闭合而是以捕捉端点方式“闭合”， 
;;则修改组码使其达到闭合效果。 
(setq 
     dat0 (reverse (member '(39 . 0.0) (reverse dat))) 
     dat1 (cdr (member '(39 . 0.0)  dat)) 
     dat9 (List (Last dat1)) 
     dat1 (reverse (cdr (reverse dat1))) 
     data (member ptfrst dat1) 
     datb (reverse (cdr (member ptfrst (reverse dat1)))) 
) 
(entmod (append dat0 data datb dat9)) 
;;以上一段：修改组码，使pline从指定点开始。 
)

zhongguola · 发表于 2011-3-15 15:56:00

命令: MAKE
请选择已封闭的界址线:
选择对象:
请指定界址线的起点：
没搞定
"AutoCAD 变量设置被拒绝: \"clayer\" \"jzd\""

jackynine · 发表于 2011-3-15 16:30:43

下载后测试许久，总算有个结果了。

xiaxiang · 发表于 2011-3-15 17:09:12

楼上出错的应仔细阅读程序说明。程序完成了，也学到了东西，同谢ANDYHON!

mandala · 发表于 2011-3-15 17:57:36

本帖最后由 mandala 于 2011-3-15 17:59 编辑

嗯，andyhon的那段lsp是最关键的，给了我一个可行的思路。

最终的宗地图程序其实还有不少可以改进的地方，比如设定entsel的结果只能是多段线等等。有空的时候再改进一下吧。

mandala · 发表于 2011-3-15 17:58:08

zhongguola 发表于 2011-3-15 15:56
命令: MAKE
请选择已封闭的界址线:
选择对象:

买家电也得看说明书啊？何况是程序……

天塘河 · 发表于 2011-12-9 09:53:00

高手们。我想知道如何标注多段线的点号

shang_123 · 发表于 2011-12-11 20:30:39

mandala 发表于 2011-3-15 15:27
嗯，看来我只好硬改组码了，结果如下：

问下这个怎么连接起来呢？

账号		自动登录	找回密码
密码			注册

[基础] 请教：如何重新指定一条封闭多段线的起点？（已解决，感谢andyhon）

本帖子中包含更多资源