光洁度等的标注

jingsabing

;这是一个基于AutoCAD 14.0下关于画基准和光洁度符号的程序
;它可以在P_CONT_X层上画基准和光洁度符号
;本程序作者b.w
;本程序无偿使用
;如有更好建议，请联系b.w
;版本:2.0.00
;日期:27/12-2001

(defun B_CCDN_DRAW
  (
  /
  B_ccdn_point0
  B_ccdn_point1
  B_ccdn_point2
  B_ccdn_point3
  )
  (setq B_ccdn_point0 B_base_ins)
  (setq B_ccdn_point1  (polar B_ccdn_point0 (+ B_base_angle 2.094395) (* B_base_scale 5.6)))
  (setq B_ccdn_point2  (polar B_ccdn_point0 (+ B_base_angle 1.047198) (* B_base_scale 11.2)))
  (setq B_ccdn_point3  (polar B_ccdn_point0 (+ B_base_angle 1.570796) (* B_base_scale 3.233161)))
  (setvar "OSMODE"        0)
  (command "line" B_ccdn_point0 B_ccdn_point1 ""
  );end-command
  (command "line" B_ccdn_point0 B_ccdn_point2 ""
  );end-command
  (command "circle" B_ccdn_point3 (* B_base_scale 1.61658)
  );end-command
  (setvar "OSMODE"        51)
);end-B_CCDN_DRAW

(defun B_CCDY_DRAW
  (
  /
  B_ccdy_point0
  B_ccdy_point1
  B_ccdy_point2
  B_ccdy_point3
  B_ccdy_point4
  B_ccdy_text_angle
  )
  (setq B_ccdy_point0 B_base_ins)
  (setq B_ccdy_point1  (polar B_ccdy_point0 (+ B_base_angle 2.094395) (* B_base_scale 5.6)))
  (setq B_ccdy_point2  (polar B_ccdy_point0 (+ B_base_angle 1.047198) (* B_base_scale 5.6)))
  (setq B_ccdy_point3  (polar B_ccdy_point0 (+ B_base_angle 1.047198) (* B_base_scale 11.2)))
  (setq B_ccdy_point4  (polar B_ccdy_point0 (+ B_base_angle 1.570796) (* B_base_scale 7.7)))
  (setvar "OSMODE"        0)
  (command "line" B_ccdy_point0 B_ccdy_point1 B_ccdy_point2 ""
  );end-command
  (command "line" B_ccdy_point0 B_ccdy_point3 ""
  );end-command
  (setq B_ccdy_text_angle (* B_base_angle 57.29577))
  (if (and (<= B_ccdy_text_angle 270.0) (> B_ccdy_text_angle 90.0))
    (setq B_ccdy_text_angle (- B_ccdy_text_angle 180.0))
  );end-if
  (command "text" "S" "SONG" "J" "M" B_ccdy_point4 (* B_base_scale 3.5) B_ccdy_text_angle B_base_text
  );end-command  
  (setvar "OSMODE"        51)
);end-B_CCDY_DRAW

(defun B_BASE_DRAW
  (
  /
  B_base_point0
  B_base_point1
  B_base_point2
  B_base_point3
  B_base_point4
  )
  (setq B_base_point0  (polar B_base_ins B_base_angle B_base_scale))
  (setq B_base_point1  (polar B_base_ins B_base_angle (* B_base_scale 4.5)))
  (setq B_base_point2  (polar B_base_ins B_base_angle (* B_base_scale 7.0)))
  (setq B_base_point3  (polar B_base_point0 (+ B_base_angle 1.570796) (* B_base_scale 2.5)))
  (setq B_base_point4  (polar B_base_point0 (+ B_base_angle 1.570796) (* B_base_scale -2.5)))
  (setvar "OSMODE"        0)
  (command "line" B_base_point3 B_base_point4 ""
  );end-command
  (command "line" B_base_point0 B_base_point1 ""
  );end-command
  (command "circle" B_base_point2 (* B_base_scale 2.5)
  );end-command
  (command "text" "S" "SONG" "J" "M" B_base_point2 (* B_base_scale 3.5) "0" B_base_text
  );end-command  
  (setvar "OSMODE"        51)
);end-B_BASE_DRAW

(defun B_BASE_LAYER
  (
  /
  current_layer
  lay_exist
  current_lt
  )
  (setq current_layer (getvar "CLAYER"))
  (setq lay_exist (tblsearch "layer" "_CONT_X"))
  (if (/= lay_exist nil)
    (setvar "CLAYER" "_CONT_X")
    (setvar "CLAYER" current_layer)
  );end-if
  (setq current_lt (getvar "CELTYPE"))
  (if (/= current_lt "CONTINUOUS")
    (setvar "CELTYPE" "CONTINUOUS")
    (setvar "CELTYPE" "BYLAYER")
  );end-if
(cond
      ((= B_base_name "B")
       (B_BASE_DRAW)
      );end-base
      ((= B_base_name "N")
       (B_CCDN_DRAW)
      );end-ccdn
      ((= B_base_name "Y")
       (B_CCDY_DRAW)
      );end-ccdy
  );end-cond
  (setvar "CELTYPE" current_lt)
  (setvar "CLAYER" current_layer)
);end-B_BASE_LAYER

(defun B_BASE
  (
  B_base_name
  /
  B_base_ins
  B_base_scale
  B_base_angle
  B_base_text
  )
  (setvar "OSMODE"        51)
  (setq B_base_ins (getpoint "请输入插入点: "))
  (setq B_base_scale (getreal "请输入比例："))
  (setq B_base_angle (getorient "请输入插入角度: "))
  (if (/= B_base_name "N")
    (setq B_base_text (getstring "请输入文字："))
  );end-if
  (setvar "OSMODE"        0)
  (B_BASE_LAYER)
  (princ)
);end-B_BASE