[求助]如何划圆弧

老虎

请各位帮帮忙，兄弟有一个小问题。过已知点如何画一条于已知圆或圆弧相切的圆弧？我现在的做法是过已知点画一个圆，然后再以已知圆的圆心画另一相应的圆，这样的两个交点就是所求圆弧的圆心，再用修剪命令。这样的做法很烦，还有更简单的方法吗？

东哥

少一个条件。

r0r

好象没有直接的方法

runkeji

不明白，说详细一点，传个图上来好吗？

gzy

在LISP版块有meflying版主的相关程序，能快速的画出来

老虎

过A如何作一R为60的圆弧？

gzy

唉，不是跟你说了去论坛收索吗？害得我给你找了这么久！
以下是MEFLYING版主曾经写的：
(defun GetInterPoint (ent1 ent2 / ax_ent_1 ax_ent_2 intpoints points i)
  (setq ax_ent_1 (vlax-ename->vla-object ent1)
        ax_ent_2 (vlax-ename->vla-object ent2)
  )
  (setq intpoints (vla-intersectwith ax_ent_1 ax_ent_2 acextendnone))
  (setq intpoints (vlax-variant-value intpoints))
  (setq i 0)
  (if (> (vlax-safearray-get-u-bound intpoints 1) 0)
    (repeat (/ (+ 1
              (- (vlax-safearray-get-u-bound intpoints 1)
                 (vlax-safearray-get-l-bound intpoints 1)
              )
           )
           3
        )
      (setq points (append points (list (list
        (vlax-safearray-get-element intpoints i)
        (vlax-safearray-get-element intpoints (+ i 1))
        (vlax-safearray-get-element intpoints (+ i 2))
      )))
      )
      (setq i (+ 3 i))
    )
  )
  points
)

(defun c:DrawCircle( / ent pt r entc entl pts i)
  (setq ent (car (entsel "\n选择直线或圆弧...")))
  (setq pt (getpoint "\n输入通过点:"))
  (setq r (getreal "\n输入半径:"))
  (setvar "cmdecho" 0)
  (command "_.circle" pt r)
  (setq entc (entlast))
  (command "_.offset" r ent pt "")
  (setq entl (entlast))
  (setq pts (GetInterpoint entc entl))
  (entdel entc)
  (entdel entl)
  (setq i 0)
  (repeat (length pts)
    (setq pt (nth i pts))
    (command "_.circle" pt r)
    (setq entc (entlast))
    (if (= (length (GetInterpoint entc ent)) 0) (entdel entc))
    (setq i (1+ i))
  )
  (princ)
)

体验

我这有个相对简单的方法，把已知圆的圆心和已知点通过直线相连接，然后在圆的命令行选择2P,直径第一点指定直线与已知圆的交点，第二点选择已知点，这样就可以做一个过已知点与已知圆现切的圆。

gzy

聪明，你利用的是连心线长度为两半径之和原理，看来你的几何学得不错呵！

体验

过奖过奖！！：）