求助，关于grread函数的用法

dalin1985

写了一个小程序想加入动态显示，不知道该加在哪里，希望高手赐教。;标注坐标
(defun c:11 ()
  (setvar "cmdecho" 0)
  (setq osmode_bak (getvar "osmode"))
  (setvar "osmode" 0)
  (setq p1 (getpoint "\nP1:"))
  (setq p2 (getpoint p1 "\nP2:"))
  (setq ang (angle p1 p2))
  (cond
    ((> ang (* 1.5 pi)) (setq p3 (polar p2 0 18)))
    ((> ang pi) (setq p3 (polar p2 pi 18)))
    ((> ang (* 0.5 pi)) (setq p3 (polar p2 pi 18)))
    ((< ang (* 0.5 pi)) (setq p3 (polar p2 0 18)))
  )
  (setq pt1x (rtos (car p1) 2 3))
  (setq pt1y (rtos (cadr p1) 2 3))
  (command "pline" p1 p2 p3 "")
  (if (< (car p2) (car p1)) (setq pt p3) (setq pt p2))
  (command "text" pt 2 "" pt1x)
  (command "text" "j" "tl" pt 2 "" pt1y)
  (setvar "osmode" osmode_bak)
  (setvar "cmdecho" 1)
  (princ)
)



该贴已经同步到 dalin1985的微博

VBALISPER

帮你顶.跟你一起学一学这个函数.

zyhandw

也顶一个，期望有高手来详解一下这个函数！

cable2004

(defun c:tt  (/ MIND P1 LOOP GR P2 DIST ANG TXTSTR TEXT LINE LINE1 *error*)
  (setq p1 (getpoint "\n第一点:"))
  (if p1
    (setq p1 (trans p1 1 0)))
  (setq loop t)
  (while (and p1 loop)
    (setq gr (grread t 15))
    (cond
      ((= 5 (car gr))
       (setq p2 (trans (cadr gr) 1 0))
       (setq dist (distance p1 p2)
             p2 (polar p1 (setq ang (angle p1 p2)) dist)
             )
       (setq txtstr (strcat (rtos (car p1) 2 3) "\n" (rtos (cadr p1) 2 3) ))
       (if text
         (progn
            (setq text (subst (cons 1 txtstr) (assoc 1 text) text))
           (setq text (subst (cons 10 (polar p2 (* pi 0.5) 6.5)) (assoc 10 text) text))
           (entmod text)
           )
         (progn
           (entmake
             (list '(0 . "MTEXT")
                   '(100 . "AcDbEntity")
                   '(67 . 0)
                   '(100 . "AcDbMText")
                   (cons 10 (polar p2 (* pi 0.5) 6.5))
                   (cons 1 txtstr)
                   (cons 40 5)
                   )
             )
           (setq text (entget (entlast)))
           )
         )
       (if line
         (entmod (subst (cons 11 p2) (assoc 11 line) line))
         (progn
           (entmake
             (list '(0 . "line")
                   (cons 10 p1)
                   (cons 11 p2)
                   )
             )
           (setq line (entget (entlast)))
           )
         )
       )
      
      ((or
         (= 3 (car gr))
         (= 25 (car gr))
         (and (= 2 (car gr)) (= (cadr gr) 13))
         (and (= 2 (car gr)) (= (cadr gr) 32))
         )
       (setq loop nil)
     
       )
      )
    )

  
           (entmake
             (list '(0 . "line")
                   (cons 10 p2)
                   (cons 11 (polar p2 0 50))
                   )
             )
           
  (princ)
  )

陨落

我会的一种grread的用法是：先建立项目，然后通过grread函数的返回值来修改这个项目