请教各位，如何求得一个图层里面所有PLINE线的长度总和

HZAUHGT

请教各位，如何求得一个图层里面所有PLINE线的长度总和，（用LIST，然后一个一个的累加，工作量太大，我的一个图层有800多条线段，）
谢谢！谢谢！谢谢！+
[em00]

gyl

编程基本思路：建立一个选择集，包含该层的所有pline线，遍历选择集中的每一个图元，查询其长度，进行累加即可。

meflying

程序返回PLINE总长度

2. 
   
3. (vl-load-com)
   
4. (defun c:addpline( / ss sum ent i)
   
5.   (setq ss (ssget '((0 . "lwpolyline,polyline"))))
   
6.   (setq sum 0)
   
7.   (setq i 0)
   
8.   (repeat (sslength ss)
   
9.     (setq ent (ssname ss i))
   
10.     (setq ent (vlax-ename->vla-object ent))
    
11.     (setq sum (+ sum (vlax-curve-getDistAtPoint ent (vlax-curve-getEndPoint ent))))
    
12.     (setq i (1+ i))
    
13.   )
    
14.   sum
    
15. )
    

<br /> (vl-load-com)<br /> (defun c:addpline( / ss sum ent i)<br />   (setq ss (ssget '((0 . "lwpolyline,polyline"))))<br />   (setq sum 0)<br />   (setq i 0)<br />   (repeat (sslength ss)<br />     (setq ent (ssname ss i))<br />     (setq ent (vlax-ename->vla-object ent))<br />     (setq sum (+ sum (vlax-curve-getDistAtPoint ent (vlax-curve-getEndPoint ent))))<br />     (setq i (1+ i))<br />   )<br />   sum<br /> )<br />

HZAUHGT

对各位高手表示最诚挚的感谢，终于不用花今天时间来统计了，谢谢

龙龙仔

;;FOR R14
;;Total length of selected lines

;;LL sums the length of all objects on selected layers.
;;OBL sums the length of selected objects.

;;Both print the output to the command line giving the lengths for different
;;layers as well as a total.

(defun CL (/)
  (LL:OUTPUT "X" "\nSelect objects on layers to total...")
  (princ)
)

(defun C:OBL (/)
  (LL:OUTPUT "" "\nSelect objects to total...")
  (princ)
)

(defun LL:OUTPUT (LL:SSTYPE         LL:PROMPT        /
                  LL:SS                 I                LL:ENAME
                  LL:ELIST         LLAYER        LLAYERLIST
                  LL:TOTALLENGTH LLAYERLENGTH        LL:ARCDELTA
                  LL:OBJLENGTH         LL:SPACE
                 )
  (prompt
    "\nLayer Lengths by Jaysen D. Long\nCopyright 1998-1999. All Rights Reserved."
  )
  (setq LLAYERLIST NIL)
  (prompt LL:PROMPT)
  (if (setq LL:SS
             (ssget
               '((0 . "ARC,CIRCLE,ELLIPSE,LINE,*POLYLINE,REGION,SPLINE"))
             )
      )
    (progn
      (repeat (setq I (sslength LL:SS))
        (setq LL:ELIST (entget (ssname LL:SS (setq I (1- I)))))
        (if (not (member (setq LLAYER (cdr (assoc 8 LL:ELIST)))
                         LLAYERLIST
                 )
            )
          (setq LLAYERLIST (append LLAYERLIST (list LLAYER)))
        )
      )
      (setq LL:TOTALLENGTH 0.0)
      (foreach X LLAYERLIST
        (setq LLAYERLENGTH 0.0)
        (command "._select" LL:SS "")
        (setq LL:SS
               (ssget
                 LL:SSTYPE
                 (list
                   (cons 0 "ARC,CIRCLE,ELLIPSE,LINE,*POLYLINE,REGION,SPLINE")
                   (cons 8 X)
                 )
               )
        )
        (repeat        (setq I (sslength LL:SS))
          (setq LL:ENAME (ssname LL:SS (setq I (1- I))))
          (setq LL:ELIST (entget LL:ENAME))
          (cond
            ((eq (cdr (assoc 0 LL:ELIST)) "ARC")
             (if
               (> (cdr (assoc 50 LL:ELIST)) (cdr (assoc 51 LL:ELIST)))
                (setq LL:ARCDELTA
                       (+ (abs (- (cdr (assoc 50 LL:ELIST))
                                  (* 2.0 pi)
                               )
                          )
                          (cdr (assoc 51 LL:ELIST))
                       )
                )
                (setq LL:ARCDELTA
                       (- (cdr (assoc 51 LL:ELIST))
                          (cdr (assoc 50 LL:ELIST))
                       )
                )
             )
             (setq LL:OBJLENGTH
                    (* (cdr (assoc 40 LL:ELIST)) LL:ARCDELTA)
             )
            )
            ((eq (cdr (assoc 0 LL:ELIST)) "LINE")
             (setq LL:OBJLENGTH
                    (distance (cdr (assoc 10 LL:ELIST))
                              (cdr (assoc 11 LL:ELIST))
                    )
             )
            )
            ((wcmatch (cdr (assoc 0 LL:ELIST))
                      "*POLYLINE,CIRCLE,ELLIPSE,REGION,SPLINE"
             )
             (command "._area" "_obj" LL:ENAME)
             (setq LL:OBJLENGTH (getvar "perimeter"))
            )
          )
          (setq LLAYERLENGTH (+ LLAYERLENGTH LL:OBJLENGTH))
        )
        (setq LL:SPACE        ""
              LL:PROMPT        (strcat        X
                                ": "
                                (rtos LLAYERLENGTH 2 2)
                                " LF"
                        )
        )
        (prompt        (strcat        "\n"
                        X
                        ": "
                        (repeat        (- 52 (strlen LL:PROMPT))
                          (setq
                            LL:SPACE (strcat LL:SPACE " ")
                          )
                        )
                        (rtos LLAYERLENGTH 2 2)
                        " LF"
                )
        )
        (setq LL:TOTALLENGTH (+ LL:TOTALLENGTH LLAYERLENGTH))
      )
      (setq LL:SPACE  ""
            LL:PROMPT (strcat "Total: "
                              (rtos LL:TOTALLENGTH
                                    2
                                    2
                              )
                              " LF"
                      )
      )
      (prompt (strcat "\nTotal: "
                      (repeat (- 52 (strlen LL:PROMPT))
                        (setq
                          LL:SPACE (strcat LL:SPACE " ")
                        )
                      )
                      (rtos LL:TOTALLENGTH 2 2)
                      " LF"
              )
      )
    )
  )
)

lockmyeye

哗！
好古董！

龙龙仔

人老了,收集的東西成便古董！哈哈!

tukuitk

飞哥，你的这个程序有个小问题：
当PLINE线重合时有问题。如两条水平的长均为100的PLINE线，它计算的结果是100，而不是200。
你试一下。

meflying

不可能，我看了程序，不会有这样的结果，而且我试了，结果也是正确的。
可能是你的操作有误，选择时，如果两条线重合，你必须窗交或窗围来选，而不能点取，你可以试试用删除，如果用点的话，你永远只能选中一条直线

zqw_zhang

谢谢龙龙仔,正在找这个东西呢.