如何获取多重引线的文字的外框大小，或右下角坐标，或行数

dingtiedt

多重引线（mld）对齐
http://bbs.mjtd.com/forum.php?mod=viewthread&tid=168655&fromuid=7309019

多重引线的对齐问题通过大师前辈的指点基本上解决了，还是想把间距排列也写进去，统一成一个命令。
构想一：（文本高度+间距），问题是，如何获取文字的外框大小或右下角坐标
构想二：（（（文字的大小）*行数）+间距），问题是，如何获取文字的行数

再请大师指点迷津，先谢谢！

lucas_3333

dingtiedt 发表于 2015-7-29 14:11
无意中在G版提供的lee-mac的页面看到了 “string to list”，正符合其中的一个构想，先取得多重引线的多行文 ...

LeeMac的函数可以做到

1. ;; MLeader Textbox  -  Lee Mac
   
2. (defun LM:mleadertextbox ( ent / bpt enx hgt jus lst mat org prp rot wid )
   
3.     (if (= acmtextcontent (cdr (assoc 172 (reverse (setq enx (entget ent))))))
   
4.         (progn
   
5.             (setq prp (list (cons 40 (cdr (assoc 41 enx)))
   
6.                             (cons 07 (cdr (assoc 02 (entget (cdr (assoc 340 enx))))))
   
7.                       )
   
8.                   lst (vl-remove-if 'null
   
9.                           (mapcar
   
10.                              '(lambda ( str / box )
    
11.                                   (if (setq box (textbox (cons (cons 1 str) prp)))
    
12.                                       (mapcar '- (cadr box) (car box))
    
13.                                   )
    
14.                               )
    
15.                               (LM:str->lst (cdr (assoc 304 enx)) "\\P")
    
16.                           )
    
17.                       )
    
18.                   bpt (trans (cdr (assoc 12 enx)) 0 (cdr (assoc 11 enx)))
    
19.                   rot (cdr (assoc 042 enx))
    
20.                   jus (cdr (assoc 171 enx))
    
21.                   wid (apply 'max (mapcar 'car lst))
    
22.                   hgt (+ (apply '+ (mapcar 'cadr lst)) (* 0.68 (cdr (assoc 45 enx)) (1- (length lst))))
    
23.                   org (list (cond ((member jus '(2 5 8)) (/ wid -2.0)) ((member jus '(3 6 9)) (- wid))      (0.0))
    
24.                             (cond ((member jus '(1 2 3)) (- hgt))      ((member jus '(4 5 6)) (/ hgt -2.0)) (0.0))
    
25.                       )
    
26.                   mat (list
    
27.                           (list (cos rot) (sin (- rot)) 0.0)
    
28.                           (list (sin rot) (cos rot)     0.0)
    
29.                          '(0.0 0.0 1.0)
    
30.                       )
    
31.             )
    
32.             (mapcar '(lambda ( p ) (mapcar '+ (mxv mat p) bpt))
    
33.                 (list org
    
34.                     (mapcar '+ org (list wid   0))
    
35.                     (mapcar '+ org (list wid hgt))
    
36.                     (mapcar '+ org (list 0   hgt))
    
37.                 )
    
38.             )
    
39.         )
    
40.     )
    
41. )
    
42. 
    
43. ;; String to List  -  Lee Mac
    
44. (defun LM:str->lst ( str del / pos )
    
45.     (if (setq pos (vl-string-search del str))
    
46.         (cons (substr str 1 pos) (LM:str->lst (substr str (+ pos 1 (strlen del))) del))
    
47.         (list str)
    
48.     )
    
49. )
    
