查看系统中的"命令/函数/变量"

自贡黄明儒

;;1 如果你装了插件而又没有安装ET，其中定义了多个命令，你不知道，那就看看吧；
;;如果你想重新定义一个命令，又不想与原有命令干涉，那就更应该看看了。
;;2 有多少函数呢，你不知道吧，我从来也不知道，那我们一起来看看吧
;;3 你编程时如果不习惯设置局部变量，在这里你可以看到运行后的值是多少了
;;查看系统中的"命令/函数/变量"
;;查看系统中的"命令/函数/变量"------------------------自贡黄明儒 2013.1.22
(defun c:MyLsp (/ A B FILE GETKW LST N TEMP_FILE)
  ;;1 是否是命令
  (defun Is-command (a /)
    (and (equal "C:" (substr (xstrcase a) 1 2))
         (Is-function (eval (read a)))
    )
  )
  ;;2 判断表 Lst 是否是点对表
  (defun consp (lst)
    (not (vl-list-length lst))
  )
  ;;3 是否函数
  (defun Is-function (b /)
    (or        (and (= 'LIST (type b))               
             (not (consp b))               
             (> (length b) 1)
             (or (= 'LIST (type (car b)))
                 (not (car b))
             )
        )
        (= 'SUBR (type b))               
        (= 'USUBR (type b))               
        (= 'EXRXSUBR (type b))               
    )
  )
  ;;4 结果显示
  (defun My-princ (a / c)
    (if        (setq c (type (eval (read a))))
      (setq c (vl-symbol-name c))
      (setq c "nil")
    )
    (setq c (strcat "(" c ")"))
    (if        (= "C:" (substr a 1 2))
      (setq a (substr a 3))
    )
    (while (< (strlen a) 40)
      (setq a (strcat a " "))
    )
    (while (< (strlen c) 20)
      (setq c (strcat c " "))
    )
    (strcat a c)
  )

  ;;5 本程序主程序
  (initget "Commands Functions Variables")
  (setq        getkw (getkword
                "\n 选项[Commands/Functions/Variables]<Variables>: "
              )
  )
  (setq lst (acad_strlsort (atoms-family 1)))
  (setq Temp_File (vl-filename-mktemp nil nil ".txt"))
  (setq file (open Temp_File "w"))
  (cond
    ((= getkw "Commands")
     (repeat (setq n (length lst))
       (setq a (xstrcase (nth (setq n (1- n)) lst)))
       (if (Is-command a)
         (write-line (My-princ a) FILE)
       )
     )
    )
    ((= getkw "Functions")
     (repeat (setq n (length lst))
       (setq a (xstrcase (nth (setq n (1- n)) lst)))
       (if (and        (setq b (eval (read a)))
                (Is-function b)
           )
         (write-line (My-princ a) FILE)
       )
     )
    )
    (T
     (repeat (setq n (length lst))
       (setq a (xstrcase (nth (setq n (1- n)) lst)))
       (setq b (eval (read a)))
       (if (and
             (not (Is-function b))
             (not (Is-command a))
           )
         (write-line (My-princ a) FILE)
       )
     )
    )
  )
  (close FILE)
  (startapp "notepad" Temp_File)
  (princ)
)
;;查看系统中的"命令/函数/变量"------------------------自贡黄明儒 2013.1.22

taoyi0727

这个好 每天折腾  好多变量冲突了

wosiguwozai0830

很实用的程序，感谢黄大师分享

xinhaichun

还有这么好的工具。下下来看看

lz123456

解决了一大问题，3Q

ww5w

看看,

hao3ren

不错，修改为查看单个程序更实用些

yjr111

关注一下下

smartstar

学习学习。

cseryaobaoku

响应楼主，那就看看吧

lht

是什么东东

ddisddis

学习一下，谢谢分享

USER2128

好贴，好想法！支持黄大侠