[飞马系列] Lisp利用MatLab 学习1-Delaunay三角网感谢高山流水

qjchen · 发表于 2011-12-15 09:12

[飞马系列] Lisp利用MatLab 学习1-Delaunay三角网感谢高山流水

在此贴-- http://bbs.mjtd.com/forum.php?mod=viewthread&tid=62106&page=6#pid393539
中，高山流水兄非常让人激动地引入了怎么用Lisp调用Matlab绘制图形的好函数。
我是近日才看到这个帖子的，非常受启发。

于是最近利用了高山流水兄的函数，做了一些探讨了研究，包括矩阵求逆等问题，有时间将慢慢添加。
Delaunay三角形是计算几何中一个重要的问题
以前我曾经用Lisp写过一个三角网程序，是翻译C语言的，
http://www.mjtd.com/Codes/ArticleShow.asp?ArticleID=1143
写的冗长无比，之后一直寻求更好的方法，也用C#编过，速度还可以。
Highflybird版主曾经用arx编过一个奇快无比的三角网，大概10000个点<1秒。C++的效率那是神速。
http://bbs.mjtd.com/forum.php?mod=redirect&goto=findpost&ptid=82644&pid=434713&fromuid=250774

因为Matlab是一个国际顶级的数学软件，也具备编程功能，在.Net方面可以和C#方便地连接，但在Lisp方面，目前为止
高山流水兄的函数是最具备现实意义的。

于是，在学习高山流水兄代码的基础上，利用Matlab的Delaunay函数，编写了如下一段代码。希望你也喜欢。

注意：系统内必须安装有Matlab（这是一个很大的应用程序），另，运行本程序的时候，最好先打开Matlab，可以节省时间。
本代码的效率一般般，10000个点大概得8秒左右，其实Matlab计算很快，大概在0.3秒左右，我的程序的大部分时间是在处理表和文件的写入上，应该说我用的文本操作方法还是比较落后的，希望高手们指正。看看有什么更好的交互方法。非常感谢。

后续希望能进一步地利用Matlab的优化工具箱啊，神经网络啊，遗传算法啊等等来看看能如何拓展Lisp的应用范畴。

