明经CAD社区

 找回密码
 注册

扫一扫,访问微社区

QQ登录

只需一步,快速开始

查看: 1008|回复: 3

[讨论] 这样的程序如何简化?

[复制链接]
发表于 2013-11-29 11:27 | 显示全部楼层 |阅读模式
[code="lisp] (defun c:ddd ()
  (setq n -1)
  (if (setq ss (ssget '((0 . "LEADER"))))
    (while (setq entname (ssname ss (setq n (+ 1 n))))
      (setq ViewportOnCode ;获得箭头样式
       (Vlax-Get (Vlax-Ename->Vla-Object entname)
           'ArrowheadType
       )
      )
      (if (= 0 ViewportOnCode)   
  (progn
    (Vlax-Put-Property
      (Vlax-Ename->Vla-Object entname)
      'ArrowheadType
      3        ;箭头样式
    )

    (Vlax-Put-Property
      (Vlax-Ename->Vla-Object entname)
      'ArrowheadSize
      1        ;箭头的大小
    )

    (Vlax-Put-Property
      (Vlax-Ename->Vla-Object entname)
      'ScaleFactor
      (* 1.5 (getvar "dimscale"))  ;箭头全局比例
    )
  )
  (progn
    (Vlax-Put-Property
      (Vlax-Ename->Vla-Object entname)
      'ArrowheadType
      0        ;箭头样式
    )
    (Vlax-Put-Property
      (Vlax-Ename->Vla-Object entname)
      'ArrowheadSize
      1        ;箭头的大小
    )

    (Vlax-Put-Property
      (Vlax-Ename->Vla-Object entname)
      'ScaleFactor
      (* 4 (getvar "dimscale"))  ;箭头全局比例
    )
  )
      )
    )
  )
  (princ)
)

[/code]以上 代码如何简化,谢谢!
发表于 2013-11-29 15:33 | 显示全部楼层
  1. (defun c:ddd (/ n ss entname ViewportOnCode obj)
  2.   (setq n -1)
  3.   (if (setq ss (ssget '((0 . "LEADER"))))
  4.     (while (setq entname (ssname ss (setq n (+ 1 n))))
  5.       (setq ViewportOnCode                ;获得箭头样式
  6.              (Vlax-Get (setq obj (Vlax-Ename->Vla-Object entname))
  7.                        'ArrowheadType
  8.              )
  9.       )
  10.       (if (= 0 ViewportOnCode)
  11.         (progn
  12.           (mapcar 'Vlax-Put-Property
  13.                   (list obj obj obj)
  14.                   (list 'ArrowheadType 'ArrowheadSize 'ScaleFactor)
  15.                   (list 3 1 (* 1.5 (getvar "dimscale")))
  16.           )
  17.         )
  18.         (progn
  19.           (mapcar 'Vlax-Put-Property
  20.                   (list obj obj obj)
  21.                   (list 'ArrowheadType 'ArrowheadSize 'ScaleFactor)
  22.                   (list 0 1 (* 4 (getvar "dimscale")))
  23.           )
  24.         )
  25.       )
  26.     )
  27.   )
  28.   (princ)
  29. )
 楼主| 发表于 2013-11-29 17:11 | 显示全部楼层
snddd2000 发表于 2013-11-29 15:33

谢谢前辈。不过觉得好象还是有点啰嗦,但又不知道怎么优化!
发表于 2013-11-29 17:25 | 显示全部楼层
  1. (defun c:ddd (/ n ss entname ViewportOnCode obj Tornil)
  2.   (setq n -1)
  3.   (if (setq ss (ssget '((0 . "LEADER"))))
  4.     (while (setq entname (ssname ss (setq n (+ 1 n))))
  5.       (setq obj                   (Vlax-Ename->Vla-Object entname)
  6.             ViewportOnCode (Vla-Get-ArrowheadType
  7.                              (setq obj (Vlax-Ename->Vla-Object entname))
  8.                            )
  9.             Tornil           (equal 0 ViewportOnCode)
  10.       )
  11.       (mapcar 'Vlax-Put-Property
  12.               (list obj obj obj)
  13.               (list 'ArrowheadType 'ArrowheadSize 'ScaleFactor)
  14.               (list (if        Tornil
  15.                       3
  16.                       0
  17.                     )
  18.                     1
  19.                     (* (if Tornil
  20.                          1.5
  21.                          4
  22.                        )
  23.                        (getvar "dimscale")
  24.                     )
  25.               )
  26.       )
  27.     )
  28.   )
  29.   (princ)
  30. )
您需要登录后才可以回帖 登录 | 注册

本版积分规则

小黑屋|手机版|CAD论坛|CAD教程|CAD下载|联系我们|关于明经|明经通道 ( 粤ICP备05003914号  
©2000-2017 明经通道 版权所有 本站代码,在未取得本站及作者授权的情况下,不得用于商业用途

GMT+8, 2019-11-21 01:54 , Processed in 0.223106 second(s), 33 queries , Gzip On.

Powered by Discuz! X3.3

© 2001-2013 Comsenz Inc.

快速回复 返回顶部 返回列表