整整一个下午也没弄出个结果来，在线等高手

yaokui25 · 发表于 2013-5-31 17:23

判断选择的线段长度当等于一个数值的时候，就被选中
例如：当判断值为10mm的时候，选择的线段中有10mm长度的线段时就被选中。

下面的代码废了好长一段时间才弄出来的
可是只适用于x轴或者y轴上的线段
当线段有角度的时候该如何修正呢，小弟弄了整整一个下午也没弄出来
在线等高手相助拜托

(defun c:st_sen ( )
(setvar "cmdecho" 0)
(cond
((not (setq ss (ssget '((0 . "LINE"))))))
(T
   (setq i 0
      ss1 (ssadd)
   )
   (while (setq ee (ssname ss i))
   (setq dat (entget ee)
            pa (cdr (assoc 10 dat))
            pb (cdr (assoc 11 dat))
            i (1+ i)
   )
   (if (= (distance pa pb) 10) ;;判断线段长度：10mm的时候，亮显
   (ssadd ee ss1)
   )
   )
(princ (strcat "\n 〓共选择了【" (itoa (sslength ss1)) "】条直线〓 "))
(sssetfirst nil ss1) ;;判断线段长度：10mm的时候，亮显
)
)
(princ)
)
)

springwillow · 发表于 2013-5-31 17:46

(if (= (distance pa pb) 10)改为(if (equal (distance pa pb) 10.0 0.1)试试

自贡黄明儒 · 发表于 2013-5-31 17:52

(defun c:w1 (/ DAT EE N PA PB SS SS1)
(IF (setq ss (ssget '((0 . "LINE"))))
(Progn
(setq ss1 (ssadd))
(repeat (setq n (SSLENGTH ss))
(setq ee (ssname ss (setq n (1- n))))
(setq dat (entget ee)
pa (cdr (assoc 10 dat))
pb (cdr (assoc 11 dat))
)
(if (= (distance pa pb) 10)
;;判断线段长度：10mm的时候，亮显
(ssadd ee ss1)
)
)
(sssetfirst nil ss1)
)
)
(princ)
)

yaokui25 · 发表于 2013-5-31 19:20

本帖最后由 yaokui25 于 2013-5-31 19:22 编辑

springwillow 发表于 2013-5-31 17:46
(if (= (distance pa pb) 10)改为(if (equal (distance pa pb) 10.0 0.1)试试

您好，谢谢您的回复
现在的代码只能选中 x轴或者y轴上的线段
带角度的线段也想选中
刚才试了一下，没有效果

yaokui25 · 发表于 2013-5-31 19:25

自贡黄明儒发表于 2013-5-31 17:52

您好，谢谢您的回复
现在的代码只能选中 x轴或者y轴上的线段
带角度的线段也想被选中，只要长度满足要求
刚才试了一下，没能达到我想要的效果。
您能在帮我看看嘛？
可能我的问题没说明白

springwillow · 发表于 2013-5-31 19:40

(defun c:st_sen ()
(setvar "cmdecho" 0)
(cond
((not (setq ss (ssget '((0 . "LINE"))))))
(T
(setq i 0
ss1 (ssadd)
)
(while (setq ee (ssname ss i))
(setq dat (entget ee)
pa (cdr (assoc 10 dat))
pb (cdr (assoc 11 dat))
i (1+ i)
)
(if (equal (distance pa pb) 10.0 0.1)
;;判断线段长度：10mm的时候，亮显
(ssadd ee ss1)
)
)
(princ (strcat "\n 〓共选择了【"
(itoa (sslength ss1))
"】条直线〓 "
)
)
(sssetfirst nil ss1)
;;判断线段长度：10mm的时候，亮显
)
)
(princ)
)

yaokui25 · 发表于 2013-5-31 20:05

springwillow 发表于 2013-5-31 19:40

再次谢谢您的回答，确实解决的我的问题，困扰了我一下午。

再次请求：如何修改为 ≧大于等于一个数值且 ≦小于等于一个数值时候，选中满足条件的线段

例如 :10≦线段长 ≦50 的所有线段

springwillow · 发表于 2013-5-31 20:16

yaokui25 发表于 2013-5-31 20:05
再次谢谢您的回答，确实解决的我的问题，困扰了我一下午。

再次请求：如何修改为 ≧大于等 ...

(defun c:st_sen (/ ss i ee dat pa pb ss1)
(setvar "cmdecho" 0)
(cond
((not (setq ss (ssget '((0 . "LINE"))))))
(T
(setq i 0
ss1 (ssadd)
)
(while (setq ee (ssname ss i))
(setq dat (entget ee)
pa (cdr (assoc 10 dat))
pb (cdr (assoc 11 dat))
i (1+ i)
)
(if (and (>= (distance pa pb) 9.9) (<= (distance pa pb) 50.1))
;;判断线段长度：10mm的时候，亮显
(ssadd ee ss1)
)
)
(princ (strcat "\n 〓共选择了【"
(itoa (sslength ss1))
"】条直线〓 "
)
)
(sssetfirst nil ss1)
;;判断线段长度：10mm的时候，亮显
)
)
(princ)
)

清风明月名字 · 发表于 2013-5-31 20:41

谢谢楼主的分享！收藏备用。

yaokui25 · 发表于 2013-6-1 00:12

springwillow 发表于 2013-5-31 20:16

谢谢您的指教
也就是说在选择上做了一个模糊处理是吧

账号		自动登录	找回密码
密码			注册

[提问] 整整一个下午也没弄出个结果来，在线等高手

评分

相关帖子

评分

本帖子中包含更多资源

评分