;;;;这是一个利用Matlab程序进行Delaunay三角网绘制的程序， ;
;;;;作者：华南理工大学qjchen;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;日期: 2011.12.15 ;
;;;;感谢：高山流水朋友在Mjtd上给出的Lisp调用Matlab函数进行计算的代码;;
;;;; 极大地拓宽了AutoCAD可能的分析计算功能 ;
;;;;软件思路：1）找点，输出到文本文件 2）利用Matlab计算，输出结果 ;;;;
;;;; 3）回调结果绘图 ;
;;;__________________________________________________________________;
;;; Purpose: draw Delaunay triangle by MatLab program ;
;;; write by qjchen ;
;;; Great Thanks to GSLS, his program about Lisp Call Matlab function;
;;; enable Autocad to use plenty of MatLab tools ;
;;;__________________________________________________________________;
;;;_____________________高山流水的函数 ______________________________;
;;; 调用MATLAB.APP, ;
(defun ss-create-matlab-object ()
(vl-load-com)
(if (or (null ss_mat_obj) (= ss_mat_obj :vlax-false))
(setq ss_mat_obj (vlax-get-or-create-object "matlab.application"))
)
)
;;; 卸载
(defun ss-release-matlab-object()
(if (= ss_mat_obj :vlax-true)
(progn
(vlax-release-object ss_mat_obj)
(setq ss_mat_obj nil)
)
)
)
;(setq ss_mat_obj (vlax-get-or-create-object (findfile "c:\\matlab701\\toolbox\\modelsim\\win32\\matlablink.dll")))
;;;ss-matlab-execute
;;;功能：调用MATLAB EXECUTE功能
;;;str1 Malab中的参数执行语句，一般为参数式函数
;;;str2 Malab中的显示执行语句,语句含义参考Matlab,如上述例题中保存在C盘的test.jpg
;;;Uility 显示完后是否关闭，
;;;Written By GSLS(SS) 2010-07-25 4:45;;;高山流水的函数
(defun ss-matlab-execute(str1 str2 uility /)
(vlax-invoke-method ss_mat_obj 'MinimizeCommandWindow)
(vlax-invoke-method ss_mat_obj 'Execute str1)
(vlax-invoke-method ss_mat_obj 'Execute str2)
)
;;;____________end of 高山流水的函数_________________________________;
;;;____________qjchen subroutine_____________________________________;
;;;String delim by [email]qjchen@gmail.com[/email]
;;;根据delim将str分解为表
(defun q:str:delim(str delim / l1 l2)
(setq str (vl-string->list str) delim (vl-string->list delim))
(while str
(if (not (member (car str) delim))
(setq l1 (cons (car str) l1))
(if l1 (setq l2 (cons (vl-list->string (reverse l1)) l2) l1 nil))
)
(setq str (cdr str))
)
(if l1 (setq l2 (cons (vl-list->string (reverse l1)) l2)))
(reverse l2)
)
;;;entmake triangle by qjchen
(defun q:entmake:triangle(p1 p2 p3 layer color width)
(entmakex
(list '(0 . "LWPOLYLINE") '(100 . "AcDbEntity") '(67 . 0)
'(410 . "Model") (cons 62 color) (cons 8 layer)
'(100 . "AcDbPolyline") '(90 . 5) '(70 . 0)
(cons 43 width) '(38 . 0.0) '(39 . 0.0)
(cons 10 p1) '(42 . 0.0) (cons 10 p2) '(42 . 0.0)
(cons 10 p3) '(42 . 0.0) (cons 10 p1) '(42 . 0.0)
'(210 0.0 0.0 1.0)
)
)
)
;;;将点集的坐标写到文件里面，并输入点集表 by qjchen
(defun q:WritePointCorToFile(ss fn / fh n p1xyz plst strxyz)
(setq fh (open fn "w"))
(repeat (setq n (fix (sslength ss))) ; fixed
(setq p1xyz (cdr (assoc 10 (entget (ssname ss (setq n (1- n))))))
plst (cons p1xyz plst))
(write-line (strcat (rtos (car p1xyz) 2 8) " " (rtos (cadr p1xyz) 2 8) " " (rtos (caddr p1xyz) 2 8)) fh)
)
(close fh)
(reverse plst)
)
;;;根据Matlab的Delaunay文件绘制三角网 by qjchen
(defun q:DrawTriangleByMatLabDelaunay(fn plst / b fh line x)
(if (setq fh (open fn "r"))
(progn
(while (setq line (read-line fh))
(setq b (q:str:delim line " \t")
x (mapcar '(lambda(x) (fix (atof x))) b))
(q:entmake:triangle (nth (1- (car x)) plst) (nth (1- (cadr x)) plst) (nth (1- (caddr x)) plst) "0" 1 0)
)
(close fh)
)
)
)
;;;____________end of qjchen subroutine_________________________________;
;;;主程序，选择点，利用Matlab进行delaunay三角形的绘制, by [email]qjchen@gmail.com[/email]
(defun c:test( / fn fn1 plst ss ss_mat_obj str)
(startTimer)
(setq fn "d:\\delaunayxy.txt" fn1 "d:\\delaunaym.txt")
(setq ss (ssget '((0 . "POINT"))))
(setq plst (q:WritePointCorToFile ss fn))
(setq str (strcat "M = load('" fn "'); x=M(:,1); y=M(:,2); TRI=delaunay(x,y); save '" fn1 "' TRI -ascii;"))
(ss-create-matlab-object)
(vlax-invoke-method ss_mat_obj 'MinimizeCommandWindow)
(vlax-invoke-method ss_mat_obj 'Execute str)
(q:DrawTriangleByMatLabDelaunay fn1 plst)
(endTimer)
)
(defun startTimer ()
(setq time (getvar "DATE"))
)
(defun endTimer ()
(setq time (- (getvar "DATE") time)
seconds (* 86400.0 (- time (fix time)))
)
(setq totaltime (rtos seconds 2 6))
(princ (strcat "\nTimed:" (rtos seconds 2 6)))
)
(princ)
(princ "\n 利用Matlab进行Autocad的Delaunay三角网绘制，编程：华南理工大学 qjchen，命令:test")
(princ)

;;;;这是一个利用Matlab程序进行Delaunay三角网绘制的程序，             ; 
;;;;作者：华南理工大学qjchen;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; 
;;;;日期: 2011.12.15                                                 ; 
;;;;感谢：高山流水朋友在Mjtd上给出的Lisp调用Matlab函数进行计算的代码;; 
;;;;      极大地拓宽了<a href="http://bbs.mjtd.com/forum-41-1.html" target="_blank" class="relatedlink">AutoCAD</a>可能的分析计算功能                      ; 
;;;;软件思路：1）找点，输出到文本文件 2）利用Matlab计算，输出结果 ;;;; 
;;;;          3）回调结果绘图                                        ; 
;;;__________________________________________________________________; 
;;; Purpose: draw Delaunay triangle by MatLab program                ; 
;;; write by qjchen                                                  ; 
;;; Great Thanks to GSLS, his program about Lisp Call Matlab function; 
;;;       enable Autocad to use plenty of MatLab tools               ; 
;;;__________________________________________________________________; 
 
;;;_____________________高山流水的函数 ______________________________; 
;;; 调用MATLAB.APP,                                                  ; 
(defun ss-create-matlab-object () 
  (vl-load-com) 
  (if (or (null ss_mat_obj) (= ss_mat_obj :vlax-false)) 
    (setq ss_mat_obj (vlax-get-or-create-object "matlab.application")) 
    ) 
  ) 
;;; 卸载 
(defun ss-release-matlab-object() 
  (if (= ss_mat_obj :vlax-true) 
  (progn 
    (vlax-release-object ss_mat_obj) 
    (setq ss_mat_obj nil) 
    ) 
    ) 
  ) 
;(setq ss_mat_obj (vlax-get-or-create-object (findfile "c:\\matlab701\\toolbox\\modelsim\\win32\\matlablink.dll"))) 
;;;ss-matlab-execute 
;;;功能：调用MATLAB EXECUTE功能 
;;;str1 Malab中的参数执行语句，一般为参数式函数 
;;;str2 Malab中的显示执行语句,语句含义参考Matlab,如上述例题中保存在C盘的test.jpg 
;;;Uility 显示完后是否关闭， 
;;;Written By GSLS(SS) 2010-07-25 4:45;;;高山流水的函数 
(defun ss-matlab-execute(str1 str2 uility /)      
  (vlax-invoke-method ss_mat_obj 'MinimizeCommandWindow) 
  (vlax-invoke-method ss_mat_obj 'Execute str1) 
  (vlax-invoke-method ss_mat_obj 'Execute str2)   
) 
;;;____________end of 高山流水的函数_________________________________; 
 
;;;____________qjchen subroutine_____________________________________; 
;;;String delim by [email]qjchen@gmail.com[/email] 
;;;根据delim将str分解为表 
(defun q:str:delim(str delim / l1 l2) 
  (setq str (vl-string->list str) delim (vl-string->list delim)) 
  (while str 
    (if (not (member (car str) delim)) 
             (setq l1 (cons (car str) l1)) 
             (if l1 (setq l2 (cons (vl-list->string (reverse l1)) l2) l1 nil)) 
    ) 
    (setq str (cdr str)) 
  ) 
  (if l1 (setq l2 (cons (vl-list->string (reverse l1)) l2))) 
  (reverse l2) 
) 
;;;entmake triangle by qjchen 
(defun q:entmake:triangle(p1 p2 p3 layer color width) 
    (entmakex 
      (list '(0 . "LWPOLYLINE") '(100 . "AcDbEntity") '(67 . 0) 
            '(410 . "Model") (cons 62 color) (cons 8 layer) 
            '(100 . "AcDbPolyline") '(90 . 5) '(70 . 0) 
            (cons 43 width) '(38 . 0.0) '(39 . 0.0) 
            (cons 10 p1) '(42 . 0.0) (cons 10 p2) '(42 . 0.0) 
            (cons 10 p3) '(42 . 0.0) (cons 10 p1) '(42 . 0.0) 
            '(210 0.0 0.0 1.0) 
      )                                
    )                                        
) 
;;;将点集的坐标写到文件里面，并输入点集表 by qjchen 
(defun q:WritePointCorToFile(ss fn / fh n p1xyz plst strxyz) 
  (setq fh (open fn "w")) 
  (repeat (setq n (fix (sslength ss))) ; fixed 
    (setq p1xyz (cdr (assoc 10 (entget (ssname ss (setq n (1- n)))))) 
          plst (cons p1xyz plst)) 
    (write-line (strcat (rtos (car p1xyz) 2 8) " " (rtos (cadr p1xyz) 2 8) " " (rtos (caddr p1xyz) 2 8)) fh) 
  ) 
  (close fh) 
  (reverse plst) 
) 
;;;根据Matlab的Delaunay文件绘制三角网 by qjchen 
(defun q:DrawTriangleByMatLabDelaunay(fn plst / b fh line x) 
   (if (setq fh (open fn "r")) 
    (progn 
      (while (setq line (read-line fh)) 
        (setq b (q:str:delim line " \t") 
              x (mapcar '(lambda(x) (fix (atof x))) b)) 
        (q:entmake:triangle (nth (1- (car x)) plst) (nth (1- (cadr x)) plst) (nth (1- (caddr x)) plst) "0" 1 0) 
      ) 
      (close fh) 
    ) 
  ) 
) 
;;;____________end of qjchen subroutine_________________________________; 
 
;;;主程序，选择点，利用Matlab进行delaunay三角形的绘制, by [email]qjchen@gmail.com[/email] 
(defun c:test( / fn fn1 plst ss ss_mat_obj str) 
  (startTimer) 
  (setq fn "d:\\delaunayxy.txt" fn1 "d:\\delaunaym.txt") 
  (setq ss (ssget '((0 . "POINT")))) 
  (setq plst (q:WritePointCorToFile ss fn)) 
  (setq str (strcat "M = load('" fn "'); x=M(:,1); y=M(:,2); TRI=delaunay(x,y); save '" fn1 "' TRI -ascii;")) 
  (ss-create-matlab-object) 
  (vlax-invoke-method ss_mat_obj 'MinimizeCommandWindow) 
  (vlax-invoke-method ss_mat_obj 'Execute str) 
  (q:DrawTriangleByMatLabDelaunay fn1 plst) 
  (endTimer) 
) 
 
(defun startTimer () 
  (setq time (getvar "DATE")) 
) 
(defun endTimer () 
  (setq time (- (getvar "DATE") time) 
        seconds (* 86400.0 (- time (fix time))) 
  ) 
  (setq totaltime (rtos seconds 2 6)) 
  (princ (strcat "\nTimed:" (rtos seconds 2 6))) 
) 
(princ) 
(princ "\n 利用Matlab进行Autocad的Delaunay三角网绘制，编程：华南理工大学 qjchen，命令:test") 
(princ)

chlh_jd · 发表于 2011-12-15 17:33

qj-chen老师对MATLAB很有研究啊！

通过文本操作可能是效率比较低的主要原因，好些可以通过COM接口给VLISP调用，不过在此之前可能得先做个转换动态链接库，我由于对WINDOWS系统知识的匮乏，中断了这些。
喜望能有更多的同仁深化这个方面的接口研究，能做到不安装MATLAB独立建库当然最好了。

yshf · 发表于 2011-12-15 23:05

qj-chen老师

qjchen · 发表于 2011-12-16 08:40

谢谢高山流水兄和yshf

To高山兄，好些可以通过COM接口给VLISP调用，不过在此之前可能得先做个转换动态链接库。在.NET里面是已经调试通过可以将MATLAB的某个函数编译成为DLL，我希望以后能在此方面继续探索一下，争取能做到高山兄的要求。：）

弓志贤 · 发表于 2011-12-17 13:10

qj-chen老师真是厉害

革天明 · 发表于 2011-12-17 14:19

谢谢楼主分享！

zdqwy19 · 发表于 2012-4-3 21:04

lisp和matlab可以这样连接啊，有学了

tm20038175 · 发表于 2012-4-3 21:10

chlh_jd 发表于 2011-12-15 17:33
qj-chen老师对MATLAB很有研究啊！
通过文本操作可能是效率比较低的主要原因，好些可以 ...

我也是这么认为的，不需要安装，用到什么函数库就直接拷贝出来调用，如果能做到这点就好了。

树櫴希德 · 发表于 2014-5-14 08:32

qj-chen老师,三角网做成后怎么样利用它？如等高线、查询任意点、挖方、填方建立坡脚等等？

landsat99 · 发表于 2022-5-20 11:33

本帖最后由 landsat99 于 2022-5-20 11:44 编辑

生成Delaunay三角网，建议CGAL库。通用cpp几何算法库，效率标准化不错

接口：CGAL::refine_Delaunay_mesh 可有不同特性。

GitHub ： https://github.com/CGAL/cgal 大家的维护热度很高。如有兴趣共同维护、优化

账号		自动登录	找回密码
密码			注册

[飞马系列] Lisp利用MatLab 学习1-Delaunay三角网感谢高山流水

本帖子中包含更多资源

评分

[飞马系列] Lisp利用MatLab 学习1-Delaunay三角网 感谢高山流水

本帖子中包含更多资源

评分

[飞马系列] Lisp利用MatLab 学习1-Delaunay三角网感谢高山流水