画矩形剪内线-请指正一下为什么不能矩形内的线-[已解决]

kwok · 发表于 2013-3-22 11:36:07

本帖最后由 kwok 于 2013-3-22 12:27 编辑

画矩形剪内线-请指正一下为什么不能矩形内的线
;;;**********画矩形剪内线
(defun c:rtt ()
(setq os (getvar "osmode"))
(setvar "osmode" 0)
(setq p1 (getpoint "\n指定基点："))
(setq p2 (getcorner p1"\n指定对角点："))
(command "rectang" p1 p2 )
(setq enRec (entlast))
(setq pt1 (polar p2 (angle p1 p2) -1.))
(setq pt2 (polar p1 (angle p1 p2) 1.))
(command ".trim" enRec  "" "c" pt1 pt2 "" )
(setvar "osmode" os)
  (princ)
  )

谢谢!

Gu_xl · 发表于 2013-3-22 11:59:58

;;框内物体删除 By Gu_xl
(defun c:tt (/ OS P1 P2 CP SS ENREC N *error*)
(defun *error* (s)
(setvar "osmode" os)
(princ s)
)
(setq os (getvar "osmode"))
(setvar "osmode" 0)
(setq p1 (getpoint "\n指定基点："))
(setq p2 (getcorner p1 "\n指定对角点："))
(setq cp (mapcar '* '(0.5 0.5 0.5) (mapcar '+ p1 p2)))
(setq ss (ssget "w" p1 p2))
(if ss (command "erase" ss ""))
(command "rectang" p1 p2)
(setq enRec (entlast))
;;重复5次，以保证剪切干净
(repeat 5
(setq ss (ssget "c" p1 p2))
(ssdel enRec ss)
(command ".trim" enRec "")
(repeat (setq n (sslength ss))
(command (list (ssname ss (setq n (1- n))) cp))
)
(command "")
)
;;删除绘制的方框
(entdel enRec)
(setvar "osmode" os)
(princ)
)

kwok · 发表于 2013-3-22 12:22:55

Gu_xl 发表于 2013-3-22 11:59

谢谢G版，原来要这么复杂，我以为直接用trim的c窗交就可以达到呢．

香田里浪人 · 发表于 2013-3-25 23:15:49

曾见过此类工具。

kwok · 发表于 2013-5-3 10:56:26

Gu_xl 发表于 2013-3-22 11:59

G版，不知为什么，此lsp在2008下是正常的，在2013 /14却是不行，如果有锁定的线，就出错，不能工作，但框选的范围里没有锁定的线却是正常的，在2008不存在这情况.
不知怎么弄可以过滤锁定的线？我试过简单加上：L不行.

注册 · 发表于 2013-5-12 20:29:14

这个好，谢谢，用的着

sicky111 · 发表于 2013-5-12 22:55:47

非常好用。

wayne_myles · 发表于 2015-6-7 15:34:38

Gu_xl 发表于 2013-3-22 11:59

很好可以帮忙写个过滤吗? 就是方框内出文字圆圈圆弧其余全部删除麻烦你一下

账号		自动登录	找回密码
密码			注册

[基础] 画矩形剪内线-请指正一下为什么不能矩形内的线-[已解决]

相关帖子

评分