请问有没有快速备份图纸的的程序呢？

theisland · 发表于 2013-5-19 14:45:23

画图的时候害怕修改，总会保存很多个版本，可不可以正画着某张图（假如该图名称为“总平面图”，所在的文件路径为：D/01项目/方案）的时候，输入一个快捷键，然后当前图纸就被复制一份到：D/01项目/方案/图纸备份，图纸名称变为“总平面图+年月日+时分”，同时将《图纸备份》文件夹打开（检查是否备份成功）

运行软件的时候，软件先判断图纸所在文件夹是不是存在《图纸备份》文件夹，如果有，按上述步骤运行；如果没有，则创建《图纸备份》文件夹，然后运行软件，请高手帮帮我，谢谢！

bing00 · 发表于 2020-7-5 17:29:51

澶囦唤鐩綍这是备份文件名，怎么是乱码

刘炎华 · 发表于 2020-7-16 15:34:39

本帖最后由刘炎华于 2020-7-16 15:41 编辑

@16楼的大师所写
要备份到指定目录下呢？例如：D:\bakfile

听见天晴 · 发表于 2024-7-7 21:59:55

这么多年前就有这么好的程序了。。。之前还不会用CAD呢

自贡黄明儒 · 发表于 2013-5-19 14:50:02

(setvar "ISAVEBAK" 1)应该可以创建一个备份文件的吧?

theisland · 发表于 2013-5-19 14:53:53

自贡黄明儒发表于 2013-5-19 14:50
(setvar "ISAVEBAK" 1)应该可以创建一个备份文件的吧?

你好！请问怎么使用呢？

theisland · 发表于 2013-5-19 15:32:02

自贡黄明儒发表于 2013-5-19 14:50
(setvar "ISAVEBAK" 1)应该可以创建一个备份文件的吧?

不是那个意思，我是想在当前图形中运行软件，然后软件把当前图形加上时间后缀名称后复制到指定文件夹中进行备份（PS：我的CAD系统设置是不要bak文件的）

tianyi1230 · 发表于 2013-5-19 16:06:12

貌似它山之石有个备份插件，还有七月信的一个云功能上传备份图纸的插件，论坛里面可以搜索到的

Gu_xl · 发表于 2013-5-19 16:22:32

本帖最后由 Gu_xl 于 2013-5-20 14:19 编辑

;;文件备份 By Gu_xl 2013.05.19
(defun c:tt1 (/ PATH NAME TIME) (vl-load-com)
(setq path (getvar 'dwgprefix)
name (getvar 'dwgname)
time (rtos (getvar 'cdate) 2 4)
time (vl-string-subst "-" "." time)
)
(if (not (findfile (strcat path "备份目录")))
(progn
(gxl-file-CreateFolder (strcat path "备份目录") 0)
)
)
(command "save" (strcat path "备份目录\\" (VL-FILENAME-BASE name) "-" time ".dwg"))
(Explore (strcat path "备份目录\\" )
)
)
(defun gxl-file-CreateFolder (FNAME att / SYS FOLDER)
(if (not (findfile FNAME))
(progn
(setq SYS (vlax-create-object "Scripting.FileSystemObject"))
(setq FOLDER (VL-CATCH-ALL-APPLY
'vlax-invoke-method
(list SYS 'CREATEFOLDER FNAME)
)
)
(if (not (VL-CATCH-ALL-ERROR-P FOLDER))
(progn
(vlax-put FOLDER
"Attributes"
att
)
(vlax-release-object FOLDER)
)
)
(vlax-release-object SYS)
)
)
)
;;;(Explore 路径) 浏览文件夹
;;;(Explore "c:\\") (Explore 5)
(defun Explore ( target / Shell result ) (vl-load-com)
;; ?Lee Mac 2010
(setq Shell (vla-getInterfaceObject (vlax-get-acad-object) "Shell.Application"))
(setq result
(and (or (eq 'INT (type target)) (vl-file-directory-p target))
(not
(vl-catch-all-error-p
(vl-catch-all-apply 'vlax-invoke (list Shell 'Explore target))
)
)
)
)
(vlax-release-object Shell)
result
)

;;文件备份 By Gu_xl 2013.05.19 
(defun c:tt1 (/ PATH NAME TIME) (vl-load-com) 
  (setq        path (getvar 'dwgprefix) 
        name (getvar 'dwgname) 
        time (rtos (getvar 'cdate) 2 4) 
        time (vl-string-subst "-" "." time) 
  ) 
  (if (not (findfile (strcat path "备份目录"))) 
    (progn 
      (gxl-file-CreateFolder (strcat path "备份目录") 0) 
      ) 
    ) 
  (command "save" (strcat path "备份目录\\" (VL-FILENAME-BASE name) "-" time ".dwg")) 
  (Explore  (strcat path "备份目录\\" ) 
  ) 
) 
(defun gxl-file-CreateFolder (FNAME att / SYS FOLDER) 
  (if (not (findfile FNAME)) 
    (progn 
      (setq SYS (vlax-create-object "Scripting.FileSystemObject")) 
      (setq FOLDER (VL-CATCH-ALL-APPLY 
                     'vlax-invoke-method 
                     (list SYS 'CREATEFOLDER FNAME) 
                   ) 
      ) 
      (if (not (VL-CATCH-ALL-ERROR-P FOLDER)) 
        (progn 
          (vlax-put FOLDER 
                    "Attributes" 
                    att 
          ) 
          (vlax-release-object FOLDER) 
        ) 
      ) 
      (vlax-release-object SYS) 
    ) 
  ) 
) 
;;;(Explore 路径) 浏览文件夹 
;;;(Explore "c:\\") (Explore 5) 
(defun Explore ( target / Shell result ) (vl-load-com) 
  ;; ?Lee Mac 2010 
  (setq Shell  (vla-getInterfaceObject (vlax-get-acad-object) "Shell.Application")) 
  (setq result 
    (and (or (eq 'INT (type target)) (vl-file-directory-p target)) 
      (not 
        (vl-catch-all-error-p 
          (vl-catch-all-apply 'vlax-invoke (list Shell 'Explore target)) 
        ) 
      ) 
    ) 
  ) 
  (vlax-release-object Shell) 
  result 
)

461045462 · 发表于 2013-5-19 16:31:29

谢谢斑竹的分享！
收藏下来学习学习。
谢谢

theisland · 发表于 2013-5-19 17:03:04

Gu_xl 发表于 2013-5-19 16:22
**** 本内容被作者隐藏 ****

非常感谢！可是为什么是这个提示呢？错误: no function definition: GXL-STRPARSEBYLST

Gu_xl · 发表于 2013-5-19 18:40:49

theisland 发表于 2013-5-19 17:03
非常感谢！可是为什么是这个提示呢？错误: no function definition: GXL-STRPARSEBYLST

已修改！

theisland · 发表于 2013-5-19 18:52:45

Gu_xl 您好！谢谢你帮我解决了个大麻烦！文件备份已经ok了，但是文件夹没有随后打开？

账号		自动登录	找回密码
密码			注册

[已解答] 请问有没有快速备份图纸的的程序呢？

点评