，尺寸线性标注800远各位版主大人~~~速度来赚钱了

cgmacby · 发表于 2013-10-23 12:32

本帖最后由 cgmacby 于 2013-10-23 12:36 编辑

xyp1964 · 发表于 2013-10-26 16:23

(defun c:tt ()
(if (and (setq p1 (getpoint "\n第一点: "))
(setq p2 (getpoint p1 "\n第二点: "))
(setq p3 (getpoint p2 "\n方向点: "))
)
(progn
(setq ang (angle p1 p2)
r1 (+ ang (* pi 0.5))
p4 (inters p1 p2 p3 (polar p3 r1 10) nil)
p3 (polar p4 (angle p4 p3) 800)
)
(command "_dimaligned" "non" p1 "non" p2 "non" p3)
)
)
(princ)
)

xyp1964 · 发表于 2014-3-14 14:17

小灰345 发表于 2014-3-14 12:45
太强大了，学习了！
请问院长能否改成800远可以自己输入指定，指定一次后按照这个值来标注，直到下一次修 ...

(defun c:tt (/ p1 p2 p3 rad r1 p3 p4)
(setq dist (Udist 5 "" "离开距离<输入或鼠标直接量取>" dist nil))
(if (and (setq p1 (getpoint "\n第一点: "))
(setq p2 (getpoint p1 "\n第二点: "))
(setq p3 (getpoint p2 "\n方向点: "))
)
(progn (setq rad (angle p1 p2)
r1 (+ rad (* pi 0.5))
p4 (inters p1 p2 p3 (polar p3 r1 10) nil)
p3 (polar p4 (angle p4 p3) dist)
)
(command "_dimaligned" "non" p1 "non" p2 "non" p3)
(while (setq p4 (getpoint "\n下一点<退出>: "))
(setq p4 (inters p1 p2 p4 (Polar p4 r1 100) nil))
(command "_dim" "con" "non" p4 "")
)
(command "_dim" "e")
)
)
(princ)
)

1028695446 · 发表于 2019-10-30 10:29

(defun c:tt(/ p1 p2 p4 temp ent elist pt10_old pt10_new *dim_dist)
  (if (and (setq p1 (getpoint "\n第一点: "))
(setq p2 (getpoint p1 "\n第二点: "))
   )
(progn
   (setq rad (angle p1 p2)
r1(+ rad (* pi 0.5))
   )
(if (null *dim_dist)
(setq *dim_dist (* 5 (getvar "DIMSCALE")));;设定偏移默认值
(progn
(princ"\n尺寸线偏移距离：")
(princ *dim_dist)
)
)
(if(setq temp (getdist(strcat "\n请输入尺寸线偏移距离：<"(rtos *dim_dist) ">")))
(setq *dim_dist temp)
)
(command "_dimaligned" "non" p1 "non" p2 pause)
(setq ent (entlast)
elist(entget ent)
pt10_old (cdr(assoc 10 elist))
p4 (inters p1 p2 pt10_old (polar pt10_old r1 10) nil)
pt10_new (polar p4 (angle p4 pt10_old) *dim_dist);;;;距离
elist (subst (cons 10 pt10_new) (assoc 10 elist) elist)
)
(entmod elist)
(while (setq p4 (getpoint "\n下一点<退出>: "))
(setq p4 (inters p1 p2 p4 (Polar p4 r1 1000) nil))
(command "DIMCONTINUE" "non" p4)
(while (> (getvar "CMDACTIVE") 0) (command ""))
)
)
)
(princ)
)

liunian0524 · 发表于 2022-5-14 18:04

本帖最后由 liunian0524 于 2022-5-16 08:38 编辑

xj6019 发表于 2019-11-26 10:46
谁能把17楼的和27楼的结合一下啊，命令运行后就先输入偏移值，并可以记忆便宜量，然后可以连续点击标注， ...

(defun c:tt3 (/ p1 p2 p3 rad r1 p3 p4)
(setvar "cmdecho" 0)
(if (null *dim_dist)(setq *dim_dist (* 200 (getvar "dimscale"))));;设定偏移默认值
(if(setq temp (getreal(strcat "\n指定尺寸线偏移距离：<"(rtos *dim_dist) ">")))(setq *dim_dist temp))
(if (and (setq p1 (getpoint "\n指定第一条尺寸界线原点:"))
         (setq p2 (getpoint p1 "\n指定第二条尺寸界线原点:"))
         (setq p3 (getpoint p2 "\n方向点: "))
   )
(progn
      (setq rad (angle p1 p2)
               r1  (+ rad (* pi 0.5))
               p4  (inters p1 p2 p3 (polar p3 r1 10) nil)
               p3  (polar p4 (angle p4 p3) *dim_dist)
         )
         (command "_dimaligned" "non" p1 "non" p2 "non" p3)
         (while (setq p4 (getpoint "\n指定第二条尺寸界线原点:<退出>: "))
         (setq p4 (inters p1 p2 p4 (polar p4 r1 100) nil))
         (command "dimcontinue" "non" p4 "")
         (while (> (getvar "cmdactive") 0) (command ""))
         )
)
  )
  (princ)
)

