“反向隐藏”达不到‘反向’的效果

冒个烟圈

；；；阿甘兄弟的代码，前面两个命令“隐藏物体”和“恢复隐藏”挺好用的，
；；；但是“反向隐藏”没有达到反向的效果，执行后全部都隐藏了，恳请帮忙诊断能达到反向的效果。。


;[隐藏物体]
(defun c:yc (/ AcadObject AcadDocument LayersObj ss n i ent ob lay vlay lay-tn)
(setq AcadObject (vlax-get-acad-object)
              AcadDocument (vla-get-ActiveDocument AcadObject)
              LayersObj (vla-get-layers AcadDocument)
);end setq
(princ "\n请选择需要隐藏的物体" )
(if (setq ss (ssget))
               (progn
                      (setq n (sslength ss))
                      (setq i (- n 1))
                      (repeat n
                             (setq ent (ssname ss i)
                                    ob (vlax-ename->vla-object ent)
                                    lay (vla-get-layer ob)
                                    vlay (vla-item LayersObj lay)
                            );end setq
                             (if (= (setq lay-tn (vla-get-lock vlay)) :vlax-true);如果图层锁定
                                    (vla-put-lock vlay :vlax-false);先解锁图层
                            );end if
                             (vla-put-visible ob :vlax-false)
                             (if (= lay-tn :vlax-true)
                                    (vla-put-lock vlay :vlax-true);再锁定图层，恢复图层状态
                            );end if
                             (setq i (1- i))
                     );end repeat
                      (princ "\n已隐藏选择物体" )
));end if
(princ)
);end defun
;[恢复隐藏]
(defun c:xs (/ AcadObject AcadDocument LayersObj ss n i ent ob lay vlay lay-tn)
(setq AcadObject (vlax-get-acad-object)
              AcadDocument (vla-get-ActiveDocument AcadObject)
              LayersObj (vla-get-layers AcadDocument)
);end setq
(if (setq ss (ssget "x" '((60 . 1))))
               (progn
                      (setq n (sslength ss))
                      (setq i (- n 1))
                      (repeat n
                             (setq ent (ssname ss i)
                                    ob (vlax-ename->vla-object ent)
                                    lay (vla-get-layer ob)
                                    vlay (vla-item LayersObj lay)
                            );end setq
                             (if (= (setq lay-tn (vla-get-lock vlay)) :vlax-true)
                                    (vla-put-lock vlay :vlax-false)
                            );end if
                             (vla-put-visible ob :vlax-true)
                             (if (= lay-tn :vlax-true)
                                    (vla-put-lock vlay :vlax-true)
                            );end if
                             (setq i (1- i))
                     );end repeat
                      (princ "\n已显示隐藏物体" )
              );end progn
               (princ "\n本图无隐藏物体" )
);end if
;(vla-regen AcadDocument AcAllViewPorts) 图形较大有时需要重生成才显示 可把这句加上
(princ)
);end defun
;[隐藏物体(反)]
(defun c:yf (/ AcadObject AcadDocument LayersObj ssObj ss ob n i ent ob ss2 ss3 lay vlay lay-tn)
(setq AcadObject (vlax-get-acad-object)
              AcadDocument (vla-get-ActiveDocument AcadObject)
              LayersObj (vla-get-layers AcadDocument)
);end setq
(princ "\n请选择不需要隐藏的物体" )
(if (setq ss (ssget))
               (progn
                      (setq ss2 (ssget "x" ))
                      (setq n (sslength ss))
                      (setq i (- n 1))
                      (repeat n
                             (setq ent (ssname ss i))
                             (if (setq ss3 (ssdel ent ss2))
                                    (setq ss2 ss3)
                            );end if
                             (setq i (1- i))
                     );end repeat
                      (sssetfirst nil ss2)
                      (setq ssObj (vla-get-ActiveSelectionSet AcadDocument))
                      (vlax-for ob ssObj
                             (setq lay (vla-get-layer ob)
                                    vlay (vla-item LayersObj lay)
                            );end setq
                             (if (= (setq lay-tn (vla-get-lock vlay)) :vlax-true)
                                    (vla-put-lock vlay :vlax-false)
                            );end if
                             (vla-put-visible ob :vlax-false)
                             (if (= lay-tn :vlax-true)
                                    (vla-put-lock vlay :vlax-true)
                            );end if
                     );end vlax-for
                      (princ "\n已隐藏非选择物体" )
));end if
(sssetfirst nil nil)
(princ)
);end defun
(princ "\n[隐藏物体-yc]/[恢复隐藏-xs]/[隐藏物体(反)-yf]" )

oistre

谢谢大神，牛牛牛牛！！！

ZZXXQQ

2. ;[隐藏物体(反)]
   
3. (defun c:yf (/ AcadObject AcadDocument LayersObj ssObj ss ob n i ent ob ss2 ss3 lay vlay lay-tn)
   
4. (setq AcadObject (vlax-get-acad-object)
   
5.       AcadDocument (vla-get-activedocument AcadObject)
   
6.       LayersObj (vla-get-layers AcadDocument)
   
7. );end setq
   
8. (princ "\n请选择不需要隐藏的物体" )
   
9. (if (setq ss (ssget)) (progn
   
10.   (setq ss2 (ssget "x"))
    
11.   (repeat (setq i (sslength ss))
    
12.    (ssdel (ssname ss (setq i (1- i))) ss2)
    
13.   );end repeat
    
14.   (sssetfirst nil ss2)
    
15.   (repeat (setq i (sslength ss2))
    
16.    (setq ent (ssname ss2 (setq i (1- i)))
    
17.          ob (vlax-ename->vla-object ent)
    
18.          lay (vla-get-layer ob)
    
19.          vlay (vla-item LayersObj lay)
    
20.    );end setq
    
21.    (if (= (setq lay-tn (vla-get-lock vlay)) :vlax-true);如果图层锁定
    
22.     (vla-put-lock vlay :vlax-false);先解锁图层
    
23.    );end if
    
24.    (vla-put-visible ob :vlax-false)
    
25.    (if (= lay-tn :vlax-true)
    
26.     (vla-put-lock vlay :vlax-true);再锁定图层，恢复图层状态
    
27.    );end if
    
28.   );end repeat
    
29.   (princ "\n已隐藏非选择物体" )
    
30. ));end if
    
31. (sssetfirst nil nil)
    
32. (princ)
    
33. );end defun
    

;[隐藏物体(反)]<br /> (defun c:yf (/ AcadObject AcadDocument LayersObj ssObj ss ob n i ent ob ss2 ss3 lay vlay lay-tn)<br /> (setq AcadObject (vlax-get-acad-object)<br />       AcadDocument (vla-get-activedocument AcadObject)<br />       LayersObj (vla-get-layers AcadDocument)<br /> );end setq<br /> (princ "\n请选择不需要隐藏的物体" )<br /> (if (setq ss (ssget)) (progn<br />   (setq ss2 (ssget "x"))<br />   (repeat (setq i (sslength ss))<br />    (ssdel (ssname ss (setq i (1- i))) ss2)<br />   );end repeat<br />   (sssetfirst nil ss2)<br />   (repeat (setq i (sslength ss2))<br />    (setq ent (ssname ss2 (setq i (1- i)))<br />          ob (vlax-ename->vla-object ent)<br />          lay (vla-get-layer ob)<br />          vlay (vla-item LayersObj lay)<br />    );end setq<br />    (if (= (setq lay-tn (vla-get-lock vlay)) :vlax-true);如果图层锁定<br />     (vla-put-lock vlay :vlax-false);先解锁图层<br />    );end if<br />    (vla-put-visible ob :vlax-false)<br />    (if (= lay-tn :vlax-true)<br />     (vla-put-lock vlay :vlax-true);再锁定图层，恢复图层状态<br />    );end if<br />   );end repeat<br />   (princ "\n已隐藏非选择物体" )<br /> ));end if<br /> (sssetfirst nil nil)<br /> (princ)<br /> );end defun<br />

lingduwx

嘿嘿，顶一个哈

ymcui

非常好用，谢谢

lingduwx

ymcui 发表于 2015-10-13 10:06
非常好用，谢谢

大哥能否把你的lsp发一个啊，我的合并代码后，反隐藏  没有反应啊，谢谢了

ivde

(defun c:yf (/ ss s sl e)
  (if (and (progn
      (setq ss (ssget))
      (vl-cmdf ".select" "all" "r" ss "")
      (setq s (ssget "P")
      )
    )
      )
    (progn
      (setvar "cmdecho" 0)
      (layerstate-save "tmpHide")
      (vl-cmdf ".layer" "U" "*" "")
      (setq sl (sslength s))
      (while (setq e (ssname s (setq sl (1- sl))))
(entmod (append (entget e) '((60 . 1))))
      )
      (layerstate-restore "tmpHide")
      (layerstate-delete "tmpHide")
    )
  )
  (princ)
)

qmqyqj

ZZXXQQ 发表于 2015-10-13 08:47

隐藏了反向，那怎么再把隐藏后的显示出来呢？

ymcui

lingduwx 发表于 2015-10-13 10:10
大哥能否把你的lsp发一个啊，我的合并代码后，反隐藏  没有反应啊，谢谢了

我就用的,ZZXXQQ 的程序.

ymcui

qmqyqj 发表于 2015-10-13 10:57
隐藏了反向，那怎么再把隐藏后的显示出来呢？

;[恢复隐藏]
(defun c:xs (/ AcadObject AcadDocument LayersObj ss n i ent ob lay vlay lay-tn)
(setq AcadObject (vlax-get-acad-object)
              AcadDocument (vla-get-ActiveDocument AcadObject)
              LayersObj (vla-get-layers AcadDocument)
);end setq
(if (setq ss (ssget "x" '((60 . 1))))
               (progn
                      (setq n (sslength ss))
                      (setq i (- n 1))
                      (repeat n
                             (setq ent (ssname ss i)
                                    ob (vlax-ename->vla-object ent)
                                    lay (vla-get-layer ob)
                                    vlay (vla-item LayersObj lay)
                            );end setq
                             (if (= (setq lay-tn (vla-get-lock vlay)) :vlax-true)
                                    (vla-put-lock vlay :vlax-false)
                            );end if
                             (vla-put-visible ob :vlax-true)
                             (if (= lay-tn :vlax-true)
                                    (vla-put-lock vlay :vlax-true)
                            );end if
                             (setq i (1- i))
                     );end repeat
                      (princ "\n已显示隐藏物体" )
              );end progn
               (princ "\n本图无隐藏物体" )
);end if
;(vla-regen AcadDocument AcAllViewPorts) 图形较大有时需要重生成才显示 可把这句加上
(princ)
);end defun

lingduwx

哎，不知道咋回事就是不行，我自己也无语了