命令反应器，调用函数时为何崩溃退出？

ou_y_x

请教一下各位，
未知命令反应器，调用回调函数时，输入33S，单击直线，
运行到entmake时，CAD出现如图问题崩溃退出：

(setq unknowncommand_reactor nil)
(if (not unknowncommand_reactor)(setq unknowncommand_reactor
        (vlr-command-reactor nil '((:vlr-unknownCommand . wzmlfyq)))
))

(defun wzmlfyq(a str / zimu shuzi changdu genshu zhijing pdml)
  (setq zimu "ASDFGQWERT" shuzi "123456789")
  (setq str(car str))
  (setq changdu(strlen str))
  (setq genshu(substr str 1 1) zhijing(substr str changdu 1))
  (setq pdml(and (vl-string-search genshu shuzi) (vl-string-search zhijing zimu)))
  (if pdml (progn
             (setq str(wenzith str changdu))
             (sclpeijin str)
    )))

(defun wenzith(zfc a / yzf xzf)
  (setq yzf(substr zfc a 1))
  (cond ((= yzf "A") (setq xzf "%%13212"))
        ((= yzf "S") (setq xzf "%%13214"))
        ((= yzf "D") (setq xzf "%%13216"))
        ((= yzf "F") (setq xzf "%%13218"))
        ((= yzf "G") (setq xzf "%%13220"))
        ((= yzf "Q") (setq xzf "%%13222"))
        ((= yzf "W") (setq xzf "%%13225"))
        ((= yzf "E") (setq xzf "%%13228"))
        ((= yzf "R") (setq xzf "%%13230"))
        ((= yzf "T") (setq xzf "%%13232"))
        )
  (setq zfc (vl-string-subst xzf yzf zfc (- a 1)))
  zfc)

(defun sclpeijin (peijin / cm zg p1 n1 s1 d1 d2 ang)
  (setq cm (getvar "cmdecho"))
  (setvar "cmdecho" 0 )
  (setq zg(* 0.25 (getvar 'ltscale)))
  (setq n1 (entsel "\n请单击直线"))
  (setq s1 (entget (car n1)))   
  (if (= (cdr (assoc 0 s1)) "LINE")
    (progn
  (setq p1 (osnap (cadr n1) "nea"))
  (setq d1 (cdr (assoc 10 s1)))
  (setq d2 (cdr (assoc 11 s1)))
  (setq ang (angle d1 d2))
         (entmake (list
               (cons 0 "TEXT")
               (cons 1 peijin)
               (cons 10 p1)
               (cons 40 zg)
               (cons 50 ang)
               (cons 41 0.7)
               ))))
  (setvar "cmdecho" cm)
  (princ))

菜卷鱼

我的是正版CAD，也是这样

ou_y_x

菜卷鱼 发表于 2014-2-20 12:00
我的是正版CAD，也是这样

谢谢回复。
我写完第一次运行时成功了，后来每次都是图片上的错误。
逐句运行的时候，到了entmake后的（list ……）那里发生错误。
实在是费解。

菡萏

ou_y_x 发表于 2014-2-20 14:21
谢谢回复。
我写完第一次运行时成功了，后来每次都是图片上的错误。
逐句运行的时候，到了entmake后的（ ...

把entmake换成vla函数：
(setq
        text (vla-addtext
               (vla-get-ModelSpace
                 (vla-get-ActiveDocument (vlax-get-acad-object)))
               peijin
               (vlax-3d-point p1)
               zg))
      (vla-put-Rotation text ang)
      (vla-put-ScaleFactor text 0.7)

edata

楼上正解。

ou_y_x

菡萏 发表于 2014-2-20 16:38
把entmake换成vla函数：
(setq
        text (vla-addtext

谢谢。问题已解决。
但发帖也是希望各位帮忙找出entmake执行不了的原因。