[源码]批量绘制圆的中心线

荒野孤行

;;; *****绘制圆的中心线 程序开始*****
(defun c:wdy_zxx ()
  (setvar "osmode" 15359)
  (setvar "cmdecho" 0)
  (command "undo" "be")
  (princ "\n★功能:批量绘制圆的中心线.\n")
  (setq ss (ssget '((-4 . "<OR") (0 . "CIRCLE") (-4 . "OR>"))))
  (if (not ss)
    (exit)
  )
  (initget "A C")
  (if (not
        (setq kw (getkword "\n中心线线长是：[固定的(A)/可变的(C)]<C>"))
      )
    (setq kw "C")
  )
  (command "LAYER" "M" "中心线"        "LT" "CENTER" "中心线" "C" "RED"
           "中心线" "")
  (command "CLAYER" "中心线")
  (setvar "osmode" 0)
  (if (= kw "A")
    (progn
      (initget 3)
      (setq dist1 (getdist "\n中心线长度:"))
      (setq i 0)
      (repeat (sslength ss)
        (setq ent (ssname ss i))
        (setq pt (cdr (assoc 10 (entget ent))))
        (setq ptup    (polar pt (angtof "90") (/ dist1 2))
              ptdown  (polar pt (angtof "270") (/ dist1 2))
              ptleft  (polar pt (angtof "180") (/ dist1 2))
              ptright (polar pt 0 (/ dist1 2))
        )
        (command "line" ptdown ptup "")
        (command "line" ptleft ptright "")
        (setq i (1+ i))
      )
    )
    (progn
      (if (not
            (setq dist2 (getreal "\n中心线半长与圆半径的差值<0.1>:"))
          )
        (setq dist2 0.1)
      )
      (setq i 0)
      (repeat (sslength ss)
        (setq ent (ssname ss i))
        (setq pt (cdr (assoc 10 (entget ent))))
        (setq bj (cdr (assoc 40 (entget ent))))
        (setq ptup    (polar pt (angtof "90") (+ bj dist2))
              ptdown  (polar pt (angtof "270") (+ bj dist2))
              ptleft  (polar pt (angtof "180") (+ bj dist2))
              ptright (polar pt 0 (+ bj dist2))
        )
        (command "line" ptdown ptup "")
        (command "line" ptleft ptright "")
        (setq i (1+ i))
      )
    )
  )
  (princ "\n★圆的中心线已绘制完成.\n")
  (command "undo" "e")
  (setvar "osmode" 15359)
  (princ)
)
;;; *****绘制圆的中心线 程序结束*****

清风明月名字

谢谢楼主的分享！很有意思的代码，收藏备用。

roro

学习中

下文没句号。

谢谢楼主的分享！收藏备用。