明经CAD社区

 找回密码
 注册

QQ登录

只需一步,快速开始

搜索
查看: 4194|回复: 4

[源码] 对齐标注转转角标注entmake方式

  [复制链接]
发表于 2014-5-24 13:47 | 显示全部楼层 |阅读模式
因为entmod不成功所以改为entmake方式
注:TT2是创建转角标注对齐方式(=旋转的转角标注),记得开关正交。
  1. ;;对齐标注转转角标注entmake法Sub function()
  2. ;;code by edata @ mjtd
  3. ;;2014-5-24
  4. (defun sk_align->rote(en / e1 e13 e14 e2 e2list en code)
  5.   (defun sk_dxf(en code)(cdr(assoc code(entget en))))
  6.   (if(= (sk_dxf en 0) "DIMENSION")
  7.     (progn
  8.       (setq e1(entget en)
  9.       e2(entget en '("*"))
  10.       e2list(assoc -3 e2)
  11.       e1(subst(cons 70 32)(assoc 70 e1)e1)
  12.       e13(cdr(assoc 13 e1))
  13.       e14(cdr(assoc 14 e1))
  14.       e1(subst(cons 50 (angle e13 e14))(assoc 50 e1)e1)
  15.       e1(reverse(cons '(100 . "AcDbRotatedDimension")(reverse e1))))
  16.       (entdel en)
  17.       (if e2list(setq e1(cons e2list e1)))
  18.       (entmake  e1)
  19.       )
  20.     )
  21.   )
  22. ;;对齐标注转转角标注main()
  23. ;;code by edata @ mjtd
  24. ;;2014-5-24
  25. (defun c:tt(/ ss en)
  26.   (prompt "\n请选择需要转换为转角标注的对齐标注:")
  27.   (if(setq ss(ssget '((0 . "DIMENSION")(-4 . "<OR")(70 . 1)(70 . 33)(-4 . "OR>"))))
  28.     (while (setq en(ssname ss 0))
  29.       (sk_align->rote en)
  30.       (setq ss(ssdel en ss))
  31.       )
  32.     )
  33.   (princ)
  34.   )
  35. ;;转角标注(按对齐标注方式)
  36. (defun c:tt2(/ e1 e13 e14 e2 e2list en en0 p1 p2 sk_dxf code)
  37.   (defun sk_dxf(en code)(cdr(assoc code(entget en))))
  38.   (while (and(setq p1(getpoint "\n指定第一条尺寸界线原点:"))
  39.        (setq p2(getpoint p1 "\n指定第二条尺寸界线原点:")))
  40.     (setq en0(entlast))
  41.     (if(= (getvar "orthomode") 0)
  42.       (progn
  43.       (command "_.DIMALIGNED" p1 p2 pause )      
  44.     (setq en(entlast))
  45.     (if (and en0 en (= (sk_dxf en0 5)(sk_dxf en 5)))
  46.       (princ)
  47.       (progn
  48.       (setq e1(entget en)
  49.       e2(entget en '("*"))
  50.       e2list(assoc -3 e2)
  51.       e1(subst(cons 70 32)(assoc 70 e1)e1)
  52.       e13(cdr(assoc 13 e1))
  53.       e14(cdr(assoc 14 e1))
  54.       e1(subst(cons 50 (angle e13 e14))(assoc 50 e1)e1)
  55.       e1(reverse(cons '(100 . "AcDbRotatedDimension")(reverse e1))))
  56.       ;(entmake (list(cons 0 "line")(cons 10 e13)(cons 11 e14)))
  57.       (entdel en)
  58.       (if e2list(setq e1(cons e2list e1)))
  59.       (entmake  e1)      
  60.       )
  61.       )
  62.     )
  63.       (command "_.DIMLINEAR" p1 p2 pause )
  64.     )
  65.     )
  66.   (princ)
  67.   )

评分

参与人数 2明经币 +2 收起 理由
tryhi + 1 赞一个!
lucas_3333 + 1 支持E大!

查看全部评分

"觉得好,就打赏"
还没有人打赏,支持一下
发表于 2014-5-24 13:58 | 显示全部楼层
为什么entmod不成功?你是改了哪个码?
 楼主| 发表于 2014-5-24 15:20 | 显示全部楼层
自贡黄明儒 发表于 2014-5-24 13:58
为什么entmod不成功?你是改了哪个码?

rote-align
entmod (70 . 33) -> 32&remove last (100 . "AcDbRotatedDimension")
发表于 2014-5-24 15:56 | 显示全部楼层
edata 发表于 2014-5-24 15:20
rote-align
entmod (70 . 33) -> 32&remove last (100 . "AcDbRotatedDimension")

好象这是超出了能entmod的范围了,道理应该和把text改成mtext或者attrib一样,应该都只能entmake后删掉原有的吧
发表于 2019-4-25 12:00 | 显示全部楼层
支持源码发送
您需要登录后才可以回帖 登录 | 注册

本版积分规则

小黑屋|手机版|CAD论坛|CAD教程|CAD下载|联系我们|关于明经|明经通道 ( 粤ICP备05003914号 )  
©2000-2023 明经通道 版权所有 本站代码,在未取得本站及作者授权的情况下,不得用于商业用途

GMT+8, 2024-3-28 17:55 , Processed in 0.254499 second(s), 27 queries , Gzip On.

Powered by Discuz! X3.4

Copyright © 2001-2021, Tencent Cloud.

快速回复 返回顶部 返回列表