[函数]返回符合长度要求的直线选择集

mccad

(defun SelLinesByLength (Low Hig / CurEnl CurEnt CurSet EntCnt LinLgt)
(if (setq CurSet (ssget "_X" '((0 . "LINE")))) ;过滤直线
  (progn                                ;如果找到直线...
   (setq EntCnt 0)                      ;设置图元计数
   (repeat (sslength CurSet)            ;扫描选择集
    (setq CurEnt (ssname CurSet EntCnt) ;提取图元
          CurEnl (entget CurEnt)        ;提取图元列表
          LinLgt (distance              ;获取直线对象的长度
                  (cdr (assoc 10 CurEnl))
                  (cdr (assoc 11 CurEnl))
                 )
    )
    (if (<= Low LinLgt Hig)             ;如果长度相符...
     (setq EntCnt (1+ EntCnt))          ;获取下一个对象...
     (ssdel CurEnt CurSet)              ;不然...从选择集中删除图元...
    )                                   ;
   )                                    ;检查是否为空的选择集
   (setq CurSet (if (= (sslength CurSet) 0) nil CurSet))
  )
)
CurSet                                 ;返回选择集
)

用法:
(SelLinesByLength MinValue MaxValue)
返回符合长度要求的直线选择集

qinleilei

好东西沉得太深了,帮你挖出来

xyp1964

2. ;; xyp-SelCurvesByLength 返回符合长度要求的曲线选择集 (xyp-SelCurvesByLength ss Low Hig)
   
3. (defun xyp-SelCurvesByLength (ss Low Hig / ll)
   
4.   (xyp-list2ss
   
5.     (vl-remove-if-not
   
6.       '(lambda (x) (setq ll (xyp-CurveLength x)) (<= low ll hig))
   
7.       (vl-remove-if-not 'xyp-curve-check (xyp-ss2list ss))
   
8.     )
   
9.   )
   
10. )
    
11. 
    
12. (if (setq ss1 (xyp-SelCurvesByLength (ssget) 200 5000))
    
13.   (sssetfirst nil ss1)
    
14. )

;; xyp-SelCurvesByLength 返回符合长度要求的曲线选择集 (xyp-SelCurvesByLength ss Low Hig)<br /> (defun xyp-SelCurvesByLength (ss Low Hig / ll)<br />   (xyp-list2ss<br />     (vl-remove-if-not<br />       '(lambda (x) (setq ll (xyp-CurveLength x)) (<= low ll hig))<br />       (vl-remove-if-not 'xyp-curve-check (xyp-ss2list ss))<br />     )<br />   )<br /> )<br /> <br /> (if (setq ss1 (xyp-SelCurvesByLength (ssget) 200 5000))<br />   (sssetfirst nil ss1)<br /> )

qinleilei

xyp1964 发表于 2015-6-30 13:41

院长威武!不过不喜欢看院长的代码,只喜欢看你的演示动画