胖大海 · 发表于 2018-11-29 23:10

(defun c:tt ()
(setq old_lay (getvar "clayer")) ;将当前图层保存起来，以便以后的恢复
  (if (and (setq p1 (getpoint "\n第一点: "))
         (setq p2 (getpoint p1 "\n第二点: "))
         (setq p3 (getpoint p2 "\n方向点: "))
   )
(progn
   (setq ang       (angle p1 p2)
         r1       (+ ang (* pi 0.5))
         p4       (inters p1 p2 p3 (polar p3 r1 10) nil)
         p3       (polar p4 (angle p4 p3) 800);尺寸标注长度
   )
(command "layer" "s" "DIM" "")  ;设置当前层DIM，可改成自己标注图层
   (command "_dimaligned" "non" p1 "non" p2 "non" p3) ;调用当前标注样式进行线性标注，切换当前标注样式 DIMSTYLE
)
  )
(setvar "clayer"  old_lay ) ;恢复原来图层
  (princ)
)[/code]

hao3ren · 发表于 2013-10-23 13:56

(DEFUN C:tt ()
(SETQ PT1 (GETPOINT "\n第一点 :"))
(SETQ PT2 (GETPOINT PT1 "\n第二点 :"))
(SETQ ANG (angle pt1 pt2))
(SETQ pt3 (polar pt2 (+ ang (* pi 0.5)) 800))
(COMMAND "_dimaligned" PT1 PT2 pt3)
)
简单写了个套套，因为我只会这么多，哈哈哈。。。。。。。

cgmacby · 发表于 2013-10-23 14:17

本帖最后由 cgmacby 于 2013-10-23 14:29 编辑

hao3ren 发表于 2013-10-23 13:56
(DEFUN C:tt ()
(SETQ PT1 (GETPOINT "\n第一点 :"))
(SETQ PT2 (GETPOINT PT1 "\n第二点 :"))

谢谢，这个简单的就足够了，哈哈~~@hao3ren，还是有点儿小bug，标注轴网内部的时候出现了这个问题，直接压线了
谢谢hao3ren兄了~~

andyhua · 发表于 2013-10-23 14:36

楼主的程序不错，就是在判断方向上，不是太好。要是可以选择判断方向的话，会更方便。目前程序得让设计人去判断，不太好？多谢，希望高手们可以改改。

sicky111 · 发表于 2013-10-23 21:49

被楼主标题误导了，还以为800明经币求一个线性标注的程式呢。

寒林清远 · 发表于 2013-10-24 08:57

本帖最后由寒林清远于 2013-10-24 09:02 编辑

;用2楼的程序改一下就可以了
;t1在第1、4象限标注，t2在第2、3象限标注
(DEFUN C:t1 ()
(SETQ PT1 (GETPOINT "\n第一点 :"))
(SETQ PT2 (GETPOINT PT1 "\n第二点 :"))
(SETQ ANG (angle pt1 pt2))
(setq old_os (getvar "osmode"))
(setvar "osmode" 0)
(SETQ pt3 (polar pt2 (+ ang (* pi 0.5)) 800))
(COMMAND "_dimaligned" PT1 PT2 pt3)
(setvar "osmode" old_os)
(princ)
)

(DEFUN C:t2 ()
(SETQ PT1 (GETPOINT "\n第一点 :"))
(SETQ PT2 (GETPOINT PT1 "\n第二点 :"))
(SETQ ANG (angle pt1 pt2))
(setq old_os (getvar "osmode"))
(setvar "osmode" 0)
(SETQ pt3 (polar pt2 (- ang (* pi 0.5)) 800))
(COMMAND "_dimaligned" PT1 PT2 pt3)
(setvar "osmode" old_os)
(princ)
)

hao3ren · 发表于 2013-10-24 10:19

把捕捉关掉试试

429014673 · 发表于 2013-10-26 15:20

兑现没有呀

andyhua · 发表于 2013-10-27 09:40

院长出手非同凡响啊！多谢！

账号		自动登录	找回密码
密码			注册

[已解答] ，尺寸线性标注800远各位版主大人~~~速度来赚钱了

本帖子中包含更多资源

点评

评分

评分

本帖子中包含更多资源

点评

点评

[已解答] ，尺寸线性标注800远 各位版主大人~~~速度来赚钱了

本帖子中包含更多资源

点评

评分

评分

本帖子中包含更多资源

点评

点评

[已解答] ，尺寸线性标注800远各位版主大人~~~速度来赚钱了