50. (defun mxv ( m v )
    
51.     (mapcar '(lambda ( r ) (apply '+ (mapcar '* r v))) m)
    
52. )

;; MLeader Textbox  -  Lee Mac<br /> (defun LM:mleadertextbox ( ent / bpt enx hgt jus lst mat org prp rot wid )<br />     (if (= acmtextcontent (cdr (assoc 172 (reverse (setq enx (entget ent))))))<br />         (progn<br />             (setq prp (list (cons 40 (cdr (assoc 41 enx)))<br />                             (cons 07 (cdr (assoc 02 (entget (cdr (assoc 340 enx))))))<br />                       )<br />                   lst (vl-remove-if 'null<br />                           (mapcar<br />                              '(lambda ( str / box )<br />                                   (if (setq box (textbox (cons (cons 1 str) prp)))<br />                                       (mapcar '- (cadr box) (car box))<br />                                   )<br />                               )<br />                               (LM:str->lst (cdr (assoc 304 enx)) "\\P")<br />                           )<br />                       )<br />                   bpt (trans (cdr (assoc 12 enx)) 0 (cdr (assoc 11 enx)))<br />                   rot (cdr (assoc 042 enx))<br />                   jus (cdr (assoc 171 enx))<br />                   wid (apply 'max (mapcar 'car lst))<br />                   hgt (+ (apply '+ (mapcar 'cadr lst)) (* 0.68 (cdr (assoc 45 enx)) (1- (length lst))))<br />                   org (list (cond ((member jus '(2 5 8)) (/ wid -2.0)) ((member jus '(3 6 9)) (- wid))      (0.0))<br />                             (cond ((member jus '(1 2 3)) (- hgt))      ((member jus '(4 5 6)) (/ hgt -2.0)) (0.0))<br />                       )<br />                   mat (list<br />                           (list (cos rot) (sin (- rot)) 0.0)<br />                           (list (sin rot) (cos rot)     0.0)<br />                          '(0.0 0.0 1.0)<br />                       )<br />             )<br />             (mapcar '(lambda ( p ) (mapcar '+ (mxv mat p) bpt))<br />                 (list org<br />                     (mapcar '+ org (list wid   0))<br />                     (mapcar '+ org (list wid hgt))<br />                     (mapcar '+ org (list 0   hgt))<br />                 )<br />             )<br />         )<br />     )<br /> )<br /> <br /> ;; String to List  -  Lee Mac<br /> (defun LM:str->lst ( str del / pos )<br />     (if (setq pos (vl-string-search del str))<br />         (cons (substr str 1 pos) (LM:str->lst (substr str (+ pos 1 (strlen del))) del))<br />         (list str)<br />     )<br /> )<br /> (defun mxv ( m v )<br />     (mapcar '(lambda ( r ) (apply '+ (mapcar '* r v))) m)<br /> )

_$ (setq e (ssget "_+.:E:S" '((0 . "MULTILEADER"))))
(setq e (ssname e 0))
(LM:mleadertextbox e)
<Selection set: 383>
<Entity name: 7ee384f8>
((1920.97 605.151 0.0) (1947.5 605.151 0.0) (1947.5 609.285 0.0) (1920.97 609.285 0.0))

dingtiedt

无意中在G版提供的lee-mac的页面看到了 “string to list”，正符合其中的一个构想，先取得多重引线的多行文字的字符串，再按 "\\" 为界分段取字符串，最后用length求得数目，就是“行数”

2. ;; String to List  -  Lee Mac
   
3. ;; Separates a string using a given delimiter
   
4. ;; str - [str] String to process
   
5. ;; del - [str] Delimiter by which to separate the string
   
6. ;; Returns: [lst] List of strings
   
7. 
   
8. (defun LM:str->lst ( str del / len lst pos )
   
9.     (setq len (1+ (strlen del)))
   
10.     (while (setq pos (vl-string-search del str))
    
11.         (setq lst (cons (substr str 1 pos) lst)
    
12.               str (substr str (+ pos len))
    
13.         )
    
14.     )
    
15.     (reverse (cons str lst))
    
16. )
    

;; String to List  -  Lee Mac<br /> ;; Separates a string using a given delimiter<br /> ;; str - [str] String to process<br /> ;; del - [str] Delimiter by which to separate the string<br /> ;; Returns: [lst] List of strings<br /> <br /> (defun LM:str->lst ( str del / len lst pos )<br />     (setq len (1+ (strlen del)))<br />     (while (setq pos (vl-string-search del str))<br />         (setq lst (cons (substr str 1 pos) lst)<br />               str (substr str (+ pos len))<br />         )<br />     )<br />     (reverse (cons str lst))<br /> )<br />

测试有用

cable2004

能不能直接求文字的box呢？

dingtiedt

cable2004 发表于 2015-7-29 14:20
能不能直接求文字的box呢？

textbox好象只对单行文字有效，mtext的dxf里有“43多行文字图元的垂直高度”，多重引线的多行文字的却找不到。
请问你有具体的方法吗？

cable2004

水平文字可以(vla-GetBoundingBox (vlax-ename->vla-object obj) 'Minp 'Maxp)

dingtiedt

cable2004 发表于 2015-7-29 14:57
水平文字可以(vla-GetBoundingBox (vlax-ename->vla-object obj) 'Minp 'Maxp)

谢谢你的回复。用这个测试了一下，得到的坐标是整个多重引线的左下角点和右上角，是不是用这个方法也能得到多重引线中的文字的坐标？

dingtiedt

lucas_3333 发表于 2015-7-31 10:50
LeeMac的函数可以做到

太好了，谢谢你解囊相助！

137407536

你好，这个LM函数的代码是怎么用到CAD里边的？直接加载然后输入什么命令？