获取块实例中对象的信息

vectra

一个块由多段线和直线组成，图形中有很多该块的实例。各实例可能进行任意的变换（旋转、非等比的缩放。。），如何获取直线在各实例中的起点及终点？

aihuyujian

循环+遍历块 应该可以获取吧
我擦  没看见是大神提问  那估计 循环+遍历块 可能是获取不到了 。。。

feng83

不会在块内做遍历，不过如果块定义的基点在直线上，可以提取出一个直线的端点，在根据50组码和41，42，43组码将另外一个点算出来，

vectra

经过几天的搜索，发现了这个 http://bbs.mjtd.com/thread-99926-1-1.html
然后提取了满足问题的最少代码。

1. ;;;-----------------------------------------------------------;;
   
2. ;;; MAT:mxm Multiply two matrices -Vladimir Nesterovsky-      ;;
   
3. ;;;-----------------------------------------------------------;;
   
4. (defun mat:mxm (m q)
   
5.   (mapcar (function (lambda (r) (mat:mxv (mat:trp q) r))) m)
   
6. )
   
7. 
   
8. ;;;-----------------------------------------------------------;;
   
9. ;;; Matrix x Vector - Vladimir Nesterovsky                    ;;
   
10. ;;; Args: m - nxn matrix, v - vector in R^n                   ;;
    
11. ;;;-----------------------------------------------------------;;
    
12. (defun mat:mxv (m v)
    
13.   (mapcar (function (lambda (r) (apply '+ (mapcar '* r v)))) m)
    
14. )
    
15. 
    
16. ;;; MAT:trp Transpose a matrix -Doug Wilson-                  ;;
    
17. ;;;-----------------------------------------------------------;;
    
18. (defun mat:trp (m)
    
19.   (apply 'mapcar (cons 'list m))
    
20. )
    
21. 
    
22. ;;;-----------------------------------------------------------;;
    
23. ;;; MAT:RefGeom (gile)                                        ;;
    
24. ;;; Returns a list which first item is a 3x3 transformation   ;;
    
25. ;;; matrix(rotation,scales normal) and second item the object ;;
    
26. ;;; insertion point in its parent(xref, bloc or space)        ;;
    
27. ;;;                                                           ;;
    
28. ;;; Argument : an ename                                       ;;
    
29. ;;;-----------------------------------------------------------;;
    
30. (defun mat:refgeom (ename / elst ang norm mat)
    
31.   (setq        elst (entget ename)
    
32.         ang  (cdr (assoc 50 elst))
    
33.         norm (cdr (assoc 210 elst))
    
34.   )
    
35.   (list
    
36.     (setq mat
    
37.            (mat:mxm
    
38.              (mapcar (function (lambda (v) (trans v 0 norm t)))
    
39.                      '((1.0 0.0 0.0) (0.0 1.0 0.0) (0.0 0.0 1.0))
    
40.              )
    
41.              (mat:mxm
    
42.                (list (list (cos ang) (- (sin ang)) 0.0)
    
43.                      (list (sin ang) (cos ang) 0.0)
    
44.                      '(0.0 0.0 1.0)
    
45.                )
    
46.                (list (list (cdr (assoc 41 elst)) 0.0 0.0)
    
47.                      (list 0.0 (cdr (assoc 42 elst)) 0.0)
    
48.                      (list 0.0 0.0 (cdr (assoc 43 elst)))
    
49.                )
    
50.              )
    
51.            )
    
52.     )
    
53.     (mapcar
    
54.       '-
    
55.       (trans (cdr (assoc 10 elst)) norm 0)
    
56.       (mat:mxv mat
    
57.                (cdr (assoc 10 (tblsearch "BLOCK" (cdr (assoc 2 elst)))))
    
58.       )
    
59.     )
    
60.   )
    
61. )
    
62. 
    
63. ;;; pt 块定义内的点
    
64. ;;; insert 块实例图元
    
65. ;;; 返回 指定实例内的点的WCS坐标值
    
66. (defun block->wcs (pt insert / geom)
    
67.   (setq geom (mat:refgeom insert))
    
68.   (mapcar '+ (mat:mxv (car geom) pt) (cadr geom))
    
69. )

;;;-----------------------------------------------------------;;<br /> ;;; MAT:mxm Multiply two matrices -Vladimir Nesterovsky-      ;;<br /> ;;;-----------------------------------------------------------;;<br /> (defun mat:mxm (m q)<br />   (mapcar (function (lambda (r) (mat:mxv (mat:trp q) r))) m)<br /> )<br /> <br /> ;;;-----------------------------------------------------------;;<br /> ;;; Matrix x Vector - Vladimir Nesterovsky                    ;;<br /> ;;; Args: m - nxn matrix, v - vector in R^n                   ;;<br /> ;;;-----------------------------------------------------------;;<br /> (defun mat:mxv (m v)<br />   (mapcar (function (lambda (r) (apply '+ (mapcar '* r v)))) m)<br /> )<br /> <br /> ;;; MAT:trp Transpose a matrix -Doug Wilson-                  ;;<br /> ;;;-----------------------------------------------------------;;<br /> (defun mat:trp (m)<br />   (apply 'mapcar (cons 'list m))<br /> )<br /> <br /> ;;;-----------------------------------------------------------;;<br /> ;;; MAT:RefGeom (gile)                                        ;;<br /> ;;; Returns a list which first item is a 3x3 transformation   ;;<br /> ;;; matrix(rotation,scales normal) and second item the object ;;<br /> ;;; insertion point in its parent(xref, bloc or space)        ;;<br /> ;;;                                                           ;;<br /> ;;; Argument : an ename                                       ;;<br /> ;;;-----------------------------------------------------------;;<br /> (defun mat:refgeom (ename / elst ang norm mat)<br />   (setq        elst (entget ename)<br />         ang  (cdr (assoc 50 elst))<br />         norm (cdr (assoc 210 elst))<br />   )<br />   (list<br />     (setq mat<br />            (mat:mxm<br />              (mapcar (function (lambda (v) (trans v 0 norm t)))<br />                      '((1.0 0.0 0.0) (0.0 1.0 0.0) (0.0 0.0 1.0))<br />              )<br />              (mat:mxm<br />                (list (list (cos ang) (- (sin ang)) 0.0)<br />                      (list (sin ang) (cos ang) 0.0)<br />                      '(0.0 0.0 1.0)<br />                )<br />                (list (list (cdr (assoc 41 elst)) 0.0 0.0)<br />                      (list 0.0 (cdr (assoc 42 elst)) 0.0)<br />                      (list 0.0 0.0 (cdr (assoc 43 elst)))<br />                )<br />              )<br />            )<br />     )<br />     (mapcar<br />       '-<br />       (trans (cdr (assoc 10 elst)) norm 0)<br />       (mat:mxv mat<br />                (cdr (assoc 10 (tblsearch "BLOCK" (cdr (assoc 2 elst)))))<br />       )<br />     )<br />   )<br /> )<br /> <br /> ;;; pt 块定义内的点<br /> ;;; insert 块实例图元<br /> ;;; 返回 指定实例内的点的WCS坐标值<br /> (defun block->wcs (pt insert / geom)<br />   (setq geom (mat:refgeom insert))<br />   (mapcar '+ (mat:mxv (car geom) pt) (cadr geom))<br /> )

vectra

好像不能把自己的贴子设成最佳答案 呵呵