【多行文字格式清除】

1028695446

;;多行文字样式清除
(defun C:mtx(/ ss i ent elist )
        (if (setq ss(ssget '((0 . "TEXT,MTEXT"))))
                (progn
                        (setq i 0)
                        (repeat (sslength ss)
                                (setq ent (ssname ss i))
                                (setq elist (entget ent))
                                (entmod
                                        (subst
                                                (cons 1
                                                        (mtext2text (cdr(assoc 1 elist)))
                                                )
                                                (assoc 1 elist)
                                                elist                                       
                                        )       
                                )
                                (setq i (1+ i))                       
                        )
                )
        )
)

;提取多行文字,去除无用格式符号--来自明经
(defun mtext2text(MTextString / regex s)
        (setq regex(vlax-create-object "Vbscript.RegExp")) ;引用正则表达式控件
        (vlax-put-property regex "IgnoreCase" 0) ;不忽略大小写
        (vlax-put-property regex "Global" 1) ;匹配方式，全文字匹配
        (setq s MTextString)
        ;替换\\字符
        (vlax-put-property regex "Pattern" "\\\\\\\\")
        (setq s(vlax-invoke-method  regex "Replace" s (chr 1)))
        ;替换\{字符
        (vlax-put-property regex "Pattern" "\\\\{")
        (setq s(vlax-invoke-method  regex "Replace" s (chr 2)))
        ;替换\}字符
        (vlax-put-property regex "Pattern" "\\\\}")
        (setq s(vlax-invoke-method  regex "Replace" s (chr 3)))
        ;删除段落缩进格式
        (vlax-put-property regex "Pattern" "\\\\pi(.[^;]*);")
        (setq s(vlax-invoke-method  regex "Replace" s ""))
        ;删除制表符格式
        (vlax-put-property regex "Pattern" "\\\\pt(.[^;]*);")
        (setq s(vlax-invoke-method  regex "Replace" s ""))
        ;删除堆迭格式
        (vlax-put-property regex "Pattern" "\\\\S(.[^;]*)(\\^|#|\\\\)(.[^;]*);")
        (setq s(vlax-invoke-method  regex "Replace" s ""))
        ;删除字体、颜色、字高、字距、倾斜、字宽、对齐格式
        (vlax-put-property regex "Pattern" "(\\\\F|\\\\f|\\\\C|\\\\H|\\\\\T|\\\\Q|\\\\W|\\\\A)(.[^;]*);")
        (setq s(vlax-invoke-method  regex "Replace" s ""))
        ;删除下划线、删除线格式
        (vlax-put-property regex "Pattern" "(\\\\L|\\\\O|\\\\l|\\\\o)")
        (setq s(vlax-invoke-method  regex "Replace" s ""))
        ;删除不间断空格格式
        (vlax-put-property regex "Pattern" "\\\\~")
        (setq s(vlax-invoke-method  regex "Replace" s ""))
        ;删除换行符格式
        (vlax-put-property regex "Pattern" "\\\\P")
        (setq s(vlax-invoke-method  regex "Replace" s ""))
        ;删除换行符格式(针对Shift+Enter格式)
        (vlax-put-property regex "Pattern" "\n")
        (setq s(vlax-invoke-method  regex "Replace" s ""))
        ;删除{}
        (vlax-put-property regex "Pattern" "({|})")
        (setq s(vlax-invoke-method  regex "Replace" s ""))
        ;替换回\\,\{,\}字符
        (vlax-put-property regex "Pattern" "\\x01")
        (setq s(vlax-invoke-method  regex "Replace" s "\\"))
        (vlax-put-property regex "Pattern" "\\x02")
        (setq s(vlax-invoke-method  regex "Replace" s "{"))
        (vlax-put-property regex "Pattern" "\\x03")
        (setq s(vlax-invoke-method  regex "Replace" s "}"))
       
        (vlax-release-object regex)
        s
)

gaics

ferious 发表于 2023-12-26 12:53
清理格式后怎么换行变了？能帮忙看下吗

“换行”也是一种格式，都清除了

juliana207

就像保留分数, 删了 "删除堆迭格式", 不过分数变大了怎么办?

664571221

你好群主错误: no function definition: VLAX-CREATE-OBJECT

llp0420

牛逼

llp0420

用上了

艾皮凯克

感谢，比smt好用

wosiguwozai0830

很好用，感谢！

vladimirputin

非常好的代码，谢谢楼主分享啊。

jkop

简单好用，收藏！

ferious

清理格式后怎么换行变了？能帮忙看下吗

gaics

当文字比较长、elist组码出现“3”时怎么处理？