[原创] 判断点在封闭曲线的位置

caoyin · 发表于 2008-5-16 16:35:00

本帖最后由作者于 2008-5-16 19:17:35 编辑

;;=======================================
;;  [原创] 判断点在封闭曲线的位置
;;  by caoyin @ www.mjtd.com
;;=======================================

;; 欢迎，大家帮忙测试，指正。抛砖引玉。。。

;; 参数 PT------任意点
;;    CURVE---任意封闭曲线
;; 返回 0------->在曲线上
;;    T------->在曲线内
;;    nil----->在曲线外

(defun LT:PT-INCURVE (PT CURVE / GetInters OBJ MINPT MAXPT E PS LST X Y)
(defun GetInters (OBJ1 OBJ2 / PS LST)
(setq PS (vla-intersectwith OBJ1 OBJ2 0)
PS (vl-catch-all-apply 'vlax-safearray->list (list (vlax-variant-value PS)))
)
(if (and PS (not (vl-catch-all-error-p PS)))
(while (setq LST (cons (list (car PS) (cadr PS)) LST)
PS (cdddr PS)
)
)
)
LST
)
(if (equal (vlax-curve-getClosestPointTo CURVE PT) PT 1E-6)
0
(progn
(setq OBJ (vlax-ename->vla-object CURVE))
(vla-getboundingbox OBJ 'MINPT 'MAXPT)
(mapcar '(lambda (X) (set X (vlax-safearray->list (eval X)))) '(MINPT MAXPT))
(entmake (list '(0 . "LINE")
(list 10 (car MINPT) (cadr PT))
(list 11 (car MAXPT) (cadr PT))
'(60 . 1)
)
)
(setq E (entlast) LST1 (GetInters OBJ (vlax-ename->vla-object E)))
(entdel E)
(if LST1
(setq LST1 (vl-remove-if
'(lambda (X / PP A)
(setq PP (vlax-curve-getParamAtPoint CURVE X)
A (angle '(0 0)
(vlax-curve-getFirstDeriv CURVE PP)
)
)
(or (equal A 0 1E-6)
(equal A PI 1E-6)
(equal A (* PI 2) 1E-6)
(equal (fix PP) PP 1E-6)
)
)
LST1
)
)
)
(entmake (list '(0 . "LINE")
(list 10 (car PT) (cadr MAXPT))
(list 11 (car PT) (cadr MINPT))
'(60 . 0)
)
)
(setq E (entlast) LST2 (GetInters OBJ (vlax-ename->vla-object E)))
(entdel E)
(if LST2
(setq LST2 (vl-remove-if
'(lambda (X / PP A)
(setq X (vlax-curve-getClosestPointTo CURVE X)
PP (vlax-curve-getParamAtPoint CURVE X)
A (angle (vlax-curve-getFirstDeriv CURVE PP)
'(0 0)
)
)
(or (equal A (/ PI 2) 1E-6)
(equal A (* PI 1.5) 1E-6)
(equal (fix PP) PP 1E-6)
)
)
LST2
)
)
)
(and LST1
LST2
(progn
(setq X (vl-sort-i (mapcar 'car (cons PT LST1)) '<)
Y (length (member 0 X))
)
(and (zerop (rem Y 2)) (= (rem (- (length X) Y) 2) 1))
)
(progn
(setq X (vl-sort-i (mapcar 'cadr (cons PT LST2)) '<)
Y (length (member 0 X))
)
(and (zerop (rem Y 2)) (= (rem (- (length X) Y) 2) 1))
)
)
)
)
)

(defun LT:PT-INCURVE (PT CURVE / GetInters OBJ MINPT MAXPT E PS LST X Y)
  (defun GetInters (OBJ1 OBJ2 / PS LST)
    (setq PS (vla-intersectwith OBJ1 OBJ2 0)
          PS (vl-catch-all-apply 'vlax-safearray->list (list (vlax-variant-value PS)))
    )
    (if (and PS (not (vl-catch-all-error-p PS)))
      (while (setq LST (cons (list (car PS) (cadr PS)) LST)
                   PS  (cdddr PS)
             )
      )
    )
    LST
  )
  (if (equal (vlax-curve-getClosestPointTo CURVE PT) PT 1E-6)
    0
    (progn
      (setq OBJ (vlax-ename->vla-object CURVE))
      (vla-getboundingbox OBJ 'MINPT 'MAXPT)
      (mapcar '(lambda (X) (set X (vlax-safearray->list (eval X)))) '(MINPT MAXPT))
      (entmake (list '(0 . "LINE")
                     (list 10 (car MINPT) (cadr PT))
                     (list 11 (car MAXPT) (cadr PT))
                     '(60 . 1)
               )
      )
      (setq E (entlast) LST1 (GetInters OBJ (vlax-ename->vla-object E)))
      (entdel E)
      (if LST1
        (setq LST1 (vl-remove-if
                     '(lambda (X / PP A)
                        (setq PP (vlax-curve-getParamAtPoint CURVE X)
                              A  (angle '(0 0)
                                        (vlax-curve-getFirstDeriv CURVE PP)
                                 )
                        )
                        (or (equal A 0 1E-6)
                            (equal A PI 1E-6)
                            (equal A (* PI 2) 1E-6)
                            (equal (fix PP) PP 1E-6)
                        )
                      )
                     LST1
                   )
        )
      )
      (entmake (list '(0 . "LINE")
                     (list 10 (car PT) (cadr MAXPT))
                     (list 11 (car PT) (cadr MINPT))
                     '(60 . 0)
               )
      )
      (setq E (entlast) LST2 (GetInters OBJ (vlax-ename->vla-object E)))
      (entdel E)
      (if LST2
        (setq LST2 (vl-remove-if
                     '(lambda (X / PP A)
                        (setq X  (vlax-curve-getClosestPointTo CURVE X)
                              PP (vlax-curve-getParamAtPoint CURVE X) 
                              A  (angle (vlax-curve-getFirstDeriv CURVE PP)
                                       '(0 0)
                                )
                        )
                        (or (equal A (/ PI 2) 1E-6)
                            (equal A (* PI 1.5) 1E-6)
                            (equal (fix PP) PP 1E-6)
                        )
                      )
                     LST2
                   )
        )
      )
      (and LST1
           LST2
           (progn
             (setq X (vl-sort-i (mapcar 'car (cons PT LST1)) '<)
                   Y (length (member 0 X))
             )
             (and (zerop (rem Y 2)) (= (rem (- (length X) Y) 2) 1))
           )
           (progn
             (setq X (vl-sort-i (mapcar 'cadr (cons PT LST2)) '<)
                   Y (length (member 0 X))
             )
             (and (zerop (rem Y 2)) (= (rem (- (length X) Y) 2) 1))
           )
      )
    )
  )
)

;;====================================================
;; 测试

(defun c:test (/ CURVE PT X)
(if (and (setq CURVE (entsel "\n选择封闭曲线: "))
(setq CURVE (car CURVE))
)
(while (setq PT (getpoint "\n拾取任意点: "))
(setq X (LT:PT-INCURVE PT CURVE))
(princ "......在曲线")
(princ (cond ((= X 0) "上。") (X "内。") (T "外。")))
)
)
(princ)
)

无痕 · 发表于 2008-5-16 18:42:00

试试看：

测试点在多义线内，并与其中一段在同一直线上（垂直或水平）

caoyin · 发表于 2008-5-16 19:20:00

试试看：
测试点在多义线内，并与其中一段在同一直线上（垂直或水平）

已经修正.

谢谢无痕斑竹提示,原来只考虑弧段的切点,没考虑顶点问题(红色为添加的顶点判断)

danxingpen · 发表于 2008-5-17 10:17:00

好,,,,顶一个~

爱丁保 · 发表于 2009-9-7 20:08:00

好东东,顶一顶

liu_kunlun · 发表于 2009-9-8 08:10:00

我原以为，通过给定点的任意方向的一条射线，如果与给定曲线交点数为单数个，就可判断为在曲线内。不知这个思路是否正确?另外，经试验intersectwith返回的交点数并不总是正确，不知何故，故该思路也不能实施。今天看此程序，如此复杂，是否可解释一下原理？

caoyin · 发表于 2009-9-16 20:17:00

本帖最后由作者于 2009-9-16 21:24:49 编辑

楼上所言不差，1楼的算法是复杂了，射线法可能是一种不错的算法。

射线法原理如下：

在通过指定的点绘制一条射线，有凸度的线排除掉切点，对有顶点的排除掉顶点，然后交点为奇数的即可判断为在曲线内。

正如你所说intersectwith存在的不确定因素，所以我还还有一种思路，不用intersectwith 的，不知可否：

1.将曲线写入特定的XDATA；

2.用XDATA作为过滤条件 (ssget "f" 。。。)创建选集

3.用 ssnamex 得到交点

4.用上面射线法排除顶点和切点

5.删除XDATA

我估计ssget和XDATA的效率很低，但是起码不用intersectwith了

不死猫 · 发表于 2009-9-16 21:02:00

以前在网上搜集的一个判定点在封闭多线段内的

涉及到算法问题:

借花献佛大伙研究一下

(我是用线段拟合曲线然后调用了这个函数)

liu_kunlun · 发表于 2009-9-16 21:02:00

谢谢caoyin的解释。

还可以利用wmf，用短线构造曲线，再拦选，并考虑只去掉这些短线的顶点。这样不够精确，估计效率也比较低，但在现在的计算机上效率应该不不是大问题。

不死猫 · 发表于 2009-9-16 21:07:00

另外还有一个讨论

http://discussion.autodesk.com/forums/thread.jspa?threadID=219833&tstart=1124

账号		自动登录	找回密码
密码			注册

[原创] 判断点在封闭曲线的位置

本帖子中包含更多资源

本帖子中包含更多资源