零件清角

sanji14 · 发表于 2014-5-28 11:12:48

谁帮忙写个零件清角程序呀
谢谢

lucas_3333 · 发表于 2014-5-28 11:19:45

这是Z版的

;方框圆弧清角明经 ZZXXQQ 2009.7.19
(defun c:tt ()
(setvar "CMDECHO" 0)
(setq oldos (getvar "OSMODE"))
(if (and (setq r (getdist "\n圆弧半径 :"))
(princ "\n选择方框 :")
(setq ss (ssget ":S" '((0 . "LWPOLYLINE") (70 . 1))))) (progn
(setq en (ssname ss 0) ent (entget en))
(if (= (cdr(assoc 90 ent)) 4) (progn
(setq ptl (list))
(foreach n ent (if (= (car N) 10) (setq ptl (cons (cdr n) ptl))))
(setq ptl (reverse ptl))
(setq p1 (car ptl) p2 (cadr ptl) p3 (caddr ptl) p4 (last ptl))
(command "circle" p1 r) (setq e1 (entlast))
(command "circle" p2 r) (setq e2 (entlast))
(command "circle" p3 r) (setq e3 (entlast))
(command "circle" p4 r) (setq e4 (entlast))
(command "trim" e1 e2 e3 e4 "" "f" p1 p3 "" "f" p1 p3 "" "f" p2 p4 "" "f" p2 p4 "" "")
(setq ss (ssget "W" p1 p3))
(command "trim" ss "" "f" p1 p3 "" "f" p2 p4 "" "")
))
))
(setvar "OSMODE" oldos)
(setvar "CMDECHO" 1)
(princ)
)

;方框圆弧清角 明经 ZZXXQQ 2009.7.19 
(defun c:tt () 
  (setvar "CMDECHO" 0) 
  (setq oldos (getvar "OSMODE")) 
  (if (and (setq r (getdist "\n圆弧半径 :")) 
           (princ "\n选择方框 :") 
           (setq ss (ssget ":S" '((0 . "LWPOLYLINE") (70 . 1))))) (progn 
   (setq en (ssname ss 0) ent (entget en)) 
   (if (= (cdr(assoc 90 ent)) 4) (progn 
    (setq ptl (list)) 
    (foreach n ent (if (= (car N) 10) (setq ptl (cons (cdr n) ptl)))) 
    (setq ptl (reverse ptl)) 
    (setq p1 (car ptl) p2 (cadr ptl) p3 (caddr ptl) p4 (last ptl)) 
    (command "circle" p1 r) (setq e1 (entlast)) 
    (command "circle" p2 r) (setq e2 (entlast)) 
    (command "circle" p3 r) (setq e3 (entlast)) 
    (command "circle" p4 r) (setq e4 (entlast)) 
    (command "trim" e1 e2 e3 e4 "" "f" p1 p3 "" "f" p1 p3 "" "f" p2 p4 "" "f" p2 p4 "" "") 
    (setq ss (ssget "W" p1 p3)) 
    (command "trim" ss "" "f" p1 p3 "" "f" p2 p4 "" "") 
   )) 
  )) 
  (setvar "OSMODE" oldos) 
  (setvar "CMDECHO" 1) 
  (princ) 
)

lucas_3333 · 发表于 2014-5-28 11:27:09

这是G版主的

;;逃孔绘制 By Gu_xl 2013.05.08;;更新 2014.01.06 不封闭多段线可以逃孔，已经逃孔部位的不再逃孔
(defun c:taokong (/ TK1 TK2 KD A R SS N E)
;;标准逃孔计算
(defun tk1 (E A R / N EL I P1 P2
P3 CLOCKWISEP MIDANG CP MRP STP ENP
MP BULGE ARCDATA OBJ A1 A2 k
)
(setq obj (vlax-ename->vla-object e))
(if (vlax-curve-isClosed obj)
(progn
(setq i 0)
(setq n (fix (vlax-curve-getEndParam obj)))
)
(progn
(setq i 0)
(setq n (1- (fix (vlax-curve-getEndParam obj)) ))
)
)
(repeat n
(setq p1 (vlax-curve-getPointAtParam e i)
p2 (vlax-curve-getPointAtParam e (setq i (1+ i)))
p3 (vlax-curve-getPointAtParam e (1+ i))
)
(if (and
(vlax-curve-isClosed obj)
(equal i (vlax-curve-getEndParam obj) 1e-6)
)
(setq k 0)
(setq k i)
)
(if (and
(equal 0 (vla-GetBulge obj (1- i)) 1e-6)
(equal 0 (vla-GetBulge obj k) 1e-6)
)
(progn
(if (null p3) (setq p3 (vlax-curve-getPointAtParam e 1)))
(setq a1 (angle p2 p1)
a2 (angle p2 p3)
)
(setq clockwisep
(<
(* (- (car p2) (car p1)) (- (cadr p3) (cadr p1)))
(* (- (cadr p2) (cadr p1)) (- (car p3) (car p1)))
)
)
(if (< a1 a2) (setq a1 (+ a1 pi pi)))
(setq midang (* 0.5 (+ a1 a2)))
(if clockwisep
(setq cp (polar p2 midang (- a r))
mrp (polar p2 midang a)
)
(setq cp (polar p2 midang (- r a))
mrp (polar p2 midang (- a))
)
)
(setq stp (car (vl-remove-if-not
'(lambda (x)
(equal (+ (distance p1 x) (distance p2 x))
(distance p1 p2)
1e-6
)
)
(IntersLineCircle p2 p1 cp r)
)
)
) ;_ 圆弧起点
(setq enp (car (vl-remove-if-not
'(lambda (x)
(equal (+ (distance p3 x) (distance p2 x))
(distance p3 p2)
1e-6
)
)
(IntersLineCircle p2 p3 cp r)
)
)
) ;_ 圆弧终点
(setq mp (mapcar '* '(0.5 0.5 0.5) (MAPCAR '+ stp enp)))
(setq bulge (/ (distance mrp mp) (distance mp stp))) ;_ 弓弦比
(if clockwisep (setq bulge (- bulge)))
(setq arcdata (cons (list stp enp bulge) arcdata))
)
)
)
(setq arcdata (reverse arcdata))
(foreach data arcdata
(setq stp (car data)
enp (cadr data)
bulge (caddr data)
)
(setq n (fix (vlax-curve-getParamAtPoint
obj
(vlax-curve-getclosestpointto obj enp)
)
)
)
(vla-put-coordinate obj n (GXL-AX:2DPOINT stp))
(if (vlax-curve-getPointAtParam obj (1+ n))
(vla-AddVertex obj (1+ n) (GXL-AX:2DPOINT enp))
(vla-AddVertex obj 1 (GXL-AX:2DPOINT enp))
)
(vla-SetBulge obj n bulge)
)
)
;;顺时针。逆时针逃孔计算
(defun tk2 (E R CLOCK / OBJ POLYCLOCK I P1 P2 P3 ARCDATA PT BULGE FLAG
N k)
(setq obj (vlax-ename->vla-object e))
(setq polyClock (not (gxl-clock e)))
(setq i 0)
(if (vlax-curve-isClosed obj)
(progn
(setq i 0)
(setq n (fix (vlax-curve-getEndParam obj)))
)
(progn
(setq i 0)
(setq n (1- (fix (vlax-curve-getEndParam obj))))
)
)
(repeat n
(setq p1 (vlax-curve-getPointAtParam obj i)
p2 (vlax-curve-getPointAtParam obj (setq i (1+ i)))
p3 (vlax-curve-getPointAtParam obj (1+ i))
)
(if (and
(vlax-curve-isClosed obj)
(equal i (vlax-curve-getEndParam obj) 1e-6)
)
(setq k 0)
(setq k i)
)
(if (and
(equal 0 (vla-GetBulge obj (1- i)) 1e-6)
(equal 0 (vla-GetBulge obj k) 1e-6)
)
(progn
(if (null p3) (setq p3 (vlax-curve-getPointAtParam obj 1)))
(cond
(polyClock ;_ 曲线顺时针
(cond
(clock ;_ 顺时针逃孔
;;(加点弓弦比 T在加点处修改弓弦比，nil在上处修改弓弦比)
(setq arcdata (cons (list (polar p2 (angle p2 p3) r) -1 nil) arcdata))
)
(t ;_ 逆时针逃孔
(setq arcdata (cons (list (polar p2 (angle p2 p1) r) -1 t) arcdata))
)
)
)
(t ;_ 曲线逆时针
(cond
(clock ;_ 顺时针逃孔
(setq arcdata (cons (list (polar p2 (angle p2 p1) r) 1 t) arcdata))
)
(t ;_ 逆时针逃孔
(setq arcdata (cons (list (polar p2 (angle p2 p3) r) 1 nil) arcdata))
)
)
)
)
)
)
)
(setq arcdata (reverse arcdata))
(foreach data arcdata
(setq pt (car data)
bulge (cadr data)
flag (caddr data)
)
(setq n (fix (vlax-curve-getParamAtPoint
obj
(vlax-curve-getclosestpointto obj pt)
)
)
)
(if (vlax-curve-getPointAtParam obj (1+ n))
(progn
(vla-AddVertex obj (1+ n) (GXL-AX:2DPOINT pt))
(if flag
(vla-SetBulge obj (1+ n) bulge)
(vla-SetBulge obj n bulge)
)
)
(progn
(vla-AddVertex obj 1 (GXL-AX:2DPOINT pt))
(if flag
(vla-SetBulge obj 1 bulge)
(vla-SetBulge obj 0 bulge)
)
)
)
)
)
(initget "1 2 3")
(if (null
(setq kd (getkword "\n[标准(1)/顺时针(2)/逆时针(3)]<1>"))
)
(setq kd "1")
)
(cond
((= "1" kd)
(if (null (setq a (getreal "\n逃孔量<5.0>:")))
(setq a 5.0)
)
(if (null (setq r (getreal "\n逃孔半径<10.0>:")))
(setq r 10.0)
)
(while (setq ss (ssget '((0 . "lwpolyline"))))
(repeat (setq n (sslength ss))
(setq e (ssname ss (setq n (1- n))))
(tk1 e a r) ;_ 修剪逃孔
)
)
)
(t
(if (null (setq r (getreal "\n逃孔半径<10.0>:")))
(setq r 10.0)
)
(while (setq ss (ssget '((0 . "*polyline"))))
(repeat (setq n (sslength ss))
(setq e (ssname ss (setq n (1- n))))
(tk2 e r (= "2" kd)) ;_ 修剪逃孔
)
)
)
)
(princ)
)
;;*******************以下是一些用到的自定义函数****************************
;; Line-Circle Intersection - Lee Mac
;;直线与园交点
(defun IntersLineCircle ( p q c r / a d n s )
(setq n (mapcar '- q p)
p (trans p 0 n)
c (trans c 0 n)
a (list (car p) (cadr p) (caddr c))
)
(cond
( (equal r (setq d (distance c a)))
(list (trans a n 0))
)
( (< d r)
(setq s (sqrt (- (* r r) (* d d))))
(list
(trans (list (car p) (cadr p) (- (caddr c) s)) n 0)
(trans (list (car p) (cadr p) (+ (caddr c) s)) n 0)
)
)
)
)
;;转换一个点到一个二维ActiveX点
(defun gxl-Ax:2DPoint (pt)
(vlax-make-variant
(vlax-safearray-fill
(vlax-make-safearray vlax-vbdouble '(0 . 1))
(list (car pt) (cadr pt))
)
)
)
;;判断点表或非自交封闭曲线的是否顺时针
(defun gxl-clock (PLIST / LW MINP MAXP LST)
(cond ((= 'LIST (type plist))
(not
(minusp
(apply '+
(mapcar
(function
(lambda (a b)
(- (* (car b) (cadr a)) (* (car a) (cadr b)))
)
)
plist
(cons (last plist) plist)
)
)
)
)
)
(t
(if (= 'ename (type plist))
(setq lw (vlax-ename->vla-object plist))
(if (= 'VLA-OBJECT (type plist))
(setq lw plist)
)
)
(vla-GetBoundingBox lw 'MinP 'MaxP)
(setq
minp (vlax-safearray->list minp)
MaxP (vlax-safearray->list MaxP)
lst (mapcar
(function
(lambda (x)
(vlax-curve-getParamAtPoint
lw
(vlax-curve-getClosestPointTo lw x)
)
)
)
(list minp
(list (car MaxP) (cadr minp))
MaxP
(list (car minp) (cadr MaxP))
)
)
)
(if (or
(<= (car lst) (cadr lst) (caddr lst) (cadddr lst))
(<= (cadr lst) (caddr lst) (cadddr lst) (car lst))
(<= (caddr lst) (cadddr lst) (car lst) (cadr lst))
(<= (cadddr lst) (car lst) (cadr lst) (caddr lst))
)
t
)
)
)
)
;;*******************以上是一些用到的自定义函数****************************

;;逃孔绘制 By Gu_xl 2013.05.08;;更新 2014.01.06 不封闭多段线可以逃孔，已经逃孔 部位的不再逃孔 
(defun c:taokong (/ TK1 TK2 KD A R SS N E) 
  ;;标准逃孔计算 
  (defun tk1 (E A      R      /      N      EL     I      P1     P2 
                P3     CLOCKWISEP    MIDANG CP     MRP    STP    ENP 
                MP     BULGE  ARCDATA       OBJ A1 A2 k 
                ) 
    (setq obj (vlax-ename->vla-object e)) 
    (if (vlax-curve-isClosed obj) 
      (progn 
        (setq i 0) 
        (setq n (fix (vlax-curve-getEndParam obj))) 
        ) 
      (progn 
        (setq i 0) 
        (setq n (1- (fix (vlax-curve-getEndParam obj)) )) 
        ) 
      ) 
 
    (repeat n 
      (setq p1 (vlax-curve-getPointAtParam e i) 
            p2 (vlax-curve-getPointAtParam e (setq i (1+ i))) 
            p3 (vlax-curve-getPointAtParam e (1+ i)) 
            ) 
      (if (and 
            (vlax-curve-isClosed obj) 
            (equal i (vlax-curve-getEndParam obj) 1e-6) 
            ) 
        (setq k 0) 
        (setq k i) 
        ) 
      (if (and 
            (equal 0 (vla-GetBulge obj (1- i)) 1e-6) 
            (equal 0 (vla-GetBulge obj k) 1e-6) 
            ) 
        (progn 
      (if (null p3) (setq p3 (vlax-curve-getPointAtParam e 1))) 
      (setq a1 (angle p2 p1) 
            a2 (angle p2 p3) 
            ) 
      (setq clockwisep 
             (< 
               (* (- (car p2) (car p1)) (- (cadr p3) (cadr p1))) 
               (* (- (cadr p2) (cadr p1)) (- (car p3) (car p1))) 
               ) 
            ) 
      (if (< a1 a2) (setq a1 (+ a1 pi pi))) 
      (setq midang (* 0.5 (+ a1 a2))) 
      (if clockwisep 
        (setq cp (polar p2 midang (- a r)) 
              mrp (polar p2 midang a) 
              ) 
        (setq cp (polar p2 midang (- r a)) 
              mrp (polar p2 midang (- a)) 
              ) 
        ) 
      (setq stp (car (vl-remove-if-not 
                       '(lambda (x) 
                          (equal (+ (distance p1 x) (distance p2 x)) 
                                 (distance p1 p2) 
                                 1e-6 
                                 ) 
                          ) 
                       (IntersLineCircle p2 p1 cp r) 
                       ) 
                     ) 
            ) ;_ 圆弧起点 
      (setq enp (car (vl-remove-if-not 
                       '(lambda (x) 
                          (equal (+ (distance p3 x) (distance p2 x)) 
                                 (distance p3 p2) 
                                 1e-6 
                                 ) 
                          ) 
                       (IntersLineCircle p2 p3 cp r) 
                       ) 
                     ) 
            ) ;_ 圆弧终点 
      (setq mp (mapcar '* '(0.5 0.5 0.5) (MAPCAR '+ stp enp))) 
      (setq bulge (/ (distance mrp mp) (distance mp stp))) ;_ 弓弦比 
      (if clockwisep (setq bulge (- bulge))) 
      (setq arcdata (cons (list stp enp bulge) arcdata)) 
      ) 
        ) 
      ) 
    (setq  arcdata (reverse arcdata)) 
    (foreach data arcdata 
      (setq stp (car data) 
            enp (cadr data) 
            bulge (caddr data) 
            ) 
      (setq n (fix (vlax-curve-getParamAtPoint 
                     obj 
                     (vlax-curve-getclosestpointto obj enp) 
                     ) 
                   ) 
            ) 
      (vla-put-coordinate obj n (GXL-AX:2DPOINT stp)) 
      (if (vlax-curve-getPointAtParam obj (1+ n)) 
      (vla-AddVertex obj (1+ n) (GXL-AX:2DPOINT enp)) 
        (vla-AddVertex obj 1 (GXL-AX:2DPOINT enp)) 
        ) 
      (vla-SetBulge obj n bulge) 
      ) 
    ) 
  ;;顺时针。逆时针逃孔计算 
  (defun tk2 (E R CLOCK / OBJ POLYCLOCK I P1 P2 P3 ARCDATA PT BULGE FLAG 
                N k) 
    (setq obj (vlax-ename->vla-object e)) 
    (setq polyClock (not (gxl-clock e))) 
    (setq i 0) 
    (if (vlax-curve-isClosed obj) 
      (progn 
        (setq i 0) 
        (setq n (fix (vlax-curve-getEndParam obj))) 
        ) 
      (progn 
        (setq i 0) 
        (setq n (1- (fix (vlax-curve-getEndParam obj)))) 
        ) 
      ) 
    (repeat n 
      (setq p1 (vlax-curve-getPointAtParam obj i) 
            p2 (vlax-curve-getPointAtParam obj (setq i (1+ i))) 
            p3 (vlax-curve-getPointAtParam obj (1+ i)) 
            ) 
      (if (and 
            (vlax-curve-isClosed obj) 
            (equal i (vlax-curve-getEndParam obj) 1e-6) 
            ) 
        (setq k 0) 
        (setq k i) 
        ) 
      (if (and 
            (equal 0 (vla-GetBulge obj (1- i)) 1e-6) 
            (equal 0 (vla-GetBulge obj k) 1e-6) 
            ) 
        (progn 
      (if (null p3) (setq p3 (vlax-curve-getPointAtParam obj 1))) 
      (cond 
        (polyClock ;_ 曲线顺时针 
         (cond 
           (clock ;_ 顺时针逃孔 
            ;;(加点 弓弦比 T在加点处修改弓弦比，nil在上处修改弓弦比) 
            (setq arcdata (cons (list (polar p2 (angle p2 p3) r) -1 nil) arcdata)) 
            ) 
           (t ;_ 逆时针逃孔 
            (setq arcdata (cons (list (polar p2 (angle p2 p1) r) -1 t) arcdata)) 
            ) 
           ) 
         ) 
        (t ;_ 曲线逆时针 
         (cond 
           (clock ;_ 顺时针逃孔 
            (setq arcdata (cons (list (polar p2 (angle p2 p1) r) 1 t) arcdata)) 
            ) 
           (t ;_ 逆时针逃孔 
            (setq arcdata (cons (list (polar p2 (angle p2 p3) r) 1 nil) arcdata)) 
            ) 
           ) 
         ) 
        ) 
      ) 
    ) 
      ) 
     (setq  arcdata (reverse arcdata)) 
    (foreach data arcdata 
      (setq pt (car data) 
            bulge (cadr data) 
            flag (caddr data) 
            ) 
      (setq n (fix (vlax-curve-getParamAtPoint 
                     obj 
                     (vlax-curve-getclosestpointto obj pt) 
                     ) 
                   ) 
            ) 
      (if (vlax-curve-getPointAtParam obj (1+ n)) 
        (progn 
         (vla-AddVertex obj (1+ n) (GXL-AX:2DPOINT pt)) 
         (if flag 
           (vla-SetBulge obj (1+ n) bulge) 
           (vla-SetBulge obj n bulge) 
           ) 
         ) 
        (progn 
         (vla-AddVertex obj 1 (GXL-AX:2DPOINT pt)) 
         (if flag 
           (vla-SetBulge obj 1 bulge) 
           (vla-SetBulge obj 0 bulge) 
           ) 
         ) 
        ) 
      ) 
      ) 
  (initget "1 2 3") 
  (if (null 
        (setq kd (getkword "\n[标准(1)/顺时针(2)/逆时针(3)]<1>")) 
        ) 
    (setq kd "1") 
    ) 
  (cond 
    ((= "1" kd) 
     (if (null (setq a (getreal "\n逃孔量<5.0>:"))) 
       (setq a 5.0) 
       ) 
     (if (null (setq r (getreal "\n逃孔半径<10.0>:"))) 
       (setq r 10.0) 
       ) 
     (while (setq ss (ssget '((0 . "lwpolyline")))) 
       (repeat (setq n (sslength ss)) 
         (setq e (ssname ss (setq n (1- n)))) 
         (tk1 e a r) ;_ 修剪逃孔 
         ) 
       ) 
     ) 
    (t 
     (if (null (setq r (getreal "\n逃孔半径<10.0>:"))) 
       (setq r 10.0) 
       ) 
     (while (setq ss (ssget '((0 . "*polyline")))) 
       (repeat (setq n (sslength ss)) 
         (setq e (ssname ss (setq n (1- n)))) 
         (tk2 e  r (= "2" kd)) ;_ 修剪逃孔 
         ) 
       ) 
     ) 
    ) 
  (princ) 
  ) 
;;*******************以下是一些用到的自定义函数**************************** 
;; Line-Circle Intersection - Lee Mac 
;;直线与园交点 
(defun IntersLineCircle ( p q c r / a d n s ) 
  (setq n (mapcar '- q p) 
        p (trans p 0 n) 
        c (trans c 0 n) 
        a (list (car p) (cadr p) (caddr c)) 
  ) 
  (cond 
    ( (equal r (setq d (distance c a))) 
      (list (trans a n 0)) 
    ) 
    ( (< d r) 
      (setq s (sqrt (- (* r r) (* d d)))) 
      (list 
        (trans (list (car p) (cadr p) (- (caddr c) s)) n 0) 
        (trans (list (car p) (cadr p) (+ (caddr c) s)) n 0) 
      ) 
    ) 
  ) 
) 
;;转换一个点到一个二维ActiveX点 
(defun gxl-Ax:2DPoint (pt) 
  (vlax-make-variant 
    (vlax-safearray-fill 
      (vlax-make-safearray vlax-vbdouble '(0 . 1)) 
      (list (car pt) (cadr pt)) 
    ) 
  ) 
) 
;;判断点表或非自交封闭曲线的是否顺时针 
(defun gxl-clock  (PLIST / LW MINP MAXP LST) 
  (cond        ((= 'LIST (type plist)) 
          (not 
            (minusp 
              (apply '+ 
                     (mapcar 
                       (function 
                         (lambda (a b) 
                           (- (* (car b) (cadr a)) (* (car a) (cadr b))) 
                         ) 
                       ) 
                       plist 
                       (cons (last plist) plist) 
                     ) 
              ) 
            ) 
          ) 
        ) 
        (t 
         (if (= 'ename (type plist)) 
           (setq lw (vlax-ename->vla-object plist)) 
           (if (= 'VLA-OBJECT (type plist)) 
             (setq lw plist) 
             ) 
           ) 
         (vla-GetBoundingBox lw 'MinP 'MaxP) 
         (setq 
           minp        (vlax-safearray->list minp) 
           MaxP        (vlax-safearray->list MaxP) 
           lst        (mapcar 
                  (function 
                    (lambda (x) 
                      (vlax-curve-getParamAtPoint 
                        lw 
                        (vlax-curve-getClosestPointTo lw x) 
                        ) 
                      ) 
                    ) 
                  (list        minp 
                        (list (car MaxP) (cadr minp)) 
                        MaxP 
                        (list (car minp) (cadr MaxP)) 
                        ) 
                  ) 
           ) 
         (if (or 
               (<= (car lst) (cadr lst) (caddr lst) (cadddr lst)) 
               (<= (cadr lst) (caddr lst) (cadddr lst) (car lst)) 
               (<= (caddr lst) (cadddr lst) (car lst) (cadr lst)) 
               (<= (cadddr lst) (car lst) (cadr lst) (caddr lst)) 
               ) 
           t 
           ) 
         ) 
        ) 
 
  ) 
;;*******************以上是一些用到的自定义函数****************************

ysq101 · 发表于 2014-5-28 11:47:48

这纯COMMAND啊

sanji14 · 发表于 2014-5-29 09:33:02

本帖最后由 sanji14 于 2014-5-29 09:40 编辑

file:///C:/Users/yangjun/AppData/Local/Temp/msohtmlclip1/01/clip_image001.jpg

非常感谢！！！！能不能做成图片这样呀



！

lucas_3333 · 发表于 2014-5-30 09:51:14

sanji14 发表于 2014-5-29 09:33
非常感谢！！！！能不能做成图片这样呀

你发的啥子内容哟？

sanji14 · 发表于 2014-6-12 22:48:19

可以做成图示那样吗?

至今没学会 · 发表于 2021-7-27 16:28:32

sanji14 发表于 2014-6-12 22:48
可以做成图示那样吗?

找到你图片这样的了嘛？兄弟，找到发我一份，谢谢了

fangseng · 发表于 2021-8-5 17:38:46

; 错误: 输入的列表有缺陷

xiaobailou · 发表于 2023-10-28 22:12:53

哪位兄弟有发我一份

账号		自动登录	找回密码
密码			注册

[源码] 零件清角

本帖子中包含更多资源